add efl 1.17.0 elementary 1.17.0 and enlightenment 0.20.5

6 files changed, 460 insertions, 0 deletions

diff --git a/dev-libs/efl/Manifest b/dev-libs/efl/Manifest
index 1659f5a..6c519a0 100644
--- a/dev-libs/efl/Manifest
+++ b/dev-libs/efl/Manifest
@@ -5,8 +5,10 @@ DIST efl-1.13.0.tar.xz 39976920 SHA256 d848da426152c12ff7fd38913d8e600f1e3f5cab1
 DIST efl-1.13.1.tar.xz 40332672 SHA256 7e06e11678063fd74522f8fc56eb3d0235e9d7f889639e2ecff4bb663a2568d6 SHA512 29324acdeffa287f4ef9c72938cfc18ab4f8ae40a0b2ddbdeccb323361bfe10da43b65a419561e04a7c2c148b1a9bc820a71ad735fbf2988940e982b73e2b2f5 WHIRLPOOL 10639471666c7aae6283f4ff442b10fea7e5159f36207a676030a9a6961e86faee72026b1bdd4c512f0831db7a945dbf53e2e3da67defb4527d3adc72ee52756
 DIST efl-1.13.2.tar.xz 40332272 SHA256 18ef8ce8586e909b562f4e0ea5abbc63efab7cd15958b2aa9d365c292499d983 SHA512 9b1f0e3ab5f929f6528e322b63da140c185749ccd918a5d5b441c55c89c98c3b96ccffe645f3ceb2b790ffbab3e1d6cd746abee058a713eb052b3ac2592028b6 WHIRLPOOL 8adb76bef97e03fcb5413cdaadac528748ab3c45af74dd32fe81d0919b52a542836cdd311b908b95e2bbe28fa6ea2be5d6ac8fc353cbe32f3d6283b3d1c447a6
 DIST efl-1.14.0.tar.xz 42974224 SHA256 aa09ad67dc76963d5566e8e345bdcad9ddfd35509dca66f4350425688b30b631 SHA512 6dbde4f860384ffcc5a8a421d2c93f7a5fb1442386dc830e9a60f45d509b4b18d05baed5238ab1bcbc72a8a0f06b00cbe98c6e4269303d110be4abfc353823da WHIRLPOOL d257b39e1a0225b3e3138276f6aa8bbe9c5da1f1dd0e692f7d0fd42d12ae7e83b179255a77a16c9e49b711ad833a8f2b11e3058f56bbd7e4b37941bd9da83127
+DIST efl-1.17.0.tar.xz 43485360 SHA256 c13540bad764d014fea2c079fad8fcca62e5c229994d43aa4eb692d2c9b73afe SHA512 e4f28f938daf4ec1cb3d761407a443e401b59c6bb0f9fa6cd771dbd256b95f4a32a5f9e6bd8ad8328708a382f732e67abd1a23c7be2ff222f08bc8135a2435da WHIRLPOOL a9687320a5a61a727dd1ad8d757b260f72165ed54fb311cb0ff0c33590b8fc083aae1850cd8bdc5ae5c7506df119a445457cda9e076193692130c92e01e2d5bf
 EBUILD efl-1.12.3.ebuild 6832 SHA256 e655add579e6c95f8761a5cf9113f03a11d1d16704a6b59d615a644ffb15aad5 SHA512 17464c4b0b71dff06f53c08d2bb5ece2e47775b13b45f585d2f8df5810b6b512e7e3b8303dbe28811756767c91493f9bd5505ef00169eef16b72cf2984340b30 WHIRLPOOL e3d15f70557639a391a7392dbee29d952f2e68e01b51be4e0d6ea7502b2ce2ffcae30cfcaaacee1b33345eded0c95bf9dfa5d13992660e083ec7528e0c51dbef
 EBUILD efl-1.13.0.ebuild 6843 SHA256 3fd11f94a8913532faf1f9e4c10e325717e78637ca673052fe53a6df74adc765 SHA512 8039ddde467301b787a59c0450c5ad7762e10da4ebb5a28ce662603b6387ccaa63809a67cabe77e0ab8badaeb44b13603fb7007a61a771c5f06778c2529e7b66 WHIRLPOOL 1d7d3f8e71d5a49c65df3d32d12438f0f6c6c3eb31650d835a4b7ae13bcb65a9512e15f38a6c4f8ba0edeff43604d8af442764b3e492d395e4ab7adf7308bcb1
 EBUILD efl-1.13.1.ebuild 6836 SHA256 5e82c5db6bae8f810dc977c423014aec32719a338991c1c65323ad0230ae4523 SHA512 e2ef3d38c5e08159c324d1e43913d0d6b2a3686d869141249c52946447bc7291e630997d804cd74132187aa7b14c7d1886a1e597d17fd6921e938c8590ec7605 WHIRLPOOL 50dca79756099c83a99a31bffaea02c1589264b66a67a657f2e7e90c66ce6a5b808a10ffb827e4267148c437e3a093565dbde98add3587b6278262daa91ae78d
 EBUILD efl-1.13.2.ebuild 6836 SHA256 5e82c5db6bae8f810dc977c423014aec32719a338991c1c65323ad0230ae4523 SHA512 e2ef3d38c5e08159c324d1e43913d0d6b2a3686d869141249c52946447bc7291e630997d804cd74132187aa7b14c7d1886a1e597d17fd6921e938c8590ec7605 WHIRLPOOL 50dca79756099c83a99a31bffaea02c1589264b66a67a657f2e7e90c66ce6a5b808a10ffb827e4267148c437e3a093565dbde98add3587b6278262daa91ae78d
 EBUILD efl-1.14.0.ebuild 6836 SHA256 5e82c5db6bae8f810dc977c423014aec32719a338991c1c65323ad0230ae4523 SHA512 e2ef3d38c5e08159c324d1e43913d0d6b2a3686d869141249c52946447bc7291e630997d804cd74132187aa7b14c7d1886a1e597d17fd6921e938c8590ec7605 WHIRLPOOL 50dca79756099c83a99a31bffaea02c1589264b66a67a657f2e7e90c66ce6a5b808a10ffb827e4267148c437e3a093565dbde98add3587b6278262daa91ae78d
+EBUILD efl-1.17.0.ebuild 6635 SHA256 1731a3c4e22100df041184f4b6560f0f4df4afd5d07bbcb69cd487ec6b85ab92 SHA512 611f576c6802ec74fb6033ca80a797d47690279b71fd15e3d7432a62dfb8a21e4607ac142d1396b357860643aeefe552f67ba91fd6b50710bf4a913d2a2c57e1 WHIRLPOOL 4b79b3171d174944a9445f6185e5b6ce6973e6552258001fe43e82bb00cf9b9fd83512188c03936e490f1786c8f443725e7f2fc7c60f68b59ae06a655c01d888
diff --git a/dev-libs/efl/efl-1.17.0.ebuild b/dev-libs/efl/efl-1.17.0.ebuild
new file mode 100644
index 0000000..e8ae205
--- /dev/null
+++ b/dev-libs/efl/efl-1.17.0.ebuild
@@ -0,0 +1,275 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+MY_P=${P/_/-}
+
+if [[ "${PV}" == "9999" ]] ; then
+	EGIT_SUB_PROJECT="core"
+	EGIT_URI_APPEND="${PN}"
+elif [[ *"${PV}" == *"_pre"* ]] ; then
+	MY_P=${P%%_*}
+	SRC_URI="https://download.enlightenment.org/pre-releases/${MY_P}.tar.xz"
+	EKEY_STATE="snap"
+else
+	SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${MY_P}.tar.xz"
+	EKEY_STATE="snap"
+fi
+
+inherit enlightenment pax-utils
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+IUSE="+bmp debug drm +eet egl fbcon +fontconfig fribidi gif gles glib gnutls gstreamer harfbuzz +ico ibus jpeg2k libressl neon oldlua opengl ssl physics pixman +png +ppm +psd pulseaudio scim sdl sound systemd tga tiff tslib v4l2 valgrind wayland webp X xim xine xpm"
+
+REQUIRED_USE="
+	pulseaudio?	( sound )
+	opengl?		( || ( X sdl wayland ) )
+	gles?		( || ( X wayland ) )
+	gles?		( !sdl )
+	gles?		( egl )
+	sdl?		( opengl )
+	wayland?	( egl !opengl gles )
+	xim?		( X )
+"
+
+RDEPEND="
+	drm? (
+		>=dev-libs/libinput-0.8
+		media-libs/mesa[gbm]
+		>=x11-libs/libdrm-2.4
+		>=x11-libs/libxkbcommon-0.3.0
+	)
+	fontconfig? ( media-libs/fontconfig )
+	fribidi? ( dev-libs/fribidi )
+	gif? ( media-libs/giflib )
+	glib? ( dev-libs/glib:2 )
+	gnutls? ( net-libs/gnutls )
+	!gnutls? (
+		ssl? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl )
+		)
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	harfbuzz? ( media-libs/harfbuzz )
+	ibus? ( app-i18n/ibus )
+	jpeg2k? ( media-libs/openjpeg:0 )
+	!oldlua? ( >=dev-lang/luajit-2.0.0 )
+	oldlua? ( dev-lang/lua:* )
+	physics? ( >=sci-physics/bullet-2.80 )
+	pixman? ( x11-libs/pixman )
+	png? ( media-libs/libpng:0= )
+	pulseaudio? ( media-sound/pulseaudio )
+	scim? ( app-i18n/scim )
+	sdl? (
+		media-libs/libsdl2
+		virtual/opengl
+	)
+	sound? ( media-libs/libsndfile )
+	systemd? ( sys-apps/systemd )
+	tiff? ( media-libs/tiff:0= )
+	tslib? ( x11-libs/tslib )
+	valgrind? ( dev-util/valgrind )
+	wayland? (
+		>=dev-libs/wayland-1.8.0
+		>=x11-libs/libxkbcommon-0.3.1
+		media-libs/mesa[gles2,wayland]
+	)
+	webp? ( media-libs/libwebp )
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libX11
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXext
+		x11-libs/libXfixes
+		x11-libs/libXinerama
+		x11-libs/libXp
+		x11-libs/libXrandr
+		x11-libs/libXrender
+		x11-libs/libXtst
+		x11-libs/libXScrnSaver
+
+		opengl? (
+			x11-libs/libX11
+			x11-libs/libXrender
+			virtual/opengl
+		)
+
+		gles? (
+			x11-libs/libX11
+			x11-libs/libXrender
+			virtual/opengl
+		)
+	)
+	xine? ( >=media-libs/xine-lib-1.1.1 )
+	xpm? ( x11-libs/libXpm )
+
+	sys-apps/dbus
+	>=sys-apps/util-linux-2.20.0
+	sys-libs/zlib
+	virtual/jpeg:0=
+
+	!dev-libs/ecore
+	!dev-libs/edbus
+	!dev-libs/eet
+	!dev-libs/eeze
+	!dev-libs/efreet
+	!dev-libs/eina
+	!dev-libs/eio
+	!dev-libs/embryo
+	!dev-libs/eobj
+	!dev-libs/ephysics
+	!media-libs/edje
+	!media-libs/emotion
+	!media-libs/ethumb
+	!media-libs/evas
+"
+#external lz4 support currently broken because of unstable ABI/API
+#	app-arch/lz4
+
+#soft blockers added above for binpkg users
+#hard blocks are needed for building
+CORE_EFL_CONFLICTS="
+	!!dev-libs/ecore
+	!!dev-libs/edbus
+	!!dev-libs/eet
+	!!dev-libs/eeze
+	!!dev-libs/efreet
+	!!dev-libs/eina
+	!!dev-libs/eio
+	!!dev-libs/embryo
+	!!dev-libs/eobj
+	!!dev-libs/ephysics
+	!!media-libs/edje
+	!!media-libs/emotion
+	!!media-libs/ethumb
+	!!media-libs/evas
+"
+
+DEPEND="
+	${CORE_EFL_CONFLICTS}
+
+	${RDEPEND}
+	doc? ( app-doc/doxygen )
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	enlightenment_src_prepare
+
+	# Remove stupid sleep command.
+	# Also back out gnu make hack that causes regen of Makefiles.
+	sed -i \
+		-e '/sleep 10/d' \
+		-e '/^#### Work around bug in automake check macro$/,/^#### Info$/d' \
+		configure || die
+}
+
+src_configure() {
+	if use ssl && use gnutls ; then
+		einfo "You enabled both USE=ssl and USE=gnutls, but only one can be used;"
+		einfo "gnutls has been selected for you."
+	fi
+	if use opengl && use gles ; then
+		einfo "You enabled both USE=opengl and USE=gles, but only one can be used;"
+		einfo "opengl has been selected for you."
+	fi
+
+	E_ECONF=(
+		--with-profile=$(usex debug debug release)
+		--with-crypto=$(usex gnutls gnutls $(usex ssl openssl none))
+		--with-x11=$(usex X xlib none)
+		$(use_with X x)
+		--with-opengl=$(usex opengl full $(usex gles es none))
+		--with-glib=$(usex glib)
+		--enable-i-really-know-what-i-am-doing-and-that-this-will-probably-break-things-and-i-will-fix-them-myself-and-send-patches-aba
+
+		$(use_enable bmp image-loader-bmp)
+		$(use_enable bmp image-loader-wbmp)
+		$(use_enable drm)
+		$(use_enable doc)
+		$(use_enable eet image-loader-eet)
+		$(use_enable egl)
+		$(use_enable fbcon fb)
+		$(use_enable fontconfig)
+		$(use_enable fribidi)
+		$(use_enable gif image-loader-gif)
+		$(use_enable gstreamer gstreamer1)
+		$(use_enable harfbuzz)
+		$(use_enable ico image-loader-ico)
+		$(use_enable ibus)
+		$(use_enable jpeg2k image-loader-jp2k)
+		$(use_enable neon)
+		$(use_enable nls)
+		$(use_enable oldlua lua-old)
+		$(use_enable physics)
+		$(use_enable pixman)
+		$(use_enable pixman pixman-font)
+		$(use_enable pixman pixman-rect)
+		$(use_enable pixman pixman-line)
+		$(use_enable pixman pixman-poly)
+		$(use_enable pixman pixman-image)
+		$(use_enable pixman pixman-image-scale-sample)
+		$(use_enable png image-loader-png)
+		$(use_enable ppm image-loader-pmaps)
+		$(use_enable psd image-loader-psd)
+		$(use_enable pulseaudio)
+		$(use_enable scim)
+		$(use_enable sdl)
+		$(use_enable sound audio)
+		$(use_enable systemd)
+		$(use_enable tga image-loader-tga)
+		$(use_enable tiff image-loader-tiff)
+		$(use_enable tslib)
+		$(use_enable v4l2)
+		$(use_enable valgrind)
+		$(use_enable wayland)
+		$(use_enable webp image-loader-webp)
+		$(use_enable xim)
+		$(use_enable xine)
+		$(use_enable xpm image-loader-xpm)
+		--enable-cserve
+		--enable-image-loader-generic
+		--enable-image-loader-jpeg
+
+		--disable-tizen
+		--disable-gesture
+		--disable-gstreamer
+		--enable-xinput2
+		--disable-xinput22
+		--disable-multisense
+		--enable-libmount
+
+		# external lz4 support currently broken because of unstable ABI/API
+		#--enable-liblz4
+	)
+
+	enlightenment_src_configure
+}
+
+src_compile() {
+	if host-is-pax && ! use oldlua ; then
+		# We need to build the lua code first so we can pax-mark it. #547076
+		local target='_e_built_sources_target_gogogo_'
+		printf '%s: $(BUILT_SOURCES)\n' "${target}" >> src/Makefile || die
+		emake -C src "${target}"
+		emake -C src bin/elua/elua
+		pax-mark m src/bin/elua/.libs/elua
+	fi
+	enlightenment_src_compile
+}
+
+src_install() {
+	MAKEOPTS+=" -j1"
+
+	enlightenment_src_install
+}
diff --git a/media-libs/elementary/Manifest b/media-libs/elementary/Manifest
index e3e3fb1..bd9ea8f 100644
--- a/media-libs/elementary/Manifest
+++ b/media-libs/elementary/Manifest
@@ -3,8 +3,10 @@ DIST elementary-1.13.0.tar.xz 16069260 SHA256 78ba546d0c5aa22dae6a27d82194c9682a
 DIST elementary-1.13.1.tar.xz 16120080 SHA256 11595b6c5f511150a26e970bf8e590f96a6ce9e33e5dd8419407013844b2b74f SHA512 b8d4e3ff2447a80a98119753012e6ef0666ca569e4d401e66477a51667b6e940eb9c02d87f37b289b257db2855fc35486f0229e8861e74b6c48366aac30caa9f WHIRLPOOL 5400f9a11f2997fde9ee7b170ccf6b8833ad0fdecf229fc2dcbb9eea731e40958922672b47fa539df533006b29f7a197473cb3b24b8bac51a4159fc9f249ec46
 DIST elementary-1.13.2.tar.xz 16121068 SHA256 49107ec262516c4e2f289a51ed143af6f69fff13915179e33895d0f50b95d49f SHA512 8e01bc2561a7a0bc2c5adea616a6eb212fd3a502669a90c6e0928b3a1eb35819e594f3c0bd702cceb7232dd51b079411d7246fb4190465790b0e9a68793b7c4b WHIRLPOOL 632d14aaca276064b40e4ac7932e69b769aa191fbcc79f90bc853f9b5e439e9eec280323bb0ca5f4569572967172e90995abf7414aedd52836538c98b4c3d50b
 DIST elementary-1.14.0.tar.xz 18400964 SHA256 1aa899e30adaa2077060784d1aaca5f934e6877746676e20722f59490aac17bc SHA512 a976e014a503a97a35e4c61d3d174fc9d23964c7e7ca6f95bd7c36ee1c50de220c13dbcc8a5cea68a286750cedeb26054a5977d199576de6a554ed85ee2b3a81 WHIRLPOOL 04dc3705e560fcdda79aed57f249c0e9f2e44a7e697eb43587229338704f27fb9392b0a55efa4c88a14b9e72488cc457f3699830ae252235fafcc65d98390ec2
+DIST elementary-1.17.0.tar.xz 18491592 SHA256 6a6a5883939eab8d87179c7980c0dbd6b53d82bf460a161045a891694d036b2b SHA512 60862e164770a93c0b864f35b5880f8d28f9fec520b7b440935143a14ffc9cd2dacbb650463c2abb7ce364c631509e1ddefce6eb49def1b016a752416d619065 WHIRLPOOL 76499e687908b8c2c885429c614a493b226f5e2d73edc040a5d6e8e287dab3b342b517fa46e4a37ca6560e4a9c617415d8138da1308865aa5d07187d60c7ea61
 EBUILD elementary-1.12.3.ebuild 1403 SHA256 0064413c42497b354ee70288009b4df16928d6c7042a6951972e20ee55bbf8ea SHA512 8ecba8c5b508a0df81241b8a68353ab9976effe089e8a542471001e0d6ffe1ee815a79ced2fefc94ee4aa3c4847c6e74b32dbfd14e8e8eeb48076d7562942296 WHIRLPOOL ea184cd4f337df53ec02035bab28bfb58f30ebce6f14c1c51fdf6f3d5811e6a2f61582bdda8a90ef43f54c652b05ab20132f93aec072dbc57d5c1636d05b5dca
 EBUILD elementary-1.13.0.ebuild 1402 SHA256 3c1248013e5f868478453d8a373af2b81fb1141456a0fa8a85bc04c46c612653 SHA512 fb29f3c26361fa29eb5f9fa2e55befbde9548ac8027d8b3a582c63a22e3acb87dcf091fcd84adb2a6166699d5b38037ed7d719b65dc70b3e38a2d772d0c725fd WHIRLPOOL 4d5ab4e3abe3a02a1dcb69a1b6cc16546a8774733984f1144ded041ad3531390d5d0a9d4bb8a5c0ccf40cd58e48c00dee2fd5fb470f2665a7a43740994519ac1
 EBUILD elementary-1.13.1.ebuild 1402 SHA256 3c1248013e5f868478453d8a373af2b81fb1141456a0fa8a85bc04c46c612653 SHA512 fb29f3c26361fa29eb5f9fa2e55befbde9548ac8027d8b3a582c63a22e3acb87dcf091fcd84adb2a6166699d5b38037ed7d719b65dc70b3e38a2d772d0c725fd WHIRLPOOL 4d5ab4e3abe3a02a1dcb69a1b6cc16546a8774733984f1144ded041ad3531390d5d0a9d4bb8a5c0ccf40cd58e48c00dee2fd5fb470f2665a7a43740994519ac1
 EBUILD elementary-1.13.2.ebuild 1402 SHA256 3c1248013e5f868478453d8a373af2b81fb1141456a0fa8a85bc04c46c612653 SHA512 fb29f3c26361fa29eb5f9fa2e55befbde9548ac8027d8b3a582c63a22e3acb87dcf091fcd84adb2a6166699d5b38037ed7d719b65dc70b3e38a2d772d0c725fd WHIRLPOOL 4d5ab4e3abe3a02a1dcb69a1b6cc16546a8774733984f1144ded041ad3531390d5d0a9d4bb8a5c0ccf40cd58e48c00dee2fd5fb470f2665a7a43740994519ac1
 EBUILD elementary-1.14.0.ebuild 1402 SHA256 3c1248013e5f868478453d8a373af2b81fb1141456a0fa8a85bc04c46c612653 SHA512 fb29f3c26361fa29eb5f9fa2e55befbde9548ac8027d8b3a582c63a22e3acb87dcf091fcd84adb2a6166699d5b38037ed7d719b65dc70b3e38a2d772d0c725fd WHIRLPOOL 4d5ab4e3abe3a02a1dcb69a1b6cc16546a8774733984f1144ded041ad3531390d5d0a9d4bb8a5c0ccf40cd58e48c00dee2fd5fb470f2665a7a43740994519ac1
+EBUILD elementary-1.17.0.ebuild 1264 SHA256 0acb4dc23dc727cea11bc4da205df5174612b68ede3e5d66402ccafa78311807 SHA512 293cf6321789b846075263c0a20d59a8f94a44ec915ffa975cf673c9b8569b3322665109bba1067497d2de92fd4297b343d9fcfb8b5b261c8f519c8f2c693478 WHIRLPOOL ba9e0e9d6177b42e29236b246580cae5e924eeca12c753c6d9c00b37920d470c012208aa7c3f1b14bc3a0e4b69db20c70712ba3b8541da3e2cb888e2e639207e
diff --git a/media-libs/elementary/elementary-1.17.0.ebuild b/media-libs/elementary/elementary-1.17.0.ebuild
new file mode 100644
index 0000000..7cef5b0
--- /dev/null
+++ b/media-libs/elementary/elementary-1.17.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+MY_P=${P/_/-}
+
+if [[ "${PV}" == "9999" ]] ; then
+	EGIT_SUB_PROJECT="core"
+	EGIT_URI_APPEND="${PN}"
+else
+	SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${MY_P}.tar.xz"
+	EKEY_STATE="snap"
+fi
+
+inherit enlightenment
+
+DESCRIPTION="Basic widget set, based on EFL for mobile touch-screen devices"
+HOMEPAGE="https://trac.enlightenment.org/e/wiki/Elementary"
+
+LICENSE="LGPL-2.1"
+IUSE="debug examples fbcon quicklaunch sdl wayland X static-libs"
+
+DEPEND=">=dev-libs/efl-${PV}[fbcon?,sdl?,png,wayland?,X?]"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	E_ECONF=(
+		$(use_enable debug)
+		$(use_enable doc)
+		--disable-ecore-cocoa
+		--disable-ecore-psl1ght
+		--disable-ecore-win32
+		--disable-elocation
+		--disable-emap
+		--disable-eweather
+		# broken: make[4]: *** No rule to make target 'prefs_example_01.epb', needed by 'all-am'.  Stop
+		#$(use_enable examples build-examples)
+		$(use_enable examples install-examples)
+		$(use_enable fbcon ecore-fb)
+		$(use_enable sdl ecore-sdl)
+		$(use_enable wayland ecore-wayland)
+		$(use_enable X ecore-x)
+		$(use_enable quicklaunch quick-launch)
+	)
+
+	enlightenment_src_configure
+}
diff --git a/x11-wm/enlightenment/Manifest b/x11-wm/enlightenment/Manifest
index c96a151..109642d 100644
--- a/x11-wm/enlightenment/Manifest
+++ b/x11-wm/enlightenment/Manifest
@@ -1,4 +1,6 @@
 AUX gentoo-sysactions.conf 3056 SHA256 5939973a9fbaaba81751e936fb541d6aebd7ec1c599174ea568f5a579356939f SHA512 688f02cbff0d50a847eb08ca7832699b836adca9b22e15a780943a8e5a8213aac04b335cfdf3cb96adbff238f681ae8954a720153e8e35b2afaba3225d53206a WHIRLPOOL 0c05e0d295ede8b2f436a87c4b98876fed64d5cc780f13bb6bde1a74a3c87847f2f90ab482a61c2b39f20894572329f5497e5da22537261eef2f0a9fb33ce56d
 AUX quickstart.diff 474 SHA256 9201674d2f8707f216e18c471f0a4a5a7366b3dd32cb8ec131ca1795a10bb3e6 SHA512 b8df654dd1246ea6391017fe9856e38d209b250625f8343aa4943a4eeed980447eb52c6a15fe170bcab90b76e5670ee9c7f98358bb87990877e312cc4cea8f6c WHIRLPOOL 7ea473b01d46ab1ae10ed50d9991de652e3c2945390a71dfa3cba4bf7c6d8ae526dbd18a275db7bd714be7e48414b90ea470c46d2460c68512ede070025b9c49
 DIST enlightenment-0.20.3.tar.xz 25039740 SHA256 321103dda0383450a1dcf1a7c172479e1bdf8face5150ac688fc5ffe1b5fe3a7 SHA512 40c5f4c2b19d25e439f5ebc83b5e044e1594a503adf4d30d2ac9823ecee65b77e9c69cd3309062e2b809e18ab0a7a81df935f2ef2e9901caf3d40023114b0097 WHIRLPOOL a8d45c43f3f68e2d1072699095320d70e3a57b8ad76915b6d6ab79732a6bb2224ee6a176c57a551ac80992aafef8c2802e4bc72341895f0d3a36f65b4b6e4828
+DIST enlightenment-0.20.5.tar.xz 25039672 SHA256 22749584d2fdf62d5a63c64dd9e57a1e318837a48f10fb9cdd2097769aa802d0 SHA512 0d66d23b3462d6bf293229256d88d486d05135ff7bc7ab4258c3923c853f1935a1850b3a3ff0dabb1aae99a31dafb578f5cbb5678d08df490d3c6837b874a911 WHIRLPOOL 5bfa8e6cc2d5d17fc61a08fc9edbc8970f60cb9e44fcfaf7035b764d21525b375ce9f4060ac33a45627cc3a1f2eb21335e322f88f8a79709fce9284aa668d983
 EBUILD enlightenment-0.20.3.ebuild 3171 SHA256 00011721c19f42bc12610d78b65872416164f6f8d1184deaff2db36cb8130094 SHA512 d6013a1623c74a8193c0c0e6a79a7ca284db5188e48538a28c5438792c466e762122ea4375327edef4ece0a3e131120905a178979ac22600a39e5bafb4d0fc63 WHIRLPOOL 0ddb8fdd5cd360a8f7895c45b33698c848e15df97f42162403974c9c2ef2efb15b19746d34f9d427d2141f2e945a710d8b23933c3ab76b54061b069c80dc7d2e
+EBUILD enlightenment-0.20.5.ebuild 3171 SHA256 00011721c19f42bc12610d78b65872416164f6f8d1184deaff2db36cb8130094 SHA512 d6013a1623c74a8193c0c0e6a79a7ca284db5188e48538a28c5438792c466e762122ea4375327edef4ece0a3e131120905a178979ac22600a39e5bafb4d0fc63 WHIRLPOOL 0ddb8fdd5cd360a8f7895c45b33698c848e15df97f42162403974c9c2ef2efb15b19746d34f9d427d2141f2e945a710d8b23933c3ab76b54061b069c80dc7d2e
diff --git a/x11-wm/enlightenment/enlightenment-0.20.5.ebuild b/x11-wm/enlightenment/enlightenment-0.20.5.ebuild
new file mode 100644
index 0000000..24f6675
--- /dev/null
+++ b/x11-wm/enlightenment/enlightenment-0.20.5.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+MY_P=${P/_/-}
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_SUB_PROJECT="core"
+	EGIT_URI_APPEND="${PN}"
+else
+	SRC_URI="https://download.enlightenment.org/rel/apps/${PN}/${MY_P}.tar.xz"
+	EKEY_STATE="snap"
+fi
+
+inherit enlightenment
+
+DESCRIPTION="Enlightenment DR17 window manager"
+
+LICENSE="BSD-2"
+SLOT="0.17/${PV%%_*}"
+
+__CONF_MODS=(
+	applications bindings dialogs display
+	interaction intl menus
+	paths performance randr shelves theme
+	window-manipulation window-remembers
+)
+__NORM_MODS=(
+	appmenu backlight bluez4 battery
+	clock conf connman cpufreq everything
+	fileman fileman-opinfo gadman geolocation
+	ibar ibox lokker
+	mixer msgbus music-control notification
+	pager packagekit pager-plain policy-mobile quickaccess
+	shot start syscon systray tasks teamwork temperature tiling
+	winlist wizard wl-desktop-shell wl-drm wl-text-input
+	wl-weekeyboard wl-wl wl-x11 xkbswitch xwayland
+)
+IUSE_E_MODULES=(
+	${__CONF_MODS[@]/#/enlightenment_modules_conf-}
+	${__NORM_MODS[@]/#/enlightenment_modules_}
+)
+
+IUSE="pam spell static-libs systemd +udev ukit wayland ${IUSE_E_MODULES[@]/#/+}"
+
+RDEPEND="
+	pam? ( sys-libs/pam )
+	systemd? ( sys-apps/systemd )
+	wayland? (
+		dev-libs/efl[wayland]
+		>=dev-libs/wayland-1.2.0
+		>=x11-libs/pixman-0.31.1
+		>=x11-libs/libxkbcommon-0.3.1
+	)
+	>=dev-libs/efl-1.16[X]
+	>=media-libs/elementary-1.16
+	x11-libs/xcb-util-keysyms"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/quickstart.diff
+	enlightenment_src_prepare
+}
+
+# Sanity check to make sure module lists are kept up-to-date.
+check_modules() {
+	local detected=$(
+		awk -F'[\\[\\](, ]' '$1 == "AC_E_OPTIONAL_MODULE" { print $3 }' \
+		configure.ac | sed 's:_:-:g' | LC_COLLATE=C sort
+	)
+	local sorted=$(
+		printf '%s\n' ${IUSE_E_MODULES[@]/#enlightenment_modules_} | \
+		LC_COLLATE=C sort
+	)
+	if [[ ${detected} != "${sorted}" ]] ; then
+		local out new old
+		eerror "The ebuild needs to be kept in sync."
+		echo "${sorted}" > ebuild-iuse
+		echo "${detected}" > configure-detected
+		out=$(diff -U 0 ebuild-iuse configure-detected | sed -e '1,2d' -e '/^@@/d')
+		new=$(echo "${out}" | sed -n '/^+/{s:^+::;p}')
+		old=$(echo "${out}" | sed -n '/^-/{s:^-::;p}')
+		eerror "Add these modules: $(echo ${new})"
+		eerror "Drop these modules: $(echo ${old})"
+		die "please update the ebuild"
+	fi
+}
+
+src_configure() {
+	check_modules
+
+	E_ECONF=(
+		--disable-install-sysactions
+		$(use_enable doc)
+		$(use_enable nls)
+		$(use_enable pam)
+		$(use_enable systemd)
+		--enable-device-udev
+		$(use_enable udev mount-eeze)
+		$(use_enable ukit mount-udisks)
+		$(use_enable wayland)
+	)
+	local u c
+	for u in ${IUSE_E_MODULES[@]} ; do
+		c=${u#enlightenment_modules_}
+		# Disable modules by hand since we default to enabling them all.
+		case ${c} in
+		wl-*|xwayland)
+			if ! use wayland ; then
+				E_ECONF+=( --disable-${c} )
+				continue
+			fi
+			;;
+		esac
+		E_ECONF+=( $(use_enable ${u} ${c}) )
+	done
+	enlightenment_src_configure
+}
+
+src_install() {
+	enlightenment_src_install
+	insinto /etc/enlightenment
+	newins "${FILESDIR}"/gentoo-sysactions.conf sysactions.conf
+}