bump libchamplain

2 files changed, 85 insertions, 0 deletions

diff --git a/media-libs/libchamplain/Manifest b/media-libs/libchamplain/Manifest
new file mode 100644
index 00000000..644cfae8
--- /dev/null
+++ b/media-libs/libchamplain/Manifest
@@ -0,0 +1,2 @@
+EBUILD libchamplain-0.7.1.ebuild 1770 RMD160 f8e5c7217e3033bf16c51f23c172e4453ed03dfd SHA1 aa67ace2e512bad0ae3b49a30ea85f4c25f4cad8 SHA256 16e879029271f33f452da639e60be1becb5892578d03228a74e6100c4ea5cef1
+DIST libchamplain-0.7.1.tar.bz2 670427 RMD160 c9a0495d865416d444309ae768944c5f7fb51ff1 SHA1 4b0cd475c00b8c949b39f171c6b885a49f594b60 SHA256 c1669cbfc0d1b01950d9740fd5d3f9f57cdfaf37df855392bdd214210d2f4601
diff --git a/media-libs/libchamplain/libchamplain-0.7.1.ebuild b/media-libs/libchamplain/libchamplain-0.7.1.ebuild
new file mode 100644
index 00000000..7e680211
--- /dev/null
+++ b/media-libs/libchamplain/libchamplain-0.7.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=3
+
+PYTHON_DEPEND="python? 2"
+SUPPORT_PYTHON_ABIS="1"
+
+inherit gnome2 python
+
+DESCRIPTION="Clutter based world map renderer"
+HOMEPAGE="http://blog.pierlux.com/projects/libchamplain/en/"
+
+LICENSE="LGPL-2"
+SLOT="0.8"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc gtk introspection python"
+
+RDEPEND="
+	>=dev-libs/glib-2.16
+	>=x11-libs/cairo-1.4
+	>=net-libs/libsoup-2.26[gnome]
+	media-libs/clutter:1.0
+	media-libs/memphis
+	dev-db/sqlite:3
+	gtk? (
+		>=x11-libs/gtk+-2.18
+		media-libs/memphis:0.2
+		>=media-libs/clutter-gtk-0.10:1.0 )
+	python? (
+		media-libs/pymemphis
+		dev-python/pyclutter
+		dev-python/pyclutter-gtk )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( >=dev-util/gtk-doc-1.9 )
+	introspection? ( >=dev-libs/gobject-introspection-0.6.3 )"
+
+RESTRICT_PYTHON_ABIS="3.*"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+G2CONF="${G2CONF}
+	--disable-static
+	--enable-memphis
+	$(use_enable debug)
+	$(use_enable gtk)
+	$(use_enable introspection)
+	$(use_enable python)"
+
+src_prepare() {
+	gnome2_src_prepare
+	sed 's:bindings::g' -i Makefile.in || die
+}
+
+src_compile() {
+	gnome2_src_compile
+	if use python; then
+		python_copy_sources bindings
+		building() {
+			emake \
+			PYTHON_INCLUDES="-I$(python_get_includedir)" \
+			pythondir="$(python_get_sitedir)" \
+			pyexecdir="$(python_get_sitedir)"
+		}
+		python_execute_function -s --source-dir bindings building
+	fi
+}
+
+src_install() {
+	gnome2_src_install
+	if use python; then
+		installation() {
+			emake DESTDIR="${ED}" \
+			pythondir="$(python_get_sitedir)" \
+			pyexecdir="$(python_get_sitedir)" \
+			install
+	}
+	python_execute_function -s --source-dir bindings installation
+	python_clean_installation_image
+	fi
+}