blob: 933f090ee1faeaf077cd57c1d33848ec0b1bb4a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit check-reqs python-r1 toolchain-funcs
if [[ ${PV} == *9999 ]]; then
EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
inherit autotools git-r3
else
SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.xz"
KEYWORDS="~amd64"
fi
DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
HOMEPAGE="https://graph-tool.skewed.de/"
LICENSE="GPL-3"
SLOT="0"
IUSE="+cairo openmp"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="
${PYTHON_DEPS}
dev-libs/boost:=[context,python,${PYTHON_USEDEP}]
dev-libs/expat
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/scipy[${PYTHON_USEDEP}]
sci-mathematics/cgal:=
dev-python/matplotlib[${PYTHON_USEDEP}]
cairo? (
dev-cpp/cairomm:0
dev-python/pycairo[${PYTHON_USEDEP}]
x11-libs/cairo[X]
)"
DEPEND="${RDEPEND}
dev-cpp/sparsehash"
BDEPEND="virtual/pkgconfig"
# bug 453544
CHECKREQS_DISK_BUILD="6G"
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
check-reqs_pkg_pretend
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
src_prepare() {
default
[[ ${PV} == *9999 ]] && eautoreconf
python_copy_sources
}
src_configure() {
my_configure() {
econf \
--disable-static \
$(use_enable openmp) \
$(use_enable cairo) \
--with-boost-python="boost_${EPYTHON/./}"
}
python_foreach_impl run_in_build_dir my_configure
}
src_compile() {
python_foreach_impl run_in_build_dir emake
}
src_install() {
my_python_install() {
default
python_optimize
}
python_foreach_impl run_in_build_dir my_python_install
find "${ED}" -name '*.la' -delete || die
}
|
GitWeb