blob: f902f7fa366b1e0c74d6b0275eb055edf825e95b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit cmake-utils multilib eutils udev python-single-r1
DESCRIPTION="Utility for advanced configuration of Razer mice (DeathAdder, Krait, Lachesis)"
HOMEPAGE="http://bues.ch/cms/hacking/razercfg.html"
SRC_URI="http://bues.ch/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 x86"
IUSE="+pm-utils qt4"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="${PYTHON_DEPS}
pm-utils? ( sys-power/pm-utils )
qt4? ( dev-python/PyQt4 )"
DEPEND="${RDEPEND}"
src_prepare() {
cmake-utils_src_prepare
sed -i \
-e '/ldconfig/{N;d}' \
-e '/udevadm control/{N;d}' \
-e "s:/etc/udev/rules.d/:$(get_udevdir)/rules.d/:" \
-e 's:01-razer-udev.rules:40-razercfg.rules:' \
-e "s:/etc/pm/sleep.d:/usr/$(get_libdir)/pm-utils/sleep.d/:" \
-e 's:50-razer:80razer:' \
librazer/CMakeLists.txt \
|| die "sed failed"
}
src_install() {
cmake-utils_src_install
newinitd "${FILESDIR}"/razerd.init.d-r1 razerd
dodoc README razer.conf
if ! use qt4; then
rm "${D}"/usr/bin/qrazercfg
else
make_desktop_entry qrazercfg "Razer Mouse Settings" mouse "Qt;Settings"
fi
use pm-utils || rm "${D}"/usr/$(get_libdir)/pm-utils/sleep.d/80razer
python_fix_shebang "${ED}"usr/bin
}
pkg_postinst() {
udevadm control --reload-rules && udevadm trigger --subsystem-match=usb
}
|
GitWeb
