1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..11} )
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1 optfeature virtualx xdg
# Commit of documentation to fetch
DOCS_PV="cfa8e009264cb5e79beeead6a012e521db2c73dc"
DESCRIPTION="The Scientific Python Development Environment"
HOMEPAGE="
https://www.spyder-ide.org/
https://github.com/spyder-ide/spyder/
https://pypi.org/project/spyder/
"
SRC_URI="
https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
>=dev-python/pylint-venv-2.1.1[${PYTHON_USEDEP}]
>=dev-python/python-lsp-black-1.2.0[${PYTHON_USEDEP}]
<dev-python/python-lsp-black-3[${PYTHON_USEDEP}]
>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
>=dev-python/pyzmq-22.1.0[${PYTHON_USEDEP}]
>=dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
<dev-python/qdarkstyle-3.2.0[${PYTHON_USEDEP}]
>=dev-python/qstylizer-0.2.2[${PYTHON_USEDEP}]
>=dev-python/qtawesome-1.2.1[${PYTHON_USEDEP}]
>=dev-python/qtconsole-5.4.2[${PYTHON_USEDEP}]
<dev-python/qtconsole-5.5.0[${PYTHON_USEDEP}]
>=dev-python/QtPy-2.1.0[${PYTHON_USEDEP},svg,webengine]
>=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
>=dev-python/spyder-kernels-2.4.4[${PYTHON_USEDEP}]
<dev-python/spyder-kernels-2.5.0[${PYTHON_USEDEP}]
>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/cython[${PYTHON_USEDEP}]
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/matplotlib[tk,${PYTHON_USEDEP}]
dev-python/pandas[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
dev-python/pytest-order[${PYTHON_USEDEP}]
dev-python/pytest-qt[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
dev-python/QtPy[${PYTHON_USEDEP},pyside2,pyqt5]
dev-python/scipy[${PYTHON_USEDEP}]
dev-python/sympy[${PYTHON_USEDEP}]
)"
# Based on the courtesy of Arfrever
# This patch removes a call to update-desktop-database during build
# This fails because access is denied to this command during build
PATCHES=(
"${FILESDIR}/${PN}-5.0.0-build.patch"
"${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
)
DOCS=(
"AUTHORS.txt"
"Announcements.md"
"CHANGELOG.md"
"CODE_OF_CONDUCT.md"
"CONTRIBUTING.md"
"NOTICE.txt"
"README.md"
"RELEASE.md"
)
distutils_enable_tests pytest
distutils_enable_sphinx docs/doc \
dev-python/sphinx-panels \
dev-python/pydata-sphinx-theme \
dev-python/sphinx-multiversion
python_prepare_all() {
# move docs into workdir
mv ../spyder-docs-${DOCS_PV}* docs || die
# these dependencies are packaged separately:
# dev-python/spyder-kernels,
# dev-python/python-lsp-server,
# dev-python/qdarkstyle
rm -r external-deps/* || die
# runs against things packaged in external-deps dir
rm conftest.py || die
# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
# Do not depend on ipython, this dependency is carried in spyder-kernels
# The explicit version requirements only make things more complicated, if e.g.
# pyls-spyder gains compatibility with a newer version of python-lsp-server
# in a new release it will take time for this information to propagate into
# the next spyder release. So just remove the dependency and let the other
# ebuilds handle the version requirements to speed things up and prevent
# issues such as Bug 803269.
sed -i \
-e "/'pyqt5[ 0-9<=>.,]*',/d" \
-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
-e "/'parso[ 0-9<=>.,]*',/d" \
-e "/'jedi[ 0-9<=>.,]*',/d" \
-e "/'pylint[ 0-9<=>.,]*',/d" \
setup.py || die
# -e "/'ipython[ 0-9<=>.,]*',/d" \
sed -i \
-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
spyder/dependencies.py || die
# -e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
# do not check deps, fails because we removed dependencies above
sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
spyder/tests/test_dependencies_in_sync.py || die
# can't check for update, need network
rm spyder/workers/tests/test_update.py || die
# skip online test
rm spyder/widgets/github/tests/test_github_backend.py || die
distutils-r1_python_prepare_all
}
# Calling pytest directly somehow passes the pytest arguments to spyder
# causing an invalid argument error
python_test() {
virtx "${EPYTHON}" runtests.py
}
pkg_postinst() {
xdg_pkg_postinst
optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
optfeature "Run Cython files in the IPython console" dev-python/cython
optfeature "The hdf5/h5py plugin" dev-python/h5py
optfeature "The line profiler plugin" dev-python/spyder-line-profiler
optfeature "Vim key bindings" dev-python/spyder-vim
optfeature "Unittest support" dev-python/spyder-unittest
optfeature "System terminal inside spyder" dev-python/spyder-terminal
optfeature "Jupyter notebook support" dev-python/spyder-notebook
# spyder-memory-profiler is not compatible with spyder-5.2+ yet
# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
# spyder-reports not yet updated to >=spyder-4.0.0
# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
# Plugins with no release yet:
# optfeature "Manage virtual environments and packages" dev-python/spyder-env-manager
# optfeature "VCS (e.g. git) integration" dev-python/spyder-vcs
}
|
GitWeb