1 files changed, 58 insertions, 0 deletions
diff --git a/net-libs/libtrace/libtrace-4.0.4.ebuild b/net-libs/libtrace/libtrace-4.0.4.ebuild
new file mode 100644
index 000000000000..30734d72f4b6
--- /dev/null
+++ b/net-libs/libtrace/libtrace-4.0.4.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils
+
+DESCRIPTION="A library and tools for trace processing"
+HOMEPAGE="http://research.wand.net.nz/software/libtrace.php"
+SRC_URI="http://research.wand.net.nz/software/${PN}/${P/_/-}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ncurses numa static-libs"
+
+RDEPEND="
+	>=net-libs/libpcap-0.8
+	dev-libs/openssl:0=
+	ncurses? ( sys-libs/ncurses:0= )
+	net-libs/wandio
+	numa? ( sys-process/numactl )
+"
+DEPEND="
+	${RDEPEND}
+	app-doc/doxygen
+	sys-devel/flex
+	virtual/pkgconfig
+	virtual/yacc
+"
+PATCHES=(
+		"${FILESDIR}"/${PN}-3.0.20-autoconf-1.13.patch
+		"${FILESDIR}"/${PN}-3.0.20-tinfo.patch
+		"${FILESDIR}"/${PN}-4.0.0-no-examples.patch
+		"${FILESDIR}"/${PN}-4.0.0-with-numa.patch
+)
+S=${WORKDIR}/${P/_beta/}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with ncurses) \
+		$(use_with numa) \
+		--with-man
+}
+
+src_install() {
+	default
+
+	use doc && dodoc -r docs/doxygen/html
+
+	prune_libtool_files --modules
+}