1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/django-timezone-field/django-timezone-field-6.0.ebuild b/dev-python/django-timezone-field/django-timezone-field-6.0.ebuild
new file mode 100644
index 000000000000..cc484c7ef9e9
--- /dev/null
+++ b/dev-python/django-timezone-field/django-timezone-field-6.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Django app providing database and form fields for timezone objects"
+HOMEPAGE="
+	https://github.com/mfogel/django-timezone-field/
+	https://pypi.org/project/django-timezone-field/
+"
+SRC_URI="
+	https://github.com/mfogel/django-timezone-field/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<dev-python/django-5[${PYTHON_USEDEP}]
+	>=dev-python/django-2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/djangorestframework[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x DB_ENGINE=sqlite
+	epytest
+}