www-client/opera-developer: Version 73.0.3834.0

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 106 insertions, 0 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 8a242ebf4222..7b43f67a73a8 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,2 +1,3 @@
 DIST opera-developer_73.0.3820.0_amd64.deb 72042252 BLAKE2B bc2dd709212c6a26208fac5d1eab246b33ac669a5f593c630ec4c379fc7330bc51485e59b3f981ac314dbf5a1cc4e033b732ea3318103118d76b021b8e6dc62a SHA512 d51eed335794dd5aa64e0300f873a8f202c1733512e192697104089a6bc57ef51ee321843044553f26444e1f649026728d66f847936d983f92c6014f68c2ec8e
 DIST opera-developer_73.0.3827.0_amd64.deb 72518736 BLAKE2B 14213c23f1e170694e9b5ccbf04755c0244988918b9c18fd733b64c656827e0d477e916ad02af61c20252ec53d5be06881bed1b8159bfbde20e4339b4ff64dfa SHA512 9b26341ac053674a8461826c221e44c2ee4833613ade0aeb1ee12ecc112418a720c9db14f7165812150576266937ec5c021ed561ad0706672a77df099418a8be
+DIST opera-developer_73.0.3834.0_amd64.deb 72418344 BLAKE2B e5d03ec7d669af896979f46c8255b06e8832de8ea45eb1c97c5f8e6e960a6b172be33259dcf6bd065666ca427dea3b917e12515055a3bea6602128c42b7faff1 SHA512 755610a2f2ccb56c1a7eaa5f2aa491a6dedd1febccb0f46c7cfaa6d60990ba5846b6b145a26be8588594b6f13a9fe0f926372722515fb549696af24ab990816f
diff --git a/www-client/opera-developer/opera-developer-73.0.3834.0.ebuild b/www-client/opera-developer/opera-developer-73.0.3834.0.ebuild
new file mode 100644
index 000000000000..c6ec6cb96a08
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-73.0.3834.0.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/libxkbcommon
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+pkg_setup() {
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_prepare() {
+	default
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	rm usr/bin/${PN} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}