net-misc/s6-networking: add 2.5.1.0

It is now possible to use ssl support via dev-libs/libretls library.

-fno-stack-protector flag was removed from configure script in upstream
in version 2.4.0.0.

Upstream-commit: 540c946d8632 ("Don't put -fno-stack-protector in default CFLAGS")
Signed-off-by: Petr Vaněk <arkamar@atlas.cz>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/net-misc/s6-networking/Manifest b/net-misc/s6-networking/Manifest
index 89edcc546797..0694b8607d9c 100644
--- a/net-misc/s6-networking/Manifest
+++ b/net-misc/s6-networking/Manifest
@@ -1 +1,2 @@
 DIST s6-networking-2.3.2.0.tar.gz 87949 BLAKE2B 675974fd5a2e2e764944eb314725834bbc1e4a17b87af9559cda4bca4a6cb3f0e766741519a4d5024f7a8608dfe80310801a59a2b04f8ccd42acede27efeffe2 SHA512 876005e3060493fb22efb59dcdc3392eb746454cf9c11c9c0ebdd6b24789db18e364039096a8a4168dcd4023b98e539d8489d490a0b7a24ddccc437f7076618d
+DIST s6-networking-2.5.1.0.tar.gz 110443 BLAKE2B 489676bcb050d57482b0901742b53ce6cff00e25c1d8effc5c3d96d8e8ad0d32d42a62c15c73155d3b21fcfe6f310fc0f0c020bf945ac1a4b1c7fb9e9785adf4 SHA512 5d64420811d8d8a0034431dccda82b7ddd546f3b7c40ed02e05565c29c3ec14b75477306fea1a1e4aacc898e66e03718d7ac229b85be82d62bfe26c3ffc5fdf8
diff --git a/net-misc/s6-networking/s6-networking-2.5.1.0.ebuild b/net-misc/s6-networking/s6-networking-2.5.1.0.ebuild
new file mode 100644
index 000000000000..47a1748d6605
--- /dev/null
+++ b/net-misc/s6-networking/s6-networking-2.5.1.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Suite of small networking utilities for Unix systems"
+HOMEPAGE="https://www.skarnet.org/software/s6-networking/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~x86"
+IUSE="ssl static static-libs"
+
+REQUIRED_USE="static? ( static-libs )
+	ssl? ( !static !static-libs )"
+
+RDEPEND=">=dev-lang/execline-2.8.1.0:=[static-libs?]
+	>=dev-libs/skalibs-2.11.0.0:=[static-libs?]
+	>=sys-apps/s6-2.11.0.0:=[execline,static-libs?]
+	ssl? ( dev-libs/libretls )
+	!static? (
+		>=net-dns/s6-dns-2.3.5.2:=
+	)
+"
+DEPEND="${RDEPEND}
+	>=net-dns/s6-dns-2.3.5.2[static-libs?]
+"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--bindir=/bin
+		--dynlibdir=/usr/$(get_libdir)
+		--libdir=/usr/$(get_libdir)/${PN}
+		--with-dynlib=/usr/$(get_libdir)
+		--with-lib=/usr/$(get_libdir)/s6
+		--with-lib=/usr/$(get_libdir)/s6-dns
+		--with-lib=/usr/$(get_libdir)/skalibs
+		--with-sysdeps=/usr/$(get_libdir)/skalibs
+		--enable-shared
+		$(use_enable ssl ssl libtls)
+		$(use_enable static allstatic)
+		$(use_enable static static-libc)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myconf[@]}"
+}