media-libs/libzen: add 0.4.41

Closes: https://bugs.gentoo.org/903729
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/media-libs/libzen/Manifest b/media-libs/libzen/Manifest
index fcc36989acd1..3d3789c8f99d 100644
--- a/media-libs/libzen/Manifest
+++ b/media-libs/libzen/Manifest
@@ -1 +1,2 @@
 DIST libzen_0.4.39.tar.bz2 129816 BLAKE2B ff3ffe1b53234e567be12e86deb5dddd54584c112d297bd50764a980f4a3bcd51a08af630d482cca3157fcc9b8452f644807d6055d88420dcc6c311725ed402d SHA512 f261a676cbde9a877b85df536306a035ede1acdc5d827049698d19b3ecd8a65e5f6cfe66851fda034e1b31c95f6d6e82b78b0bc35989ec1568a010fb88a5a2d8
+DIST libzen_0.4.41.tar.bz2 129664 BLAKE2B 9e8f7fd77dfa0224c330a1c6c5e77e96e235b1119efc060ed9077d4dc00a6040c1ee8d8fba09f2bdb6bc9c964e3a4e703bd073d58d6a6366f84ff49f82102211 SHA512 a65bd9753a4d5676eaaf1c6d3e8d6fbd460b0dfee8a5a80708b3924ad1aa2ecfe0059b6d2c6f6e490a6367727f049cafd5d86fca584e11063cb1ca376e07e529
diff --git a/media-libs/libzen/libzen-0.4.41.ebuild b/media-libs/libzen/libzen-0.4.41.ebuild
new file mode 100644
index 000000000000..29ba280e9c20
--- /dev/null
+++ b/media-libs/libzen/libzen-0.4.41.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# These must be bumped together:
+# - media-libs/libzen (if a release is available)
+# - media-libs/libmediainfo
+# - media-video/mediainfo
+
+inherit autotools
+
+MY_PN="ZenLib"
+DESCRIPTION="Shared library for libmediainfo and mediainfo"
+HOMEPAGE="https://github.com/MediaArea/ZenLib"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.bz2"
+S="${WORKDIR}"/${MY_PN}/Project/GNU/Library
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc static-libs"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	default
+
+	sed -i 's:-O2::' configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-unicode \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+
+	if use doc ; then
+		cd "${WORKDIR}"/${MY_PN}/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	default
+
+	# remove since the pkgconfig file should be used instead
+	rm -f "${ED}"/usr/bin/libzen-config
+
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Format/Html Format/Http HTTP_Client ; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}/Source/${MY_PN}/${x}/*.h
+	done
+
+	dodoc "${WORKDIR}"/${MY_PN}/History.txt
+	if use doc ; then
+		docinto html
+		dodoc "${WORKDIR}"/${MY_PN}/Doc/*
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}