kde-apps/k3b: 20.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 121 insertions, 0 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index 87ddadfe939e..1599594254e4 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1,2 +1,3 @@
 DIST k3b-20.08.3.tar.xz 10684548 BLAKE2B bfb9a06fd5b9c023fe7a9c1c93fd2f473941906870f8face596617cf5bc2e26e258cc6adbe9fb7a99da0ed5bd9f09273168408133c8d6142bd42dc4779e2fa32 SHA512 0d068f10d8dd287a33ca672e780673b7f6a92c2071ea9ec22176ea4a9a210e205eb1b605ee23edca4d2e7eaefbe2dead04ef8b8ee29b690f38185e3caae14ba8
 DIST k3b-20.12.2.tar.xz 10685396 BLAKE2B 6ec804b26d02421f0e2fe78dfecc5a208d5a79727e4cc7519bade4af84cce2e0a4a7077c184b4e66bda802d006ac6b7bc6345430bf36ee99a779dbfb24c7068e SHA512 6d29cff9969fb09a54c0819f289f0dae5b31d84085d1fcc3c1d9f351db87563b9381d507cc3f2fe6f54b165b63f47d66ff23ebeab4d6ef32bbb520b6beb08a56
+DIST k3b-20.12.3.tar.xz 10688136 BLAKE2B aa2e8de78b98e33888f47454ca5b2edfb195915c000c5a6f94f6cf0bd89575d22b7c4efde1e307a91b61bab1087b2e5fa665bf2abcb28de178f236df1ec37758 SHA512 e0c85d4faa6749d271d92a945e54c68876582b7d5c5719682950ca9305b75d0a46226f080e9c0bac300e63e32387ebb034d48f6ddc3b2d1a4fa2487db53f4039
diff --git a/kde-apps/k3b/k3b-20.12.3.ebuild b/kde-apps/k3b/k3b-20.12.3.ebuild
new file mode 100644
index 000000000000..ca9977f28e15
--- /dev/null
+++ b/kde-apps/k3b/k3b-20.12.3.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.75.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/en/k3b https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="dvd encode ffmpeg flac mad mp3 musepack sndfile sox taglib vcd vorbis"
+
+REQUIRED_USE="
+	flac? ( taglib )
+	mp3? ( encode taglib )
+	sox? ( encode taglib )
+"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-apps/libkcddb-${PVCUT}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib?]
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	flac? ( >=media-libs/flac-1.2[cxx] )
+	mp3? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	app-cdr/cdrtools
+	dev-libs/libburn
+	media-sound/cdparanoia
+	dvd? (
+		>=app-cdr/dvd+rw-tools-7
+		encode? ( media-video/transcode[dvd] )
+	)
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	echo
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}