dev-ruby/unf_ext: add 0.0.7.4

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-ruby/unf_ext/unf_ext-0.0.7.4.ebuild b/dev-ruby/unf_ext/unf_ext-0.0.7.4.ebuild
new file mode 100644
index 000000000000..d3b2a42402af
--- /dev/null
+++ b/dev-ruby/unf_ext/unf_ext-0.0.7.4.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby21 ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_RECIPE_TEST="none"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+inherit ruby-fakegem multilib
+
+DESCRIPTION="Unicode Normalization Form support library for CRuby"
+HOMEPAGE="https://github.com/knu/ruby-unf_ext"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="doc test"
+
+ruby_add_bdepend "
+	test? (
+		>=dev-ruby/test-unit-2.5.1-r1
+	)"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/,/end/ s:^:#:' Rakefile test/helper.rb || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/unf_ext extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake -Cext/unf_ext CFLAGS="${CFLAGS} -fPIC" archflag="${LDFLAGS}" V=1
+	cp ext/unf_ext/*$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+	ruby-ng_testrb-2 test/test_*.rb
+}