dev-libs/feedbackd: add 0.1.1

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

2 files changed, 76 insertions, 0 deletions

diff --git a/dev-libs/feedbackd/Manifest b/dev-libs/feedbackd/Manifest
index 65d75ba64..45148ba51 100644
--- a/dev-libs/feedbackd/Manifest
+++ b/dev-libs/feedbackd/Manifest
@@ -1,2 +1,3 @@
 DIST feedbackd-v0.1.0.tar.bz2 75888 BLAKE2B a33d5161a1e83696a0d21a4487070abc7b31a1634cd6ca715bf489a29bf3e5c4f72b3838b87cde1e361df063ea829ca40083592681d46db2a324a7db1995dffb SHA512 e056dc3441318237f7faae7ceefbbcbc5a3078a622fad8a35265074c15d3236fc90932d38c32acb4ac1dcbefadc0548aec135caff7918d2979b1b5b1b6821aeb
+DIST feedbackd-v0.1.1.tar.bz2 76231 BLAKE2B 0ef5b501d8619cc1278d6469ffeb91b65303a5601387665606fb14a2edb83e7a0f2cc3be84e0fbe496f0f482fba6bb4d0c8444ee2c4356f7af787dff7a30cc64 SHA512 6f7ef65b156504665d4f0eba73c2b4209f4f3c8bd41a46e367a0dde4fbe9e1cabbc9e237a1b3bb399fba847c47717db11295766a34f8ba58cf8f32a07b333a80
 DIST gmobile-d483537aee4778b114ce5d50c4c8a9f8d58337ed.tar.bz2 20337 BLAKE2B f94295672ed699f308ccfab3835ed6c7f1184c0e267ea1c2ab7b6d59c98b3d027b300bf6d29db6442de20cec852f5c1031d1b09f220e94afc79c48566c160676 SHA512 86acabbffb1b5f98f2b132ce5bd12940769c11ed53d38401a0048216943a4b095bd230774d83444e7b5f5d26825f32ced0075dce7354f6fa486d47ef5f86b4f3
diff --git a/dev-libs/feedbackd/feedbackd-0.1.1.ebuild b/dev-libs/feedbackd/feedbackd-0.1.1.ebuild
new file mode 100644
index 000000000..69f16f01e
--- /dev/null
+++ b/dev-libs/feedbackd/feedbackd-0.1.1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit vala meson
+
+GMOBILE_COMMIT="d483537aee4778b114ce5d50c4c8a9f8d58337ed"
+DESCRIPTION="A daemon to provide haptic feedback on events"
+HOMEPAGE="https://source.puri.sm/Librem5/feedbackd"
+SRC_URI="
+	https://source.puri.sm/Librem5/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2
+	https://gitlab.gnome.org/guidog/gmobile/-/archive/${GMOBILE_COMMIT}.tar.bz2 -> gmobile-${GMOBILE_COMMIT}.tar.bz2
+"
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+SLOT="0"
+IUSE="+daemon gtk-doc +introspection man test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/glib:2
+	daemon? (
+		dev-libs/json-glib
+		dev-libs/libgudev
+		media-libs/gsound
+	)
+	introspection? ( dev-libs/gobject-introspection )
+"
+RDEPEND="${DEPEND}
+	dev-libs/feedbackd-device-themes
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+
+	if use daemon; then
+		rmdir "${S}/subprojects/gmobile" || die
+		mv "${WORKDIR}/gmobile-${GMOBILE_COMMIT}" "${S}/subprojects/gmobile" || die
+	fi
+
+	use vala && vala_setup
+	sed -i 's/-G feedbackd/-G video/g' debian/feedbackd.udev || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature introspection)
+		$(meson_use daemon)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/libfeedback-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}