sys-block/fio/fio-2.1.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-block/fio/fio-2.1.2.ebuild,v 1.3 2014/08/05 01:16:05 robbat2 Exp $

EAPI="5"

PYTHON_COMPAT=( python2_7 )
inherit eutils flag-o-matic python-r1 toolchain-funcs

MY_PV="${PV/_rc/-rc}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="Jens Axboe's Flexible IO tester"
HOMEPAGE="http://brick.kernel.dk/snaps/"
SRC_URI="http://brick.kernel.dk/snaps/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86"
IUSE="gtk"

DEPEND="dev-libs/libaio
	gtk? ( x11-libs/gtk+:2 )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	chmod g-w "${T}"
	sed -i \
		-e '/^DEBUGFLAGS/s, -D_FORTIFY_SOURCE=2,,g' \
		-e '/-o gfio/s/$(LIBS)/$(LDFLAGS) $(LIBS)/' \
		Makefile || die
	epatch_user
}

src_configure() {
	# not a real configure script
	./configure \
		--extra-cflags="${CFLAGS}" --cc="$(tc-getCC)" \
		$(use gtk && echo "--enable-gfio") || die 'configure failed'
}

src_compile() {
	append-flags -W
	emake V=1
}

src_install() {
	emake install DESTDIR="${D}" prefix="/usr" mandir="/usr/share/man"
	python_replicate_script "${ED}/usr/bin/fio2gnuplot.py"
	dodoc README REPORTING-BUGS HOWTO
	docinto examples
	dodoc examples/*
	doman fio.1
}