dev-util/bugle/bugle-0.0.20090801.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/bugle/bugle-0.0.20090801.ebuild,v 1.2 2010/01/08 15:05:33 ssuominen Exp $

EAPI="2"

inherit autotools eutils toolchain-funcs

DESCRIPTION="A tool for OpenGL debugging"
HOMEPAGE="http://www.opengl.org/sdk/tools/BuGLe/"
SRC_URI="mirror://sourceforge/bugle/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ffmpeg gtk readline"

DEPEND="ffmpeg? ( >=media-video/ffmpeg-0.5 )
	gtk? ( x11-libs/gtk+ x11-libs/gtkglext )
	readline? ( sys-libs/readline )
	virtual/opengl
	media-libs/glew
	sys-libs/ncurses"
RDEPEND="${DEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-asneeded.patch
	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_with ffmpeg lavc) \
		$(use_with readline) \
		$(use_with gtk) \
		$(use_with gtk gtkglext)
}

src_install() {
	dodoc README TODO NEWS doc/*.{txt,html} || die "dodoc failed"
	docinto examples
	dodoc doc/examples/* || die "dodoc failed"
	emake DESTDIR="${D}" install || die "emake install failed"
}

pkg_postinst() {
	elog "See man 3 bugle for an introduction to BuGLe."
}