dev-python/cosmolopy/cosmolopy-0.1.104-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/cosmolopy/cosmolopy-0.1.104-r1.ebuild,v 1.2 2015/03/06 22:12:51 pacho Exp $

EAPI=5

PYTHON_COMPAT=( python2_7)

inherit distutils-r1

MY_PN=CosmoloPy
MY_P=${MY_PN}-${PV}

DESCRIPTION="Cosmology routines built on NumPy/SciPy"
HOMEPAGE="http://roban.github.com/CosmoloPy/ http://pypi.python.org/pypi/CosmoloPy"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc"

DEPEND="dev-python/nose[${PYTHON_USEDEP}]
	dev-lang/swig
	doc? ( dev-python/epydoc[${PYTHON_USEDEP}] )"
RDEPEND="sci-libs/scipy[${PYTHON_USEDEP}]"

S=${WORKDIR}/${MY_P}

python_compile_all() {
	if use doc; then
		epydoc -n "CosmoloPy - Cosmology routines built on NumPy/SciPy" \
			--exclude='cosmolopy.EH._power' --exclude='cosmolopy.EH.power' \
			--no-private --no-frames --html --docformat restructuredtext \
			cosmolopy/ -o docAPI/ || die
	fi
}

python_install_all() {
	use doc && local HTML_DOCS=( docAPI/. )
	distutils-r1_python_install_all
}