1 files changed, 64 insertions, 0 deletions
diff --git a/sys-apps/iproute2/iproute2-2.6.7.20040608.ebuild b/sys-apps/iproute2/iproute2-2.6.7.20040608.ebuild
new file mode 100644
index 000000000000..03e622acdae6
--- /dev/null
+++ b/sys-apps/iproute2/iproute2-2.6.7.20040608.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2004 Gentoo Technologies, Inc.
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-2.6.7.20040608.ebuild,v 1.1 2004/06/22 03:00:50 vapier Exp $
+
+inherit eutils
+
+MY_PV="${PV:0:5}"
+SNAP="${PV:${#PV}-6}"
+DESCRIPTION="kernel routing and traffic control utilities"
+HOMEPAGE="http://developer.osdl.org/dev/iproute2/"
+SRC_URI="http://developer.osdl.org/dev/iproute2/download/${PN}-${MY_PV}-ss${SNAP}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~ppc ~sparc ~mips ~alpha ~arm ~hppa ~amd64 ~ia64"
+IUSE="atm"
+
+RDEPEND="virtual/glibc
+	sys-libs/db
+	atm? ( net-dialup/linux-atm )"
+DEPEND="${RDEPEND}
+	>=virtual/os-headers-2.4.21
+	>=sys-apps/sed-4"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	# Enable HFSC scheduler #45274
+	if [ ! -z "`grep tc_service_curve ${ROOT}/usr/include/linux/pkt_sched.h`" ] ; then
+		epatch ${FILESDIR}/2.4.7.20020116-hfsc.patch
+	else
+		ewarn "Your linux-headers in /usr/include/linux are too old to"
+		ewarn "support the HFSC scheduler.  It has been disabled."
+	fi
+
+	# Fix cflags and db code
+	sed -i \
+		-e 's:-I/usr/include/db3::g' \
+		-e "s:-O2:${CFLAGS}:g" \
+		Makefile || die "sed Makefile failed"
+	sed -i 's:-ldb-4\.1:-ldb:' misc/Makefile || die "sed misc/Makefile failed"
+	sed -i 's:db41/db_185:db_185:' misc/arpd.c || die "sed misc/arpd.c failed"
+
+	# Enable diffserv/atm support
+	if use atm ; then
+		sed -i 's:=n$:=y:' Config || die "sed Config failed"
+	fi
+}
+
+src_compile() {
+	emake KERNEL_INCLUDE=/usr/include || die
+}
+
+src_install() {
+	make install DESTDIR=${D} DOCDIR=/usr/share/doc/${PF} || die "make install failed"
+
+	into /
+	dosbin ip/{ifcfg,rtpr} || die "dosbin failed"
+
+	doman man/*/*
+}