1 files changed, 83 insertions, 0 deletions
diff --git a/dev-util/gtk-doc/gtk-doc-1.10-r2.ebuild b/dev-util/gtk-doc/gtk-doc-1.10-r2.ebuild
new file mode 100644
index 000000000000..4f755c5e2e70
--- /dev/null
+++ b/dev-util/gtk-doc/gtk-doc-1.10-r2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/gtk-doc/gtk-doc-1.10-r2.ebuild,v 1.1 2008/06/06 14:57:39 remi Exp $
+
+inherit eutils elisp-common gnome2
+
+DESCRIPTION="GTK+ Documentation Generator"
+HOMEPAGE="http://www.gtk.org/gtk-doc/"
+
+LICENSE="GPL-2 FDL-1.1"
+SLOT="0"
+KEYWORDS="alpha amd64 ~arm ~hppa ~ia64 ~m68k ~mips ppc ~ppc64 ~s390 ~sh sparc ~sparc-fbsd x86 ~x86-fbsd"
+IUSE="doc emacs"
+
+RDEPEND=">=dev-lang/perl-5.6
+	>=app-text/openjade-1.3.1
+	dev-libs/libxslt
+	>=dev-libs/libxml2-2.3.6
+	~app-text/docbook-xml-dtd-4.1.2
+	app-text/docbook-xsl-stylesheets
+	~app-text/docbook-sgml-dtd-3.0
+	>=app-text/docbook-dsssl-stylesheets-1.40
+	emacs? ( virtual/emacs )"
+
+DEPEND="${RDEPEND}
+	=dev-util/gtk-doc-am-${PV}*
+	>=dev-util/pkgconfig-0.19
+	>=app-text/scrollkeeper-0.3.5"
+
+SITEFILE=61${PN}-gentoo.el
+
+DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README TODO"
+
+# Revisit this in next version. Might be related to upstream bug 521784 and/or 485806
+RESTRICT="test"
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# Remove global Emacs keybindings.
+	epatch "${FILESDIR}"/${PN}-1.8-emacs-keybindings.patch
+
+	# Don't install gtk-doc.m4; it's in gtk-doc-am now
+	epatch "${FILESDIR}"/${PN}-1.10-no-m4.patch
+
+	# Don't install the gnome/yelp help files (bug #224519)
+	sed -e "s/SUBDIRS = manual//" -i help/Makefile.in
+}
+
+src_compile() {
+	gnome2_src_compile
+
+	use emacs && elisp-compile tools/gtk-doc.el
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use doc; then
+		docinto doc
+		dodoc doc/*
+		docinto examples
+		dodoc examples/*
+	fi
+
+	if use emacs; then
+		elisp-install ${PN} tools/gtk-doc.el*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	if use emacs; then
+		elisp-site-regen
+		elog "gtk-doc does no longer define global key bindings for Emacs."
+		elog "You may set your own key bindings for \"gtk-doc-insert\" and"
+		elog "\"gtk-doc-insert-section\" in your ~/.emacs file."
+	fi
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}