Version bump with various bugfixes.

Package-Manager: portage-2.2.0_alpha95/cvs/Linux x86_64

4 files changed, 188 insertions, 2 deletions

diff --git a/x11-libs/gdk-pixbuf/ChangeLog b/x11-libs/gdk-pixbuf/ChangeLog
index c765841de652..f9468ba9dbb8 100644
--- a/x11-libs/gdk-pixbuf/ChangeLog
+++ b/x11-libs/gdk-pixbuf/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/gdk-pixbuf
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/gdk-pixbuf/ChangeLog,v 1.45 2012/02/04 18:25:49 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/gdk-pixbuf/ChangeLog,v 1.46 2012/03/27 04:45:56 tetromino Exp $
+
+*gdk-pixbuf-2.26.0 (27 Mar 2012)
+
+  27 Mar 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +gdk-pixbuf-2.26.0.ebuild:
+  Version bump with various bugfixes.
 
   04 Feb 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
   gdk-pixbuf-2.24.0-r1.ebuild:
diff --git a/x11-libs/gdk-pixbuf/gdk-pixbuf-2.26.0.ebuild b/x11-libs/gdk-pixbuf/gdk-pixbuf-2.26.0.ebuild
new file mode 100644
index 000000000000..c305fdc576ab
--- /dev/null
+++ b/x11-libs/gdk-pixbuf/gdk-pixbuf-2.26.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/gdk-pixbuf/gdk-pixbuf-2.26.0.ebuild,v 1.1 2012/03/27 04:45:56 tetromino Exp $
+
+EAPI="4"
+
+inherit gnome.org multilib libtool autotools
+
+DESCRIPTION="Image loading library for GTK+"
+HOMEPAGE="http://www.gtk.org/"
+
+LICENSE="LGPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+X debug doc +introspection jpeg jpeg2k tiff test"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.31.0:2
+	>=media-libs/libpng-1.4:0
+	introspection? ( >=dev-libs/gobject-introspection-0.9.3 )
+	jpeg? ( virtual/jpeg )
+	jpeg2k? ( media-libs/jasper )
+	tiff? ( >=media-libs/tiff-3.9.2:0 )
+	X? ( x11-libs/libX11 )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/pkgconfig-0.9
+	>=sys-apps/coreutils-8.5
+	>=sys-devel/gettext-0.17
+	>=dev-util/gtk-doc-am-1.11
+	doc? (
+		>=dev-util/gtk-doc-1.11
+		~app-text/docbook-xml-dtd-4.1.2 )"
+# librsvg blocker is for the new pixbuf loader API, you lose icons otherwise
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gail-1000
+	!<gnome-base/librsvg-2.31.0
+	!<x11-libs/gtk+-2.21.3:2
+	!<x11-libs/gtk+-2.90.4:3"
+
+src_prepare() {
+	# This will avoid polluting the pkg-config file with versioned libpng,
+	# which is causing problems with libpng14 -> libpng15 upgrade
+	# See upstream bug #667068
+	sed -i -e 's:libpng15:libpng libpng15:' configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	# png always on to display icons (foser)
+	local myconf="
+		$(use_enable doc gtk-doc)
+		$(use_with jpeg libjpeg)
+		$(use_with jpeg2k libjasper)
+		$(use_with tiff libtiff)
+		$(use_enable introspection)
+		$(use_with X x11)
+		--with-libpng"
+
+	# Passing --disable-debug is not recommended for production use
+	use debug && myconf="${myconf} --enable-debug=yes"
+
+	econf ${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS NEWS* README*
+
+	# New library, remove .la files
+	find "${D}" -name '*.la' -exec rm -f '{}' + || die
+}
+
+pkg_postinst() {
+	# causes segfault if set, see bug 375615
+	unset __GL_NO_DSO_FINALIZER
+
+	tmp_file=$(mktemp --suffix=gdk_pixbuf_ebuild)
+	# be atomic!
+	gdk-pixbuf-query-loaders > "${tmp_file}"
+	if [ "${?}" = "0" ]; then
+		cat "${tmp_file}" > "${EROOT}usr/$(get_libdir)/gdk-pixbuf-2.0/2.10.0/loaders.cache"
+	else
+		ewarn "Cannot update loaders.cache, gdk-pixbuf-query-loaders failed to run"
+	fi
+	rm "${tmp_file}"
+
+	if [ -e "${EROOT}"usr/lib/gtk-2.0/2.*/loaders ]; then
+		elog "You need to rebuild ebuilds that installed into" "${EROOT}"usr/lib/gtk-2.0/2.*/loaders
+		elog "to do that you can use qfile from portage-utils:"
+		elog "emerge -va1 \$(qfile -qC ${EPREFIX}/usr/lib/gtk-2.0/2.*/loaders)"
+	fi
+}
diff --git a/x11-libs/pango/ChangeLog b/x11-libs/pango/ChangeLog
index 1fbf13d85315..a1595842a7a7 100644
--- a/x11-libs/pango/ChangeLog
+++ b/x11-libs/pango/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/pango
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/pango/ChangeLog,v 1.336 2012/03/25 15:48:14 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/pango/ChangeLog,v 1.337 2012/03/27 04:45:39 tetromino Exp $
+
+*pango-1.30.0 (27 Mar 2012)
+
+  27 Mar 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +pango-1.30.0.ebuild:
+  Version bump with various bugfixes.
 
   25 Mar 2012; Markus Meier <maekke@gentoo.org> pango-1.29.4.ebuild:
   arm stable, bug #407643
diff --git a/x11-libs/pango/pango-1.30.0.ebuild b/x11-libs/pango/pango-1.30.0.ebuild
new file mode 100644
index 000000000000..6ad15dc80c16
--- /dev/null
+++ b/x11-libs/pango/pango-1.30.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/pango/pango-1.30.0.ebuild,v 1.1 2012/03/27 04:45:39 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit autotools eutils gnome2 multilib toolchain-funcs
+
+DESCRIPTION="Internationalized text layout and rendering library"
+HOMEPAGE="http://www.pango.org/"
+
+LICENSE="LGPL-2 FTL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+
+IUSE="X doc +introspection test"
+
+# Upstream bug #643802
+REQUIRED_USE="doc? ( X )"
+
+RDEPEND=">=dev-libs/glib-2.31.0:2
+	>=media-libs/fontconfig-2.5.0:1.0
+	media-libs/freetype:2
+	>=x11-libs/cairo-1.7.6[X?]
+	X? (
+		x11-libs/libXrender
+		x11-libs/libX11
+		>=x11-libs/libXft-2.0.0 )"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/gtk-doc-am-1.13
+	doc? (
+		>=dev-util/gtk-doc-1.13
+		~app-text/docbook-xml-dtd-4.1.2
+		x11-libs/libXft )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+	test? (
+		>=dev-util/gtk-doc-1.13
+		~app-text/docbook-xml-dtd-4.1.2
+		x11-libs/libXft )
+	X? ( x11-proto/xproto )
+	!<=sys-devel/autoconf-2.63:2.5"
+
+function multilib_enabled() {
+	has_multilib_profile || ( use x86 && [ "$(get_libdir)" = "lib32" ] )
+}
+
+pkg_setup() {
+	tc-export CXX
+	G2CONF="${G2CONF}
+		$(use_enable introspection)
+		$(use_with X x)
+		$(use X && echo --x-includes=${EPREFIX}/usr/include)
+		$(use X && echo --x-libraries=${EPREFIX}/usr/$(get_libdir))"
+	DOCS="AUTHORS ChangeLog* NEWS README THANKS"
+}
+
+src_prepare() {
+	# make config file location host specific so that a 32bit and 64bit pango
+	# wont fight with each other on a multilib system.  Fix building for
+	# emul-linux-x86-gtklibs
+	if multilib_enabled ; then
+		epatch "${FILESDIR}/${PN}-1.26.0-lib64.patch"
+		eautoreconf
+	fi
+
+	gnome2_src_prepare
+}
+
+pkg_postinst() {
+	einfo "Generating modules listing..."
+
+	local PANGO_CONFDIR="${EROOT}/etc/pango"
+	multilib_enabled && PANGO_CONFDIR+="/${CHOST}"
+
+	mkdir -p "${PANGO_CONFDIR}"
+	pango-querymodules \
+		"${EROOT}"usr/$(get_libdir)/pango/1.6.0/modules/*.so \
+		> "${PANGO_CONFDIR}"/pango.modules
+}