Version bump for dev channel release.

Package-Manager: portage-2.2_rc83/cvs/Linux x86_64

3 files changed, 233 insertions, 2 deletions

diff --git a/www-client/chromium/ChangeLog b/www-client/chromium/ChangeLog
index cd9be57fad88..b3dfb806be3d 100644
--- a/www-client/chromium/ChangeLog
+++ b/www-client/chromium/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.175 2010/09/15 01:34:46 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.176 2010/09/17 09:26:32 voyageur Exp $
+
+*chromium-7.0.517.8 (17 Sep 2010)
+
+  17 Sep 2010; Bernard Cafarelli <voyageur@gentoo.org>
+  +chromium-7.0.517.8.ebuild:
+  Version bump for dev channel release.
 
 *chromium-6.0.472.59-r1 (15 Sep 2010)
 *chromium-6.0.472.59 (15 Sep 2010)
diff --git a/www-client/chromium/Manifest b/www-client/chromium/Manifest
index 4c1bed85d57e..2aa4a10ea87d 100644
--- a/www-client/chromium/Manifest
+++ b/www-client/chromium/Manifest
@@ -15,11 +15,13 @@ DIST chromium-5.0.375.127.tar.bz2 163270882 RMD160 c1ebb4c214299de291067e6afd430
 DIST chromium-6.0.472.59.tar.bz2 123988791 RMD160 90ea863301b6f65d9559749ff77287cfbc39f3f0 SHA1 6f46e63f24d7540ea86b066ee55351fe775a1f0f SHA256 90473e06242ba52c2e73f2a9729ad830e2baac0af1b2823e3b25ef0c83031999
 DIST chromium-7.0.503.1.tar.bz2 127233310 RMD160 4d99a7fb8a30e4c97b972f2685f759da5d23b1af SHA1 f7613b4a078ca0ed8924173d994700b6cbdb2210 SHA256 17acda2dd849d1dee5f575847880b4d2b1ff21dfe6f0ae5c3ec00d30e23afc09
 DIST chromium-7.0.517.5.tar.bz2 231754066 RMD160 bf509acf62b8bc17ce52d28bfd8f84f9a0458d2f SHA1 66cebd7354b32e6b23d7ecf6b5bd8bc6a819b86b SHA256 c81651852b6fe6e70004e7e52ee287b2913a0a4ef8794bfbce2a67e0886df6f4
+DIST chromium-7.0.517.8.tar.bz2 231773965 RMD160 da5e1ea0b3098632636420e40e8b14117f295fed SHA1 d0b7b91db874567ea9b1282f52ea55e79341dc03 SHA256 4469ae174e025799ff428aea13030b7bdbc977da9be8d870d411cc9597ddac08
 EBUILD chromium-5.0.375.127.ebuild 5388 RMD160 8fbd9d9c5fd250c34264b0d1df47dae7032f6d73 SHA1 da2b6074d41cb77cc3714f7347268d036bfc2aa3 SHA256 a0d5a008691c43c773825310bb52872cbefe57e76e5cc986055e290d1a0029cb
 EBUILD chromium-6.0.472.59-r1.ebuild 6917 RMD160 abf00e9b1c778758f671f549b2bceb02ca5f94ea SHA1 4ce94a4d7b51bb0bc752abb22c11f5e6612b959b SHA256 b1840eaee55d9fb7e7fd8d63e0287938d4b639fbf9c9fc47b8e9ea44d60e91e9
 EBUILD chromium-6.0.472.59.ebuild 6915 RMD160 c04bbc7220d98ae587b3637ce14664dcf46a4c2d SHA1 3cc3e801eb2dd13938f7bec896fa9512ba0cd72f SHA256 6b741c25bb699291b19a1511ac0f69067f591f47b5fb9cadec86230cfd2cc2c2
 EBUILD chromium-7.0.503.1-r1.ebuild 6652 RMD160 738f3510cda8926a65e5730e3a48d86bf91edf13 SHA1 a37e00e2068e5f9cdc58a4cafbbe82b6ff12f1b8 SHA256 466b49a9610841e9e6d56b0afd4598205a3bd8606f76a9c3e94ca3f82d2576c6
 EBUILD chromium-7.0.517.5.ebuild 6634 RMD160 a1644de208689e249b6d070a36625ded6a03f72d SHA1 929d9405865c35d674b199b45905e9558c194a49 SHA256 18282f118aeaade09e24c7b6111eb642310b733a0da01166fa6a8d25e0847455
+EBUILD chromium-7.0.517.8.ebuild 6632 RMD160 77207e598415c315cf80d8f20611eea6812c685c SHA1 8539942e0e3bf49a4c50ee627d9fe109b0bf6ed8 SHA256 1b56f3d1e28d4321a62c4bd81013ebc60d7deb856110e6dfb08fa99ee4487753
 EBUILD chromium-9999.ebuild 8391 RMD160 989c626b39c7fafebfa5e6e0abebe71f284c87e0 SHA1 13a1606fb5e10c5e5a10304ba44626b2cc1f6176 SHA256 b917787bd50e1e8419adfabf008924eb17af95909a817ad1ccb9d73dc0644753
-MISC ChangeLog 38992 RMD160 133096d9dbe672a0b57d31262da556aa604f69e3 SHA1 6aecf95eee8a9c7156f3c8096c86b9243b889cc2 SHA256 99f882cda0a5b2b0848f94a1e27a46ce2e951fbecaebcc1479fdf295f90b1d3c
+MISC ChangeLog 39151 RMD160 a4e43999938044a4abce391d430657648e4eec23 SHA1 a3799651c19fb3a3ede21d5ab5a1fa25338d848e SHA256 158440360e52185357a72395f68403e13c5e104a3e303a352e05b1c0e15ec9c9
 MISC metadata.xml 378 RMD160 3309b2d1fb60157d0da1e22070ba3c448bd46b74 SHA1 0a8d13bb94e9836a14255b724b738c5df1f8ed7e SHA256 7d02fdca1b3c68d1202c720f1987713c28e38b1f9f3e30cbc3138c000572f08e
diff --git a/www-client/chromium/chromium-7.0.517.8.ebuild b/www-client/chromium/chromium-7.0.517.8.ebuild
new file mode 100644
index 000000000000..9f14b29f2204
--- /dev/null
+++ b/www-client/chromium/chromium-7.0.517.8.ebuild
@@ -0,0 +1,223 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.517.8.ebuild,v 1.1 2010/09/17 09:26:32 voyageur Exp $
+
+EAPI="2"
+
+inherit eutils flag-o-matic multilib pax-utils toolchain-funcs
+
+DESCRIPTION="Open-source version of Google Chrome web browser"
+HOMEPAGE="http://chromium.org/"
+SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="cups gnome gnome-keyring sse2"
+
+RDEPEND="app-arch/bzip2
+	>=dev-libs/icu-4.4.1
+	>=dev-libs/libevent-1.4.13
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-libs/nss-3.12.3
+	>=gnome-base/gconf-2.24.0
+	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
+	>=media-libs/alsa-lib-1.0.19
+	media-libs/jpeg:0
+	media-libs/libpng
+	cups? ( >=net-print/cups-1.4.4 )
+	sys-libs/zlib
+	>=x11-libs/gtk+-2.14.7
+	x11-libs/libXScrnSaver"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	>=dev-util/gperf-3.0.3
+	>=dev-util/pkgconfig-0.23
+	sys-devel/flex"
+RDEPEND+="
+	|| (
+		x11-themes/gnome-icon-theme
+		x11-themes/oxygen-molecule
+		x11-themes/tango-icon-theme
+		x11-themes/xfce4-icon-theme
+	)
+	x11-apps/xmessage
+	x11-misc/xdg-utils
+	virtual/ttf-fonts"
+
+remove_bundled_lib() {
+	einfo "Removing bundled library $1 ..."
+	local out
+	out="$(find $1 -mindepth 1 \! -iname '*.gyp' -print -delete)" \
+		|| die "failed to remove bundled library $1"
+	if [[ -z $out ]]; then
+		die "no files matched when removing bundled library $1"
+	fi
+}
+
+pkg_setup() {
+	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"
+}
+
+src_prepare() {
+	# Add Gentoo plugin paths.
+	epatch "${FILESDIR}"/${PN}-plugins-path-r0.patch
+
+	# Make compile-time dependency on gnome-keyring optional, bug #332411.
+	epatch "${FILESDIR}"/${PN}-gnome-keyring-r0.patch
+
+	remove_bundled_lib "third_party/bzip2"
+	remove_bundled_lib "third_party/codesighs"
+	remove_bundled_lib "third_party/cros"
+	remove_bundled_lib "third_party/icu"
+	remove_bundled_lib "third_party/jemalloc"
+	remove_bundled_lib "third_party/lcov"
+	remove_bundled_lib "third_party/libevent"
+	remove_bundled_lib "third_party/libjpeg"
+	remove_bundled_lib "third_party/libpng"
+	remove_bundled_lib "third_party/libxml"
+	remove_bundled_lib "third_party/libxslt"
+	remove_bundled_lib "third_party/lzma_sdk"
+	remove_bundled_lib "third_party/molokocacao"
+	remove_bundled_lib "third_party/ocmock"
+	remove_bundled_lib "third_party/pyftpdlib"
+	remove_bundled_lib "third_party/simplejson"
+	remove_bundled_lib "third_party/tlslite"
+	# TODO: also remove third_party/zlib. For now the compilation fails if we
+	# remove it (minizip-related).
+}
+
+src_configure() {
+	local myconf=""
+
+	# Make it possible to build chromium on non-sse2 systems.
+	if use sse2; then
+		myconf+=" -Ddisable_sse2=0"
+	else
+		myconf+=" -Ddisable_sse2=1"
+	fi
+
+	# Use system-provided libraries.
+	# TODO: use_system_ffmpeg (http://crbug.com/50678).
+	# TODO: use_system_sqlite (http://crbug.com/22208).
+	# TODO: use_system_hunspell (upstream changes needed).
+	# TODO: use_system_ssl when we have a recent enough system NSS.
+	myconf+="
+		-Duse_system_bzip2=1
+		-Duse_system_icu=1
+		-Duse_system_libevent=1
+		-Duse_system_libjpeg=1
+		-Duse_system_libpng=1
+		-Duse_system_libxml=1
+		-Duse_system_zlib=1"
+
+	# The dependency on cups is optional, see bug #324105.
+	if use cups; then
+		myconf+=" -Duse_cups=1"
+	else
+		myconf+=" -Duse_cups=0"
+	fi
+
+	if use "gnome-keyring"; then
+		myconf+=" -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
+	else
+		# TODO: we should also disable code trying to dlopen
+		# gnome-keyring in that case.
+		myconf+=" -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
+	fi
+
+	# Enable sandbox.
+	myconf+="
+		-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
+		-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
+
+	# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
+	# and the performance gain isn't worth it.
+	myconf+=" -Dv8_use_snapshot=0"
+
+	# Disable tcmalloc memory allocator. It causes problems,
+	# for example bug #320419.
+	myconf+=" -Dlinux_use_tcmalloc=0"
+
+	# Use target arch detection logic from bug #296917.
+	local myarch="$ABI"
+	[[ $myarch = "" ]] && myarch="$ARCH"
+
+	if [[ $myarch = amd64 ]] ; then
+		myconf+=" -Dtarget_arch=x64"
+	elif [[ $myarch = x86 ]] ; then
+		myconf+=" -Dtarget_arch=ia32"
+	elif [[ $myarch = arm ]] ; then
+		# TODO: check this again after
+		# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
+		append-flags -fno-tree-sink
+
+		myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
+	else
+		die "Failed to determine target arch, got '$myarch'."
+	fi
+
+	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
+		myconf+=" -Dno_strict_aliasing=1 -Dgcc_version=44"
+	fi
+
+	# Work around a likely GCC bug, see bug #331945.
+	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "45" ]]; then
+		append-flags -fno-ipa-cp
+	fi
+
+	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
+	# Depending on GCC version the warnings are different and we don't want
+	# the build to fail because of that.
+	myconf+=" -Dwerror="
+
+	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die
+}
+
+src_compile() {
+	emake -r V=1 chrome chrome_sandbox BUILDTYPE=Release \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		AR="$(tc-getAR)" \
+		RANLIB="$(tc-getRANLIB)" \
+		|| die
+}
+
+src_install() {
+	exeinto "${CHROMIUM_HOME}"
+	pax-mark m out/Release/chrome
+	doexe out/Release/chrome
+	doexe out/Release/chrome_sandbox || die
+	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
+	doexe out/Release/xdg-settings || die
+	doexe "${FILESDIR}"/chromium-launcher.sh || die
+
+	insinto "${CHROMIUM_HOME}"
+	doins out/Release/chrome.pak || die
+	doins out/Release/resources.pak || die
+
+	doins -r out/Release/locales || die
+	doins -r out/Release/resources || die
+
+	# chrome.1 is for chromium --help
+	newman out/Release/chrome.1 chrome.1 || die
+	newman out/Release/chrome.1 chromium.1 || die
+
+	doexe out/Release/ffmpegsumo_nolink || die
+	doexe out/Release/libffmpegsumo.so || die
+
+	# Install icon and desktop entry.
+	newicon out/Release/product_logo_48.png ${PN}-browser.png || die
+	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
+	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser" \
+		"MimeType=text/html;text/xml;application/xhtml+xml;"
+	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop || die
+
+	# Install GNOME default application entry (bug #303100).
+	if use gnome; then
+		dodir /usr/share/gnome-control-center/default-apps || die
+		insinto /usr/share/gnome-control-center/default-apps
+		doins "${FILESDIR}"/chromium.xml || die
+	fi
+}