Fix bug 408196.

Package-Manager: portage-2.2.0_alpha92/cvs/Linux x86_64

3 files changed, 283 insertions, 5 deletions

diff --git a/sys-boot/grub/ChangeLog b/sys-boot/grub/ChangeLog
index eb021250d098..b2faee683009 100644
--- a/sys-boot/grub/ChangeLog
+++ b/sys-boot/grub/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-boot/grub
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.190 2012/03/18 06:41:10 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.191 2012/03/20 03:29:08 floppym Exp $
+
+*grub-2.00_beta2-r1 (20 Mar 2012)
+
+  20 Mar 2012; Mike Gilbert <floppym@gentoo.org> +grub-2.00_beta2-r1.ebuild:
+  Fix bug 408196.
 
   18 Mar 2012; Mike Gilbert <floppym@gentoo.org> grub-2.00_beta2.ebuild,
   grub-9999.ebuild:
diff --git a/sys-boot/grub/Manifest b/sys-boot/grub/Manifest
index 13e55519dbd3..f57b7168c407 100644
--- a/sys-boot/grub/Manifest
+++ b/sys-boot/grub/Manifest
@@ -47,14 +47,15 @@ EBUILD grub-0.97.ebuild 4238 RMD160 498e38af891b8e1a147356f4e1c97ca12c2a6429 SHA
 EBUILD grub-1.99-r2.ebuild 8285 RMD160 2b6ae9f59dda41f0893438c9c03e7ad9b0c2e7d9 SHA1 8aaae86ab3ae0092e3c343e7fd1fd58d0d19dac3 SHA256 783fad22b5cae394862725d5eaeed80ad7a26dcce833f65fed0b3135858ae171
 EBUILD grub-2.00_beta0.ebuild 5993 RMD160 88832dcfd48236a47039c12c89c0099f2033b1de SHA1 9453ac5ec45265ddf5be0003e4e858757f00f6de SHA256 ff8d30de025e10e061f47097d502501e628c146ea2ce8d91b2b1bbf04ffb52ef
 EBUILD grub-2.00_beta1.ebuild 5837 RMD160 7269e69d2c57d79f3299dded2b9ac26c9c625e10 SHA1 d3b629db5ae54b3f8e9e168bcca51949e54a6136 SHA256 9b159e68d77c414e5b8e131ab3b18fe009e116ec78a7721a267f1ddd0bf91db9
+EBUILD grub-2.00_beta2-r1.ebuild 6560 RMD160 839b499f634a2123af357694cbab151822ee4818 SHA1 4dbb9017e56de9781e340a1d5c519d457f62399a SHA256 f62c3296bbbe91d0dfcc10628446e835f485dbd96db4127761a22ffcf48760cf
 EBUILD grub-2.00_beta2.ebuild 6476 RMD160 43557ca6eb3e61f66fe4d8c2977d9ac1e4db2d96 SHA1 0d7d68e9869b646275d28e1acd3badbe80b33559 SHA256 d60330fd91721d586fe4254bbaa02add8accc2ea729fff1c376aa544ed4f96ca
 EBUILD grub-9999.ebuild 6471 RMD160 44a6134970c488856e0df8f637e99768bdb00181 SHA1 c3c8c14032951bcc8a2350f97674e2156476c972 SHA256 d7ea52eca2b187d6d256bade46e0ba30def79e7d416c3ced1c63a72f4b308a4b
-MISC ChangeLog 38543 RMD160 c742dc7225d95c749bf5b240ef47558b3f9c42c8 SHA1 2d2db8eb6ac68018a9c4cd083a1e136f8acc59e9 SHA256 82931f80ca3c43e1787000e6bcb3ff472ccf1d90ce9c521a700cb24e84e6ec02
+MISC ChangeLog 38674 RMD160 e8da22ce682dbc90d1c20145bc13551dd058ff49 SHA1 5bd577fdc7d07670a96676e80d395af9383eeabf SHA256 9ec67094fb119b0795228628b93f5fcbd4b6f0a50c044a39a81e925b34674d52
 MISC metadata.xml 673 RMD160 2181a768c776eed3e76c3604a2a0c03be360aa06 SHA1 0434ff5fb3b8702ca4a4661240ed08cfb06c529c SHA256 e14e5e46b726a3645b85217a2afbd5b04adb54990c7db837e01a50a8322d81b9
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iF4EAREIAAYFAk9lg40ACgkQC77qH+pIQ6Qh0wEAmChN5DZMhzDghTYjhXl0/RUy
-GaSlktemV5LjQ/7wcHEBAIcE86C2eZ9cahNjw1uAeP0o4Jg3nVnLISt1l3eA/ZFO
-=tEKX
+iF4EAREIAAYFAk9n+YkACgkQC77qH+pIQ6SSZQEAps+3t6CLquFtVVFzL3Gjy36E
+KB5LErfox10DRfBee18BAMO3UbKikCZmjw0l79vdvKniSAQXyrg5GyRhn28xfX5/
+=RHZE
 -----END PGP SIGNATURE-----
diff --git a/sys-boot/grub/grub-2.00_beta2-r1.ebuild b/sys-boot/grub/grub-2.00_beta2-r1.ebuild
new file mode 100644
index 000000000000..f556c96c7462
--- /dev/null
+++ b/sys-boot/grub/grub-2.00_beta2-r1.ebuild
@@ -0,0 +1,272 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.00_beta2-r1.ebuild,v 1.1 2012/03/20 03:29:08 floppym Exp $
+
+EAPI=4
+
+if [[ ${PV} == "9999" ]] ; then
+	EBZR_REPO_URI="http://bzr.savannah.gnu.org/r/grub/trunk/grub/"
+	LIVE_ECLASS="bzr"
+	SRC_URI=""
+	DO_AUTORECONF="true"
+else
+	MY_P=${P/_/\~}
+	if [[ ${PV} == *_alpha* || ${PV} == *_beta* ]]; then
+		SRC_URI="mirror://gnu-alpha/${PN}/${MY_P}.tar.xz"
+	else
+		SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.xz
+		mirror://gentoo/${MY_P}.tar.xz"
+	fi
+	# Masked until documentation guys consolidate the guide and approve
+	# it for usage.
+	#KEYWORDS="~amd64 ~mips ~x86"
+	S=${WORKDIR}/${MY_P}
+fi
+
+inherit eutils flag-o-matic pax-utils toolchain-funcs ${DO_AUTORECONF:+autotools} ${LIVE_ECLASS}
+unset LIVE_ECLASS
+
+DESCRIPTION="GNU GRUB boot loader"
+HOMEPAGE="http://www.gnu.org/software/grub/"
+
+LICENSE="GPL-3"
+SLOT="2"
+IUSE="custom-cflags debug device-mapper efiemu mount nls static sdl truetype libzfs"
+
+GRUB_PLATFORMS=(
+	# everywhere:
+	emu
+	# mips only:
+	qemu-mips yeeloong
+	# amd64, x86, ppc, ppc64:
+	ieee1275
+	# amd64, x86:
+	coreboot multiboot efi-32 pc qemu
+	# amd64, ia64:
+	efi-64
+)
+IUSE+=" ${GRUB_PLATFORMS[@]/#/grub_platforms_}"
+
+# os-prober: Used on runtime to detect other OSes
+# xorriso (dev-libs/libisoburn): Used on runtime for mkrescue
+RDEPEND="
+	dev-libs/libisoburn
+	dev-libs/lzo
+	sys-boot/os-prober
+	>=sys-libs/ncurses-5.2-r5
+	debug? (
+		sdl? ( media-libs/libsdl )
+	)
+	device-mapper? ( >=sys-fs/lvm2-2.02.45 )
+	libzfs? ( sys-fs/zfs )
+	mount? ( sys-fs/fuse )
+	truetype? ( media-libs/freetype >=media-fonts/unifont-5 )"
+DEPEND="${RDEPEND}
+	>=dev-lang/python-2.5.2
+	sys-devel/flex
+	virtual/yacc
+	sys-apps/texinfo
+"
+RDEPEND+="
+	grub_platforms_efi-32? ( sys-boot/efibootmgr )
+	grub_platforms_efi-64? ( sys-boot/efibootmgr )
+"
+if [[ -n ${DO_AUTORECONF} ]] ; then
+	DEPEND+=" >=sys-devel/autogen-5.10 sys-apps/help2man"
+else
+	DEPEND+=" app-arch/xz-utils"
+fi
+
+export STRIP_MASK="*/grub/*/*.{mod,img}"
+
+QA_EXECSTACK="
+	usr/bin/grub*
+	usr/sbin/grub*
+	usr/lib*/grub/*/*.mod
+	usr/lib*/grub/*/kernel.exec
+	usr/lib*/grub/*/kernel.img
+	usr/lib*/grub/*/setjmp.module
+"
+
+QA_WX_LOAD="
+	usr/lib*/grub/*/kernel.exec
+	usr/lib*/grub/*/kernel.img
+	usr/lib*/grub/*/*.image
+"
+
+QA_PRESTRIPPED="
+	usr/lib.*/grub/.*/kernel.img
+"
+
+grub_run_phase() {
+	local phase=$1
+	local platform=$2
+	[[ -z ${phase} || -z ${platform} ]] && die "${FUNCNAME} [phase] [platform]"
+
+	[[ -d "${WORKDIR}/build-${platform}" ]] || \
+		{ mkdir "${WORKDIR}/build-${platform}" || die ; }
+	pushd "${WORKDIR}/build-${platform}" > /dev/null || die
+
+	echo ">>> Running ${phase} for platform \"${platform}\""
+	echo ">>> Working in: \"${WORKDIR}/build-${platform}\""
+
+	grub_${phase} ${platform}
+
+	popd > /dev/null || die
+}
+
+grub_src_configure() {
+	local platform=$1
+	local with_platform=
+
+	[[ -z ${platform} ]] && die "${FUNCNAME} [platform]"
+
+	# Used below for efi cross-building
+	tc-export CC NM OBJCOPY STRIP
+
+	estack_push CTARGET "${CTARGET}"
+	estack_push TARGET_CC "${TARGET_CC}"
+	estack_push TARGET_CFLAGS "${TARGET_CFLAGS}"
+	estack_push TARGET_CPPFLAGS "${TARGET_CPPFLAGS}"
+
+	case ${platform} in
+		efi-32)
+			if [[ ${CHOST} == x86_64* ]]; then
+				CTARGET="${CTARGET:-i386}"
+				TARGET_CC="${TARGET_CC:-${CC}}"
+				export TARGET_CC
+			fi
+			with_platform="--with-platform=efi"
+			;;
+		efi-64)
+			if [[ ${CHOST} == i?86* ]]; then
+				CTARGET="${CTARGET:-x86_64}"
+				TARGET_CC="${TARGET_CC:-${CC}}"
+				TARGET_CFLAGS="-Os -march=x86-64 ${TARGET_CFLAGS}"
+				TARGET_CPPFLAGS="-march=x86-64 ${TARGET_CPPFLAGS}"
+				export TARGET_CC TARGET_CFLAGS TARGET_CPPFLAGS
+			fi
+			with_platform="--with-platform=efi"
+			;;
+		guessed) ;;
+		*) with_platform="--with-platform=${platform}" ;;
+	esac
+
+	ECONF_SOURCE="${S}" \
+	econf \
+		--disable-werror \
+		--program-prefix= \
+		--program-transform-name="s,grub,grub2," \
+		--with-grubdir=grub2 \
+		${with_platform} \
+		$(use_enable debug mm-debug) \
+		$(use_enable debug grub-emu-usb) \
+		$(use_enable device-mapper) \
+		$(use_enable efiemu) \
+		$(use_enable mount grub-mount) \
+		$(use_enable nls) \
+		$(use_enable truetype grub-mkfont) \
+		$(use_enable libzfs) \
+		$(use sdl && use_enable debug grub-emu-sdl)
+
+	estack_pop CTARGET CTARGET || die
+	estack_pop TARGET_CC TARGET_CC || die
+	estack_pop TARGET_CFLAGS TARGET_CFLAGS || die
+	estack_pop TARGET_CPPFLAGS TARGET_CPPFLAGS || die
+}
+
+grub_src_compile() {
+	default_src_compile
+	pax-mark -mpes "${grub_binaries[@]}"
+}
+
+grub_src_install() {
+	default_src_install
+}
+
+src_prepare() {
+	local i j
+
+	epatch_user
+
+	# autogen.sh does more than just run autotools
+	if [[ -n ${DO_AUTORECONF} ]] ; then
+		sed -i -e '/^autoreconf/s:^:set +e; e:' autogen.sh || die
+		(. ./autogen.sh) || die
+	fi
+
+	# install into the right dir for eselect #372735
+	sed -i \
+		-e '/^bashcompletiondir =/s:=.*:= $(datarootdir)/bash-completion:' \
+		util/bash-completion.d/Makefile.in || die
+
+	# Bug 408195.
+	sed -i -e "s/sort -v/sort -V/" util/grub-mkconfig_lib.in || die
+
+	# get enabled platforms
+	GRUB_ENABLED_PLATFORMS=""
+	for i in ${GRUB_PLATFORMS[@]}; do
+		use grub_platforms_${i} && GRUB_ENABLED_PLATFORMS+=" ${i}"
+	done
+	[[ -z ${GRUB_ENABLED_PLATFORMS} ]] && GRUB_ENABLED_PLATFORMS="guessed"
+	elog "Going to build following platforms: ${GRUB_ENABLED_PLATFORMS}"
+}
+
+src_configure() {
+	local i
+
+	use custom-cflags || unset CFLAGS CPPFLAGS LDFLAGS
+	use libzfs && addpredict /etc/dfs
+	use static && append-ldflags -static
+
+	for i in ${GRUB_ENABLED_PLATFORMS}; do
+		grub_run_phase ${FUNCNAME} ${i}
+	done
+}
+
+src_compile() {
+	# Used for pax marking in grub_src_compile
+	local grub_binaries=(
+		grub-editenv
+		grub-fstest
+		grub-menulst2cfg
+		grub-mkimage
+		grub-mklayout
+		grub-mkpasswd-pbkdf2
+		grub-mkrelpath
+		grub-script-check
+		grub-bios-setup
+		grub-ofpathname
+		grub-probe
+		grub-sparc64-setup
+	)
+	use mount && grub_binaries+=( grub-mount )
+	use truetype && grub_binaries+=( grub-mkfont )
+
+	local i
+
+	for i in ${GRUB_ENABLED_PLATFORMS}; do
+		grub_run_phase ${FUNCNAME} ${i}
+	done
+}
+
+src_install() {
+	local i
+
+	for i in ${GRUB_ENABLED_PLATFORMS}; do
+		grub_run_phase ${FUNCNAME} ${i}
+	done
+
+	mv "${ED}"usr/share/info/grub{,2}.info || die
+
+	# can't be in docs array as we use default_src_install in different builddir
+	dodoc AUTHORS ChangeLog NEWS README THANKS TODO
+	insinto /etc/default
+	newins "${FILESDIR}"/grub.default grub
+}
+
+pkg_postinst() {
+	# display the link to guide
+	elog "For information on how to configure grub-2 please refer to the guide:"
+	elog "    http://wiki.gentoo.org/wiki/GRUB2"
+}