version bump, drop old, bug 522302, thanks Jose Romildo Malaquias

Package-Manager: portage-2.2.13/cvs/Linux x86_64
Manifest-Sign-Key: 0xAABEFD55

1 files changed, 65 insertions, 0 deletions

diff --git a/net-misc/connman/connman-1.25.ebuild b/net-misc/connman/connman-1.25.ebuild
new file mode 100644
index 000000000000..ceca4008fcc7
--- /dev/null
+++ b/net-misc/connman/connman-1.25.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/connman/connman-1.25.ebuild,v 1.1 2014/09/23 09:52:09 dlan Exp $
+
+EAPI="5"
+inherit base systemd
+
+DESCRIPTION="Provides a daemon for managing internet connections"
+HOMEPAGE="http://connman.net"
+SRC_URI="mirror://kernel/linux/network/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="bluetooth debug doc examples +ethernet ofono openvpn openconnect policykit tools vpnc +wifi"
+
+RDEPEND=">=dev-libs/glib-2.16
+	>=sys-apps/dbus-1.2.24
+	>=net-firewall/iptables-1.4.8
+	net-libs/gnutls
+	bluetooth? ( net-wireless/bluez )
+	ofono? ( net-misc/ofono )
+	policykit? ( sys-auth/polkit )
+	openvpn? ( net-misc/openvpn )
+	vpnc? ( net-misc/vpnc )
+	wifi? ( >=net-wireless/wpa_supplicant-2.0[dbus] )"
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.39"
+
+PATCHES=( "${FILESDIR}/${PN}-1.16-execinfo-assumptions.patch" )
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		--enable-client \
+		--enable-datafiles \
+		--enable-loopback=builtin \
+		$(use_enable examples test) \
+		$(use_enable ethernet ethernet builtin) \
+		$(use_enable wifi wifi builtin) \
+		$(use_enable bluetooth bluetooth builtin) \
+		$(use_enable ofono ofono builtin) \
+		$(use_enable openconnect openconnect builtin) \
+		$(use_enable openvpn openvpn builtin) \
+		$(use_enable policykit polkit builtin) \
+		$(use_enable vpnc vpnc builtin) \
+		$(use_enable debug) \
+		$(use_enable tools) \
+		--disable-iospm \
+		--disable-hh2serial-gps
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dobin client/connmanctl || die "client installation failed"
+
+	if use doc; then
+		dodoc doc/*.txt
+	fi
+	keepdir /var/lib/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd2 ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	systemd_dounit "${FILESDIR}"/connman.service
+}