Version bump.

Package-Manager: portage-2.2.10/cvs/Linux x86_64
Manifest-Sign-Key: 0x4868F14D

1 files changed, 70 insertions, 0 deletions

diff --git a/net-libs/libpcap/libpcap-1.6.2.ebuild b/net-libs/libpcap/libpcap-1.6.2.ebuild
new file mode 100644
index 000000000000..8ca46be31546
--- /dev/null
+++ b/net-libs/libpcap/libpcap-1.6.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libpcap/libpcap-1.6.2.ebuild,v 1.1 2014/09/04 04:14:56 ssuominen Exp $
+
+EAPI=5
+inherit autotools eutils
+
+DESCRIPTION="A system-independent library for user-level network packet capture"
+HOMEPAGE="http://www.tcpdump.org/"
+SRC_URI="http://www.tcpdump.org/release/${P}.tar.gz
+	http://www.jp.tcpdump.org/release/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="bluetooth dbus ipv6 netlink static-libs canusb"
+
+RDEPEND="
+	bluetooth? ( net-wireless/bluez:= )
+	dbus? ( sys-apps/dbus )
+	netlink? ( dev-libs/libnl )
+	canusb? ( virtual/libusb )
+"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	virtual/pkgconfig
+	virtual/yacc
+"
+
+DOCS=( CREDITS CHANGES VERSION TODO README{,.dag,.linux,.macosx,.septel} )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.2.0-cross-linux.patch
+	epatch "${FILESDIR}"/${PN}-1.6.1-configure.patch
+	epatch "${FILESDIR}"/${PN}-1.6.1-prefix-solaris.patch
+
+	mkdir bluetooth || die
+	cp "${FILESDIR}"/mgmt.h bluetooth/ || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable bluetooth) \
+		$(use_enable ipv6) \
+		$(use_enable canusb) \
+		$(use_enable dbus) \
+		$(use_with netlink libnl)
+}
+
+src_compile() {
+	emake all shared
+}
+
+src_install() {
+	default
+
+	# remove static libraries (--disable-static does not work)
+	if ! use static-libs; then
+		find "${ED}" -name '*.a' -exec rm {} + || die
+	fi
+	prune_libtool_files
+
+	# We need this to build pppd on G/FBSD systems
+	if [[ "${USERLAND}" == "BSD" ]]; then
+		insinto /usr/include
+		doins pcap-int.h
+	fi
+}