Fix wakeup-reboot-script for baselayout-1.

Package-Manager: portage-2.1.5_rc4

4 files changed, 181 insertions, 6 deletions

diff --git a/media-tv/gentoo-vdr-scripts/ChangeLog b/media-tv/gentoo-vdr-scripts/ChangeLog
index 9186509383eb..20e770247b2c 100644
--- a/media-tv/gentoo-vdr-scripts/ChangeLog
+++ b/media-tv/gentoo-vdr-scripts/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-tv/gentoo-vdr-scripts
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog,v 1.90 2008/03/22 17:00:05 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog,v 1.91 2008/04/19 12:23:23 zzam Exp $
+
+*gentoo-vdr-scripts-0.4.3-r1 (19 Apr 2008)
+
+  19 Apr 2008; Matthias Schwarzott <zzam@gentoo.org>
+  +files/gentoo-vdr-scripts-0.4.3-fix-wakeup-reboot.diff,
+  +gentoo-vdr-scripts-0.4.3-r1.ebuild:
+  Fix wakeup-reboot-script for baselayout-1.
 
   22 Mar 2008; Matthias Schwarzott <zzam@gentoo.org>
   gentoo-vdr-scripts-0.4.3.ebuild:
diff --git a/media-tv/gentoo-vdr-scripts/Manifest b/media-tv/gentoo-vdr-scripts/Manifest
index 47b845acf6c5..ccae7ed34cdc 100644
--- a/media-tv/gentoo-vdr-scripts/Manifest
+++ b/media-tv/gentoo-vdr-scripts/Manifest
@@ -1,6 +1,7 @@
 -----BEGIN PGP SIGNED MESSAGE-----
 Hash: SHA1
 
+AUX gentoo-vdr-scripts-0.4.3-fix-wakeup-reboot.diff 602 RMD160 65225f656eb3c5026502c02a291ad4d433b20401 SHA1 13c51cdc4953cdc751a5ec4a56919eb79e0be7db SHA256 671ac882d7c30b84d7d10d5c54ac2ccc264e6cd0ef2e7621bd3e62fd8a136042
 DIST gentoo-vdr-scripts-0.4.0.tar.bz2 27936 RMD160 221063e8296281087b9d0f0031f7a37c405ff72d SHA1 d8f76b4c2977c0dc6d159111519ba0001b922440 SHA256 71ed687787aef0e9d263824505bd1244b6527bda95c0aa2c8ed408be53d2a301
 DIST gentoo-vdr-scripts-0.4.1.tar.bz2 30683 RMD160 5dc4a9ef2e2a6ab6f3cea879c1a546a883ac9b7c SHA1 b29088a0746e27941984e6cf26f4e9046fd6c3f5 SHA256 5e5a826936523208994a64d12fd04421eaaf6de474d7bfa3ff1e6f08233c0d1f
 DIST gentoo-vdr-scripts-0.4.2.tar.bz2 32110 RMD160 7c8bb70cb5a9e766b91ea57ec17786130448812e SHA1 e242092ae444cac1f835b56690f4449b4bffcca5 SHA256 1c3f10166e1a2012f4274d8b2c348243795603899195a3231b8c7cbf005f9e49
@@ -8,13 +9,14 @@ DIST gentoo-vdr-scripts-0.4.3.tar.bz2 33196 RMD160 29f0b8b1c0fdb6b4ad8d6604ad58d
 EBUILD gentoo-vdr-scripts-0.4.0.ebuild 3710 RMD160 f96264a5f57907e2a1a34f3c2377f034cfb7244c SHA1 d402f1646a969298887b080512932d12de732eee SHA256 9b0e3bac194f3d2ff374c87a4c775dc88a3b1951e5a6947ede226f31580295ff
 EBUILD gentoo-vdr-scripts-0.4.1.ebuild 4013 RMD160 a3de3f4b0882cb1f44c159173bd8843c21d44b36 SHA1 3ce643b3c64c4e5253b2e06971fb8e929e1e45e6 SHA256 e20823c197c1fcccb80755a7f7105851a26f9ae80c728b629a48400653896c5b
 EBUILD gentoo-vdr-scripts-0.4.2.ebuild 4041 RMD160 8747187d52e696b5bc5b7b039f895f35babd017d SHA1 0090e47e75e0b8933015af44447f5454f1edf6c7 SHA256 bcedd17d4e2df8332f34a49d79d3e1e3ecb4078805f7c4502ec2b0bb34a86a24
+EBUILD gentoo-vdr-scripts-0.4.3-r1.ebuild 4137 RMD160 770ccedff97ff062e85685a3eef0880ded451214 SHA1 2cb2cd6edb8f4aaba17d158f71b3c707a7785db1 SHA256 5c721b330ff65c96925e05359ed4211be42c577f88f608a0e8dd10493cea4754
 EBUILD gentoo-vdr-scripts-0.4.3.ebuild 4041 RMD160 4f885ef804b6b052899b3924ee53d97b85cecef1 SHA1 e1d0b1d9fa1412ffe7f6782848a1e69533608c04 SHA256 d9f45c4d949dde4b268d766daaae0a6048ec80e33e761359f5ed3da4934625c8
-MISC ChangeLog 18223 RMD160 19aca0368006d07263614cd508ab1fc1b8ae3e42 SHA1 ca337a0e77fcd2561febda7647d254f2cbd1de4a SHA256 7adde57f0b2deeb96a84c1f5b2876ff25b88e61f99425bdcd0eed25d40fa530f
+MISC ChangeLog 18463 RMD160 0a80c260cdbc947a32058a437d34892f24248193 SHA1 bdc1a80c1e72b3da741a9fce95fa9b6bb38a16e1 SHA256 880d8ae7b6f8d706d7c415f45e305896e82f202c706ef5afb1ac143e0dc0c8c3
 MISC metadata.xml 257 RMD160 8bee49b98c59996aaaa019fb2c764c08d8004507 SHA1 d2419394e7d5c7463d7dea33e9190ebd57484531 SHA256 0dd45fbbaf1c6173535e371e3ff8a3faa41f3f89123ac9dffe338998599ebe26
 -----BEGIN PGP SIGNATURE-----
-Version: GnuPG v2.0.7 (GNU/Linux)
+Version: GnuPG v2.0.9 (GNU/Linux)
 
-iD8DBQFH5Tsft2vP6XvVdOcRAqN8AJ9yTjC2WInHOno6RxKP0L9i74dapgCfbpvZ
-VvUkNUziYJ06QYtupsUbFMM=
-=2E6u
+iEYEARECAAYFAkgJ5EQACgkQt2vP6XvVdOf8cwCfRbrx5i5lbcHoH+ezXrLVD3de
+aZcAnjNiRuINosppIu5xL1GmWADfahVW
+=WJMB
 -----END PGP SIGNATURE-----
diff --git a/media-tv/gentoo-vdr-scripts/files/gentoo-vdr-scripts-0.4.3-fix-wakeup-reboot.diff b/media-tv/gentoo-vdr-scripts/files/gentoo-vdr-scripts-0.4.3-fix-wakeup-reboot.diff
new file mode 100644
index 000000000000..9ea6957bda53
--- /dev/null
+++ b/media-tv/gentoo-vdr-scripts/files/gentoo-vdr-scripts-0.4.3-fix-wakeup-reboot.diff
@@ -0,0 +1,12 @@
+diff -ru gentoo-vdr-scripts-0.4.3-orig/etc/init.d/wakeup-reboot-halt gentoo-vdr-scripts-0.4.3/etc/init.d/wakeup-reboot-halt
+--- gentoo-vdr-scripts-0.4.3-orig/etc/init.d/wakeup-reboot-halt	2008-04-19 14:13:33.322545533 +0200
++++ gentoo-vdr-scripts-0.4.3/etc/init.d/wakeup-reboot-halt	2008-04-19 14:13:56.422544885 +0200
+@@ -3,7 +3,7 @@
+ # Distributed under the terms of the GNU General Public License v2
+ # $Id: gentoo-vdr-scripts-0.4.3-fix-wakeup-reboot.diff,v 1.1 2008/04/19 12:23:23 zzam Exp $
+ 
+-extra_commands="mark_for_reboot"
++opts="${opts} mark_for_reboot"
+ 
+ STATEFILE=/force_reboot_shutdown
+ 
diff --git a/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.4.3-r1.ebuild b/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.4.3-r1.ebuild
new file mode 100644
index 000000000000..819c1499a4ed
--- /dev/null
+++ b/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.4.3-r1.ebuild
@@ -0,0 +1,154 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.4.3-r1.ebuild,v 1.1 2008/04/19 12:23:23 zzam Exp $
+
+inherit eutils
+
+DESCRIPTION="Scripts necessary for use of vdr as a set-top-box"
+HOMEPAGE="http://www.gentoo.org/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2
+	http://dev.gentoo.org/~zzam/distfiles/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="nvram"
+
+RDEPEND="nvram? ( sys-power/nvram-wakeup )
+	app-admin/sudo
+	!media-tv/vdr-dvd-scripts
+	!media-tv/vdrplugin-rebuild"
+
+VDR_HOME=/var/vdr
+
+pkg_setup() {
+	enewgroup vdr
+
+	# Add user vdr to these groups:
+	#   video - accessing dvb-devices
+	#   audio - playing sound when using software-devices
+	#   cdrom - playing dvds/audio-cds ...
+	enewuser vdr -1 /bin/bash "${VDR_HOME}" vdr,video,audio,cdrom
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/${P}-fix-wakeup-reboot.diff"
+}
+
+src_install() {
+	local myopts=""
+	if use nvram ; then
+		myopts="${myopts} NVRAM=1"
+	fi
+
+	emake -s install DESTDIR="${D}" ${myopts} || die "make install failed"
+	dodoc README TODO ChangeLog
+
+	# create necessary directories
+	diropts -ovdr -gvdr
+	keepdir "${VDR_HOME}"
+
+	local kd
+	for kd in shutdown-data merged-config-files dvd-images tmp; do
+		keepdir "${VDR_HOME}/${kd}"
+	done
+}
+
+pkg_preinst() {
+	einfo "Smart updating /etc/conf.d/vdr.plugins"
+	local PLUGINS_NEW=0
+	if [[ -f "${ROOT}"/etc/conf.d/vdr.plugins ]]; then
+		PLUGINS_NEW=$(grep -v '^#' "${ROOT}"/etc/conf.d/vdr.plugins |grep -v '^$'|wc -l)
+	fi
+	if [[ ${PLUGINS_NEW} > 0 ]]; then
+		einfo "Using existing /etc/conf.d/vdr.plugins"
+		cp "${ROOT}"/etc/conf.d/vdr.plugins "${D}"/etc/conf.d/vdr.plugins
+	else
+		einfo "Using PLUGINS from /etc/conf.d/vdr"
+		local PLUGIN
+		for PLUGIN in $(source "${ROOT}"/etc/conf.d/vdr;echo $PLUGINS); do
+			echo ${PLUGIN} >> "${D}"/etc/conf.d/vdr.plugins
+		done
+	fi
+}
+
+VDRSUDOENTRY="vdr ALL=NOPASSWD:/usr/share/vdr/bin/vdrshutdown-really.sh"
+
+pkg_postinst() {
+	if has_version "<media-tv/gentoo-vdr-scripts-0.3.6"; then
+		ewarn
+		ewarn "A shutdown-file has been changed."
+		ewarn "You really have to execute"
+		ewarn "\temerge --config gentoo-vdr-scripts"
+		ewarn "to keep shutdown working."
+		ewarn
+
+		ebeep 5
+	else
+		elog
+		elog "To make shutdown work add this line to /etc/sudoers"
+		elog "\t${VDRSUDOENTRY}"
+		elog
+		elog "or execute this command:"
+		elog "\temerge --config gentoo-vdr-scripts"
+		elog
+	fi
+
+	if ! use nvram ; then
+		elog "nvram wakeup is now optional."
+		elog "To make use of it enable the use flag nvram for ${PN}"
+		elog "or just emerge nvram-wakeup."
+	fi
+
+	if has_version "<media-tv/gentoo-vdr-scripts-0.3.7"; then
+		einfo
+		einfo "Plugins which should be used are now set via its"
+		einfo "own config-file called /etc/conf.d/vdr.plugins"
+		einfo
+		einfo "Smart updating should have moved all your settings"
+		einfo
+	fi
+
+	if [[ -f "${ROOT}/etc/init.d/dvbsplash" ]]; then
+		ewarn
+		ewarn "You have dvbsplash installed!"
+		ewarn "/etc/init.d/dvbsplash will now be deleted"
+		ewarn "as it causes difficult to debug problems."
+		ewarn
+		rm "${ROOT}/etc/init.d/dvbsplash"
+	fi
+
+	if [[ -f "${ROOT}"/etc/conf.d/vdr.dvdswitch ]] &&
+		grep -q ^DVDSWITCH_BURNSPEED= "${ROOT}"/etc/conf.d/vdr.dvdswitch
+	then
+		ewarn "You are setting DVDSWITCH_BURNSPEED in /etc/conf.d/vdr.dvdswitch"
+		ewarn "This no longer has any effect, please use"
+		ewarn "VDR_DVDBURNSPEED in /etc/conf.d/vdr.cd-dvd"
+	fi
+}
+
+pkg_config() {
+	if grep -q /usr/share/vdr/bin/vdrshutdown-really.sh "${ROOT}"/etc/sudoers; then
+		einfo "sudoers-entry for vdr already in place."
+	else
+		einfo "Adding this line to /etc/sudoers:"
+		einfo "+  ${VDRSUDOENTRY}"
+
+		cd "${T}"
+		cat >sudoedit-vdr.sh <<-SUDOEDITOR
+			#!/bin/bash
+			echo Commenting out old entry
+			sed -i \${1} -e '/\/usr\/lib\/vdr\/bin\/vdrshutdown-really.sh/s/^/#/'
+			echo Adding new entry
+			echo "" >> \${1}
+			echo "${VDRSUDOENTRY}" >> \${1}
+		SUDOEDITOR
+		chmod a+x sudoedit-vdr.sh
+
+		VISUAL="${T}"/sudoedit-vdr.sh visudo -f "${ROOT}"/etc/sudoers || die "visudo failed"
+
+		einfo "Edited /etc/sudoers"
+	fi
+}