New version 0.4.5 - content identical to rc2.

Package-Manager: portage-2.2_rc8/cvs/Linux 2.6.25-tuxonice-r6 i686

3 files changed, 137 insertions, 5 deletions

diff --git a/media-tv/gentoo-vdr-scripts/ChangeLog b/media-tv/gentoo-vdr-scripts/ChangeLog
index 5d71dd08dabf..94fe45f960af 100644
--- a/media-tv/gentoo-vdr-scripts/ChangeLog
+++ b/media-tv/gentoo-vdr-scripts/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-tv/gentoo-vdr-scripts
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog,v 1.97 2008/08/14 17:56:01 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog,v 1.98 2008/08/28 09:25:13 zzam Exp $
+
+*gentoo-vdr-scripts-0.4.5 (28 Aug 2008)
+
+  28 Aug 2008; Matthias Schwarzott <zzam@gentoo.org>
+  +gentoo-vdr-scripts-0.4.5.ebuild:
+  New version 0.4.5 - content identical to rc2.
 
 *gentoo-vdr-scripts-0.4.5_rc2 (14 Aug 2008)
 
diff --git a/media-tv/gentoo-vdr-scripts/Manifest b/media-tv/gentoo-vdr-scripts/Manifest
index b39703a30298..1e303a48ed38 100644
--- a/media-tv/gentoo-vdr-scripts/Manifest
+++ b/media-tv/gentoo-vdr-scripts/Manifest
@@ -7,6 +7,7 @@ DIST gentoo-vdr-scripts-0.4.1.tar.bz2 30683 RMD160 5dc4a9ef2e2a6ab6f3cea879c1a54
 DIST gentoo-vdr-scripts-0.4.2.tar.bz2 32110 RMD160 7c8bb70cb5a9e766b91ea57ec17786130448812e SHA1 e242092ae444cac1f835b56690f4449b4bffcca5 SHA256 1c3f10166e1a2012f4274d8b2c348243795603899195a3231b8c7cbf005f9e49
 DIST gentoo-vdr-scripts-0.4.3.tar.bz2 33196 RMD160 29f0b8b1c0fdb6b4ad8d6604ad58dd34cccdf442 SHA1 162b15c6d9d508968040512507ca106f021f3f29 SHA256 68036e2fe63bc40e357b3e9e4a7be991c344875229393a6f2dbe0fc54425348f
 DIST gentoo-vdr-scripts-0.4.4.tar.bz2 33500 RMD160 ef80dc1d3d6e483434ac1486297ce1a5dfdbec13 SHA1 420a6419ac1f0a06d56544b18b385e43def54c73 SHA256 8ee95144942b9ea5164fac2b068dc8698fc1114f34cc951b1c472c58f33ebf3c
+DIST gentoo-vdr-scripts-0.4.5.tar.bz2 35411 RMD160 d7e47effaeccbb527ce4fbc997ee11aa09e1c6e5 SHA1 17c0a631359b977a8be7ff01141465f76c35c144 SHA256 4883c59e0a8cc7625fde24609501baf0e0d265de266a4a3777cd0ad6e60cf406
 DIST gentoo-vdr-scripts-0.4.5_rc1.tar.bz2 35532 RMD160 9f8640734da9c697cbe0df3ebf51f6b96878c487 SHA1 feb2b52c1f25b1f44bd9e1f2045b0d18817c9088 SHA256 662e7c708dd07e1968c104209cae6d35568bc4722825d4f01e942c0029e3e28c
 DIST gentoo-vdr-scripts-0.4.5_rc2.tar.bz2 35423 RMD160 96879f5a5047ba18c49652934bba2791c3cdf73f SHA1 6f403716d13fe17ab5a0333dd4b0f277a8edde49 SHA256 9b11ad8c40f572641e8b7051d2184a79c9f2688d8a09464585c1dc80c92cdf21
 EBUILD gentoo-vdr-scripts-0.4.0.ebuild 3829 RMD160 78a0e6f0706e2e98148bd48f9e7e2ecc15dcfff1 SHA1 c736bd058284e4aa350dbe8a1928fc9ff51f22b2 SHA256 0ba19e54c81eed852953ffd8206671fcf0b37baf3ab3e7d85a51f4a2c008edc4
@@ -15,14 +16,15 @@ EBUILD gentoo-vdr-scripts-0.4.2.ebuild 4160 RMD160 49ff19e8f87f83cd924fd00000f94
 EBUILD gentoo-vdr-scripts-0.4.3-r1.ebuild 4255 RMD160 ed59150dc900a58a8dab685eb692f78ca1bbccc1 SHA1 e1ee853d3510df6d5225bed1be54a22ab329c896 SHA256 d4cb4470d5d61142cca6e351595b892fc63f084d09bd8625cce9b7922486689f
 EBUILD gentoo-vdr-scripts-0.4.3.ebuild 4160 RMD160 7c8f405c8538574a66a0ba01ac5387b437d6aa65 SHA1 7ef58c09f5b824e0422e68c9f852c1e5f26c3990 SHA256 bee752b252028b92aac0da0b0f279b4735eb0d2541a95d3e28bab2ffc79eb2d2
 EBUILD gentoo-vdr-scripts-0.4.4.ebuild 4160 RMD160 554687fb50f3f4d704d8804c29489b987f28346d SHA1 80d3a666d609be4235f162296beee66fb471e749 SHA256 1a12fe3cfb03e8d2cd66630d4bfe024ebc095b04dd4e97c2ebdb2f9b1b62f9bc
+EBUILD gentoo-vdr-scripts-0.4.5.ebuild 3475 RMD160 8f8f85b4f67d15cf8d7b7444a3295eec9037c70c SHA1 068594a244dd22263233ac64385abbb648babe9e SHA256 ef08a5ba93f3d7a346bfd460de6fd3ea85b5beb879ecc51397aab1720d7b30a9
 EBUILD gentoo-vdr-scripts-0.4.5_rc1.ebuild 3479 RMD160 f6ad4d93df837464deb881d78c47f03d43f536ff SHA1 0a6209c42218c1bd4705fa7087fbb015028b4fc2 SHA256 7e9a4c5ae3e33bafaa5900169e852ff067e3520e279a417daef91896c03a3a95
 EBUILD gentoo-vdr-scripts-0.4.5_rc2.ebuild 3479 RMD160 52eae58354fe566ec0b28c4d59154b3b6b7b645a SHA1 57a92543084caa9dea51d156b285d36f08b45593 SHA256 3763270693a927aef1e34123f8ff87f39c9f6681b00b21a411531d8026c377da
-MISC ChangeLog 19734 RMD160 6c3c86c270376652c315e8f849aafd8a9c7739fb SHA1 8c997612172363e6f0964a4e804da92462b10b12 SHA256 b39d46ba695b9bc4f546c3bae660713cbdd30aff3d1fd622ae8535014a729dc7
+MISC ChangeLog 19913 RMD160 cdb77e1987391d3c4a461f1391051ec70c3ab92f SHA1 9c82886b12278ee14b18393fe3383d2e405536aa SHA256 401e12aafccd626cc87d16668799fa24303175125cadc1b1b1bf16956cfae5d7
 MISC metadata.xml 366 RMD160 2c6ee9297820274dce664dfc05d65b36b5342984 SHA1 6e0c2ac753886340601e6058e5c306e0fbc1c760 SHA256 a92d2326d3f734f176d63173dd3a19fa2cd3b9744ee142cd3e4fb0771d08fd29
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.9 (GNU/Linux)
 
-iEYEARECAAYFAkikcbYACgkQt2vP6XvVdOdeJwCdGcDaCTk5GZPa7kiwV497psy9
-HKEAni4IOAeMS9V7ZP12vYfQOXnCh/5C
-=oR5H
+iEYEARECAAYFAki2bv8ACgkQt2vP6XvVdOcRLACdG3EzFWptACsrWj0LoR2+z5i0
+dloAoLN2br1KG77pdLG72Ajb44PbttGk
+=nikY
 -----END PGP SIGNATURE-----
diff --git a/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.4.5.ebuild b/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.4.5.ebuild
new file mode 100644
index 000000000000..6fc56cbc70f1
--- /dev/null
+++ b/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.4.5.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.4.5.ebuild,v 1.1 2008/08/28 09:25:13 zzam Exp $
+
+inherit eutils
+
+DESCRIPTION="Scripts necessary for use of vdr as a set-top-box"
+HOMEPAGE="http://www.gentoo.org/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2
+	http://dev.gentoo.org/~zzam/distfiles/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="nvram"
+
+RDEPEND="nvram? ( sys-power/nvram-wakeup )
+	app-admin/sudo
+	!media-tv/vdr-dvd-scripts
+	!media-tv/vdrplugin-rebuild"
+
+VDR_HOME=/var/vdr
+
+pkg_setup() {
+	enewgroup vdr
+
+	# Add user vdr to these groups:
+	#   video - accessing dvb-devices
+	#   audio - playing sound when using software-devices
+	#   cdrom - playing dvds/audio-cds ...
+	enewuser vdr -1 /bin/bash "${VDR_HOME}" vdr,video,audio,cdrom
+}
+
+src_install() {
+	emake -s install DESTDIR="${D}" || die "make install failed"
+	dodoc README TODO ChangeLog
+
+	# create necessary directories
+	diropts -ovdr -gvdr
+	keepdir "${VDR_HOME}"
+
+	local kd
+	for kd in shutdown-data merged-config-files dvd-images tmp; do
+		keepdir "${VDR_HOME}/${kd}"
+	done
+}
+
+pkg_preinst() {
+	local PLUGINS_NEW=0
+	if [[ -f "${ROOT}"/etc/conf.d/vdr.plugins ]]; then
+		PLUGINS_NEW=$(grep -v '^#' "${ROOT}"/etc/conf.d/vdr.plugins |grep -v '^$'|wc -l)
+	fi
+	if [[ ${PLUGINS_NEW} > 0 ]]; then
+		cp "${ROOT}"/etc/conf.d/vdr.plugins "${D}"/etc/conf.d/vdr.plugins
+	else
+		einfo "Migrating PLUGINS setting from /etc/conf.d/vdr to /etc/conf.d/vdr.plugins"
+		local PLUGIN
+		for PLUGIN in $(source "${ROOT}"/etc/conf.d/vdr;echo $PLUGINS); do
+			echo ${PLUGIN} >> "${D}"/etc/conf.d/vdr.plugins
+		done
+	fi
+}
+
+VDRSUDOENTRY="vdr ALL=NOPASSWD:/usr/share/vdr/bin/vdrshutdown-really.sh"
+
+pkg_postinst() {
+	elog
+	elog "To make shutdown work add this line to /etc/sudoers"
+	elog "\t${VDRSUDOENTRY}"
+	elog
+	elog "or execute this command:"
+	elog "\temerge --config gentoo-vdr-scripts"
+	elog
+
+	elog "nvram wakeup is optional."
+	elog "To make use of it emerge sys-power/nvram-wakeup."
+	elog
+
+	elog "Plugins which should be used are now set via its"
+	elog "own config-file called /etc/conf.d/vdr.plugins"
+	elog "or enabled via the frontend eselect vdr-plugin."
+	elog
+
+	if [[ -f "${ROOT}/etc/init.d/dvbsplash" ]]; then
+		ewarn
+		ewarn "You have dvbsplash installed!"
+		ewarn "/etc/init.d/dvbsplash will now be deleted"
+		ewarn "as it causes difficult to debug problems."
+		ewarn
+		rm "${ROOT}/etc/init.d/dvbsplash"
+	fi
+
+	if [[ -f "${ROOT}"/etc/conf.d/vdr.dvdswitch ]] &&
+		grep -q ^DVDSWITCH_BURNSPEED= "${ROOT}"/etc/conf.d/vdr.dvdswitch
+	then
+		ewarn "You are setting DVDSWITCH_BURNSPEED in /etc/conf.d/vdr.dvdswitch"
+		ewarn "This no longer has any effect, please use"
+		ewarn "VDR_DVDBURNSPEED in /etc/conf.d/vdr.cd-dvd"
+	fi
+}
+
+pkg_config() {
+	if grep -q /usr/share/vdr/bin/vdrshutdown-really.sh "${ROOT}"/etc/sudoers; then
+		einfo "sudoers-entry for vdr already in place."
+	else
+		einfo "Adding this line to /etc/sudoers:"
+		einfo "+  ${VDRSUDOENTRY}"
+
+		cd "${T}"
+		cat >sudoedit-vdr.sh <<-SUDOEDITOR
+			#!/bin/bash
+			echo Commenting out old entry
+			sed -i \${1} -e '/\/usr\/lib\/vdr\/bin\/vdrshutdown-really.sh/s/^/#/'
+			echo Adding new entry
+			echo "" >> \${1}
+			echo "${VDRSUDOENTRY}" >> \${1}
+		SUDOEDITOR
+		chmod a+x sudoedit-vdr.sh
+
+		VISUAL="${T}"/sudoedit-vdr.sh visudo -f "${ROOT}"/etc/sudoers || die "visudo failed"
+
+		einfo "Edited /etc/sudoers"
+	fi
+}