Updated to include the 0.8.1a fixes

Package-Manager: portage-2.1_rc1-r2

1 files changed, 58 insertions, 0 deletions

diff --git a/media-sound/museseq/museseq-0.8.1-r1.ebuild b/media-sound/museseq/museseq-0.8.1-r1.ebuild
new file mode 100644
index 000000000000..6cc5b99f662d
--- /dev/null
+++ b/media-sound/museseq/museseq-0.8.1-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/museseq/museseq-0.8.1-r1.ebuild,v 1.1 2006/05/15 20:45:44 fvdpol Exp $
+
+inherit kde-functions virtualx eutils
+
+MY_P=${P/museseq/muse}
+MY_P=${MY_P/_/}
+REV="a"
+
+DESCRIPTION="MusE is a MIDI/Audio sequencer with recording and editing capabilities"
+SRC_URI="mirror://sourceforge/lmuse/${MY_P}${REV}.tar.gz"
+HOMEPAGE="http://www.muse-sequencer.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="doc lash debug"
+
+DEPEND="$(qt_min_version 3.2)
+	>=media-libs/alsa-lib-0.9.0
+	media-sound/fluidsynth
+	doc? ( app-text/openjade
+		app-doc/doxygen
+		media-gfx/graphviz )
+	dev-lang/perl
+	>=media-libs/libsndfile-1.0.1
+	>=media-libs/libsamplerate-0.1.0
+	>=media-sound/jack-audio-connection-kit-0.98.0
+	lash? ( media-sound/lash )"
+
+src_compile() {
+	cd ${WORKDIR}/${MY_P}
+	local myconf
+	myconf="--disable-suid-build" # instead, use CONFIG_RTC and realtime-lsm
+	use lash		&& myconf="${myconf} --enable-lash"
+	use lash		|| myconf="${myconf} --disable-lash"
+	use debug		&& myconf="${myconf} --enable-debug"
+	Xeconf ${myconf} || die "configure failed"
+
+	emake all || die
+}
+
+src_install() {
+	cd ${WORKDIR}/${MY_P}
+	make DESTDIR=${D} install || die "install failed"
+	dodoc AUTHORS ChangeLog NEWS README SECURITY README.*
+	mv ${D}/usr/bin/muse ${D}/usr/bin/museseq
+}
+
+pkg_postinst() {
+	einfo "You must have the realtime module loaded to use MusE 0.8.x"
+	einfo "Additionally, configure your Linux Kernel for non-generic"
+	einfo "Real Time Clock support enabled or loaded as a module."
+	einfo "User must have read/write access to /dev/misc/rtc device."
+	einfo "Realtime LSM: http://sourceforge.net/projects/realtime-lsm/"
+}