New version with ffmpeg support, and asf dependant on asf useflag (allows to play audio of wma/wmv files using ffmpeg on non-x86 arches).

Package-Manager: portage-2.0.53_rc7

4 files changed, 259 insertions, 5 deletions

diff --git a/media-libs/xine-lib/ChangeLog b/media-libs/xine-lib/ChangeLog
index 4b232354d979..9441f2a68370 100644
--- a/media-libs/xine-lib/ChangeLog
+++ b/media-libs/xine-lib/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/xine-lib
 # Copyright 1999-2005 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/ChangeLog,v 1.268 2005/11/15 16:57:03 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/ChangeLog,v 1.269 2005/11/20 20:06:44 flameeyes Exp $
+
+*xine-lib-1.1.1-r1 (20 Nov 2005)
+
+  20 Nov 2005; Diego Pettenò <flameeyes@gentoo.org>
+  +xine-lib-1.1.1-r1.ebuild:
+  New version with ffmpeg support, and asf dependant on asf useflag (allows to
+  play audio of wma/wmv files using ffmpeg on non-x86 arches).
 
 *xine-lib-1.1.1 (15 Nov 2005)
 
diff --git a/media-libs/xine-lib/Manifest b/media-libs/xine-lib/Manifest
index fd506dc18417..f51de7250b9c 100644
--- a/media-libs/xine-lib/Manifest
+++ b/media-libs/xine-lib/Manifest
@@ -1,12 +1,13 @@
 -----BEGIN PGP SIGNED MESSAGE-----
 Hash: SHA1
 
-MD5 b36bd627e8195ce63221d144d56c817c ChangeLog 17311
+MD5 9f34276d64984b399f72eae0c035c7b8 ChangeLog 17570
 MD5 9678227c043f04d5e8561cb6ba80d3e6 files/digest-xine-lib-1.0.1-r4 137
 MD5 33da8deb9637be23cd464aba9c5c4ac4 files/digest-xine-lib-1.1.0 137
 MD5 3d6e1d0e96ea02e463d045cd83e2e32f files/digest-xine-lib-1.1.0-r5 138
 MD5 9ca4799efa33fefe9faaad047fb3dcbb files/digest-xine-lib-1.1.0-r7 138
 MD5 c67420852e94a93aef8edd92271497e0 files/digest-xine-lib-1.1.1 137
+MD5 c67420852e94a93aef8edd92271497e0 files/digest-xine-lib-1.1.1-r1 137
 MD5 51e97df2f6ae538ab33a802eafb10457 files/digest-xine-lib-1_rc8-r2 138
 MD5 cd292167e0ca6e7910e1cf32091e3a27 files/xine-lib-formatstring.patch 315
 MD5 40462be9f1caff6326630fc3b93e7105 metadata.xml 330
@@ -14,12 +15,13 @@ MD5 6b76f6f5129a29911fd681772ba92601 xine-lib-1.0.1-r4.ebuild 7507
 MD5 6d96166f223f8fbeecbdc2acaf32ccb3 xine-lib-1.1.0-r5.ebuild 6845
 MD5 d57a85599064698f1a9ebf69c913cbc3 xine-lib-1.1.0-r7.ebuild 6851
 MD5 1a7fe2febb92bcbc715be3fcdb0d8361 xine-lib-1.1.0.ebuild 7277
+MD5 da8975b2daf9bd53ae67bad2358cfc03 xine-lib-1.1.1-r1.ebuild 7017
 MD5 96a153f79bdc85013277825cceac009f xine-lib-1.1.1.ebuild 6731
 MD5 8e8e38d54e416b12108a0597f4d0801f xine-lib-1_rc8-r2.ebuild 5288
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v1.4.2 (GNU/Linux)
 
-iD8DBQFDehOKAiZjviIA2XgRAr0BAKDDoXPKUnHWvxwnbp6KR/txc/mwuwCfbi6s
-ePOKeEl0HjZ1rxwtfbvyroE=
-=ZqiQ
+iD8DBQFDgNduAiZjviIA2XgRAutHAKCcrUSUWnA/XY/XQsaB81NeW4WP9QCcCe2D
+7WknxXiEWUWnQtvK0DEfH6o=
+=sPc6
 -----END PGP SIGNATURE-----
diff --git a/media-libs/xine-lib/files/digest-xine-lib-1.1.1-r1 b/media-libs/xine-lib/files/digest-xine-lib-1.1.1-r1
new file mode 100644
index 000000000000..eb065c5276b8
--- /dev/null
+++ b/media-libs/xine-lib/files/digest-xine-lib-1.1.1-r1
@@ -0,0 +1,2 @@
+MD5 b1f42602c776bb93e3cbf127e220cbfd xine-lib-1.1.1.tar.gz 7990031
+MD5 8a03332130019a14417c6564a57e1a17 xine-lib-patches-17.tar.bz2 1971
diff --git a/media-libs/xine-lib/xine-lib-1.1.1-r1.ebuild b/media-libs/xine-lib/xine-lib-1.1.1-r1.ebuild
new file mode 100644
index 000000000000..0312dd9dbe34
--- /dev/null
+++ b/media-libs/xine-lib/xine-lib-1.1.1-r1.ebuild
@@ -0,0 +1,243 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/xine-lib-1.1.1-r1.ebuild,v 1.1 2005/11/20 20:06:45 flameeyes Exp $
+
+inherit eutils flag-o-matic toolchain-funcs libtool autotools
+
+# This should normally be empty string, unless a release has a suffix.
+MY_PKG_SUFFIX=""
+MY_P=${PN}-${PV/_/-}${MY_PKG_SUFFIX}
+
+PATCHLEVEL="17"
+
+DESCRIPTION="Core libraries for Xine movie player"
+HOMEPAGE="http://xine.sourceforge.net/"
+SRC_URI="mirror://sourceforge/xine/${MY_P}.tar.gz
+	http://digilander.libero.it/dgp85/gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="1"
+KEYWORDS="-*"
+IUSE="aalib libcaca arts cle266 esd win32codecs nls dvd X directfb vorbis alsa
+gnome sdl speex theora ipv6 altivec opengl aac fbcon xv xvmc nvidia i8x0
+samba dxr3 vidix mng flac oss v4l xinerama vcd a52 mad imagemagick dts asf
+ffmpeg"
+RESTRICT="nostrip"
+
+RDEPEND="vorbis? ( media-libs/libvorbis )
+	X? ( || ( (
+			x11-libs/libXext
+			x11-libs/libX11 )
+		virtual/x11 ) )
+	xv? ( || ( x11-libs/libXv virtual/x11 ) )
+	xvmc? (
+		|| ( x11-libs/libXvMC virtual/x11 )
+		nvidia? ( media-video/nvidia-glx )
+		cle266? ( || ( x11-drivers/xf86-video-via virtual/x11 ) )
+		i8x0? ( || ( x11-drivers/xf86-video-i810 virtual/x11 ) ) )
+	xinerama? ( || ( x11-libs/libXinerama virtual/x11 ) )
+	win32codecs? ( >=media-libs/win32codecs-0.50 )
+	esd? ( media-sound/esound )
+	dvd? ( >=media-libs/libdvdcss-1.2.7 )
+	arts? ( kde-base/arts )
+	alsa? ( media-libs/alsa-lib )
+	aalib? ( media-libs/aalib )
+	directfb? ( >=dev-libs/DirectFB-0.9.9 )
+	gnome? ( >=gnome-base/gnome-vfs-2.0 )
+	flac? ( >=media-libs/flac-1.0.4 )
+	sdl? ( >=media-libs/libsdl-1.1.5 )
+	dxr3? ( >=media-libs/libfame-0.9.0 )
+	theora? ( media-libs/libtheora )
+	speex? ( media-libs/speex )
+	libcaca? ( media-libs/libcaca )
+	samba? ( net-fs/samba )
+	mng? ( media-libs/libmng )
+	vcd? ( media-video/vcdimager )
+	a52? ( >=media-libs/a52dec-0.7.4-r5 )
+	mad? ( media-libs/libmad )
+	imagemagick? ( media-gfx/imagemagick )
+	dts? ( media-libs/libdts )
+	!=media-libs/xine-lib-0.9.13*"
+
+DEPEND="${RDEPEND}
+	X? ( || ( (
+			x11-base/xorg-server
+			x11-libs/libXt
+			x11-proto/xextproto
+			x11-proto/xproto
+			x11-proto/videoproto
+			x11-proto/xf86vidmodeproto )
+		virtual/x11 )
+		)
+	xinerama? ( || ( x11-proto/xineramaproto virtual/x11 ) )
+	v4l? ( virtual/os-headers )
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+#	>=sys-devel/automake-1.7
+#	>=sys-devel/autoconf-2.59
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	EPATCH_SUFFIX="patch" epatch ${WORKDIR}/patches/
+
+	# AT_M4DIR="m4" eautoreconf
+	elibtoolize
+}
+
+# check for the X11 path for a given library
+get_x11_dir() {
+	if [[ -f "${ROOT}/usr/$(get_libdir)/$1" ]]; then
+		echo "${ROOT}/usr/$(get_libdir)"
+	elif [[ -f "${ROOT}/usr/$(get_libdir)/xorg/$1" ]]; then
+		echo "${ROOT}/usr/$(get_libdir)/xorg"
+	elif [[ -f "${ROOT}/usr/X11R6/$(get_libdir)/$1" ]]; then
+		echo "${ROOT}/usr/X11R6/$(get_libdir)"
+	fi
+}
+
+src_compile() {
+	#prevent quicktime crashing
+	append-flags -frename-registers -ffunction-sections
+
+	# Specific workarounds for too-few-registers arch...
+	if [[ $(tc-arch) == "x86" ]]; then
+		has_pic && append-flags -UHAVE_MMX
+		filter-flags -fforce-addr  # breaks ffmpeg module
+		filter-flags -momit-leaf-frame-pointer # break on gcc 3.4/4.x
+		append-flags -mno-sse -fomit-frame-pointer
+		is-flag -O? || append-flags -O2
+
+		ewarn ""
+		ewarn "Debug information will be almost useless as the frame pointer is omitted."
+		ewarn "This makes debugging harder, so crashes that has no fixed behavior are"
+		ewarn "difficult to fix. Please have that in mind."
+		ewarn ""
+	fi
+
+	local myconf
+
+	# the win32 codec path should ignore $(get_libdir) and always use lib
+	use win32codecs \
+		&& myconf="${myconf} --with-w32-path=/usr/$(get_libdir)/win32"
+
+	# enable/disable appropiate optimizations on sparc
+	[[ "${PROFILE_ARCH}" == "sparc64" ]] && myconf="${myconf} --enable-vis"
+	[[ "${PROFILE_ARCH}" == "sparc" ]] && myconf="${myconf} --disable-vis"
+
+	# The default CFLAGS (-O) is the only thing working on hppa.
+	use hppa && unset CFLAGS
+
+	if use xvmc; then
+		count="0"
+		if use nvidia; then
+			count="`expr ${count} + 1`"
+			xvmclib="XvMCNVIDIA"
+		fi
+
+		if use i8x0; then
+			count="`expr ${count} + 1`"
+			xvmclib="I810XvmC"
+		fi
+
+		if use cle266; then
+			count="`expr ${count} + 1`"
+			xvmclib="viaXvMC"
+		fi
+
+		if [[ "${count}" -gt "1" ]]; then
+			eerror "Invalid combination of USE flags"
+			eerror "When building support for xvmc, you may only include support for one video card:"
+			eerror "   nvidia, i8x0, cle266"
+			eerror ""
+			eerror "XvMC support will not be built."
+		elif [[ -n "${xvmclib}" ]]; then
+			xvmcconf="--with-xvmc-lib=${xvmclib} --with-xxmc-lib=${xvmclib}"
+			xvmcdir=$(get_x11_dir libXvMC.so)
+
+			[[ -z ${xvmcdir} ]] && die "Unable to find libXvMC.so."
+
+			myconf="${myconf} ${xvmcconf} --with-xvmc-path=${xvmcdir} --with-xxmc-path=${xvmcdir}"
+		fi
+	fi
+
+	if use xv; then
+		xvdir=$(get_x11_dir libXv.so)
+
+		[[ -z ${xvdir} ]] && die "Unable to find libXv.so. Did you set USE=\"xv\" when you emerged xorg-x11?"
+
+		myconf="${myconf} --with-xv-path=${xvdir}"
+	fi
+
+	econf \
+		$(use_enable gnome) \
+		$(use_enable nls) \
+		$(use_enable ipv6) \
+		$(use_enable samba) \
+		$(use_enable altivec) \
+		\
+		$(use_enable mng) \
+		$(use_enable imagemagick) \
+		\
+		$(use_enable aac faad) \
+		$(use_enable flac) \
+		$(use_with vorbis ogg) $(use_with vorbis) \
+		$(use_enable speex) \
+		$(use_enable a52) --with-external-a52dec \
+		$(use_enable mad) --with-external-libmad \
+		$(use_enable dts) --with-external-libdts \
+		\
+		$(use_with X x) \
+		$(use_enable xinerama) \
+		$(use_enable vidix) \
+		$(use_enable dxr3) \
+		$(use_enable directfb) \
+		$(use_enable fbcon fb) \
+		$(use_enable opengl) \
+		$(use_enable aalib) \
+		$(use_enable libcaca caca) \
+		$(use_enable sdl) \
+		\
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable arts) \
+		$(use_enable esd) \
+		$(use_enable vcd) --without-internal-vcdlibs \
+		\
+		$(use_enable asf) \
+		$(use_with ffmpeg external-ffmpeg) \
+		--disable-polypaudio \
+		--disable-optimizations \
+		${myconf} \
+		--disable-dependency-tracking || die "econf failed"
+
+		#$(use_with dvdnav external-dvdnav) \
+		#$(use_enable macos macosx-video) $(use_enable macos coreaudio) \
+		# This will be added when polypaudio will be added to portage.
+		# $(use_enable polypaudio)
+
+	emake -j1 || die "emake failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "Install failed"
+
+	dodoc AUTHORS ChangeLog README TODO doc/README* doc/faq/faq.txt
+	dohtml doc/faq/faq.html doc/hackersguide/*.html doc/hackersguide/*.png
+
+	rm -rf ${D}/usr/share/doc/xine
+}
+
+pkg_postinst() {
+	if use win32codecs && ! use asf; then
+		einfo "You choose to build win32codecs support but disabled ASF"
+		einfo "demuxer. This way you'll have support for win32codecs in"
+		einfo "formats like AVI or Matroska, but not in WMV/WMA files."
+		einfo
+		einfo "To be able to play WMV/WMA files, please add asf useflag."
+	fi
+}