Version bump to fix the KSpell2 debacle, bug #152417. Keywording on 3.5.4-r4 and 3.5.5-r5 was limited to the arches having hspell-1.0 available.

Package-Manager: portage-2.1.2_pre3-r8

9 files changed, 741 insertions, 1 deletions

diff --git a/kde-base/kdelibs/ChangeLog b/kde-base/kdelibs/ChangeLog
index 44ee86d21f1c..cec5fdd9336e 100644
--- a/kde-base/kdelibs/ChangeLog
+++ b/kde-base/kdelibs/ChangeLog
@@ -1,6 +1,20 @@
 # ChangeLog for kde-base/kdelibs
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v 1.373 2006/10/19 11:46:31 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v 1.374 2006/10/25 20:29:22 flameeyes Exp $
+
+*kdelibs-3.5.5-r5 (25 Oct 2006)
+*kdelibs-3.5.5-r4 (25 Oct 2006)
+*kdelibs-3.5.4-r4 (25 Oct 2006)
+*kdelibs-3.5.4-r3 (25 Oct 2006)
+
+  25 Oct 2006; Diego Pettenò <flameeyes@gentoo.org>
+  -kdelibs-3.5.4-r1.ebuild, -kdelibs-3.5.4-r2.ebuild,
+  +kdelibs-3.5.4-r3.ebuild, +kdelibs-3.5.4-r4.ebuild,
+  -kdelibs-3.5.5-r1.ebuild, -kdelibs-3.5.5-r2.ebuild,
+  -kdelibs-3.5.5-r3.ebuild, +kdelibs-3.5.5-r4.ebuild,
+  +kdelibs-3.5.5-r5.ebuild:
+  Version bump to fix the KSpell2 debacle, bug #152417. Keywording on 3.5.4-r4
+  and 3.5.5-r5 was limited to the arches having hspell-1.0 available.
 
   19 Oct 2006; Diego Pettenò <flameeyes@gentoo.org>
   kdelibs-3.5.5-r3.ebuild:
diff --git a/kde-base/kdelibs/files/digest-kdelibs-3.5.4-r3 b/kde-base/kdelibs/files/digest-kdelibs-3.5.4-r3
new file mode 100644
index 000000000000..2dfe8bb2da7d
--- /dev/null
+++ b/kde-base/kdelibs/files/digest-kdelibs-3.5.4-r3
@@ -0,0 +1,6 @@
+MD5 6f8254317dd43af7aea2a347656f552a kdelibs-3.5-patchset-05.tar.bz2 36423
+RMD160 684bb235f3b5b3cb900632e11aa912670f641b96 kdelibs-3.5-patchset-05.tar.bz2 36423
+SHA256 f237ccd3a35c629740355fbcf69b0d706690acac832a4d35db5c0d3a30235e0a kdelibs-3.5-patchset-05.tar.bz2 36423
+MD5 979d056ca0e21c12caed270126e60e3e kdelibs-3.5.4.tar.bz2 15450025
+RMD160 a80ce24ee485bcfc7f2f06c3a798401b3188670d kdelibs-3.5.4.tar.bz2 15450025
+SHA256 9458d94d842855b4f0ea30520dc9ed0988563564bc72c8a86a5c40d57ab6887e kdelibs-3.5.4.tar.bz2 15450025
diff --git a/kde-base/kdelibs/files/digest-kdelibs-3.5.4-r4 b/kde-base/kdelibs/files/digest-kdelibs-3.5.4-r4
new file mode 100644
index 000000000000..2dfe8bb2da7d
--- /dev/null
+++ b/kde-base/kdelibs/files/digest-kdelibs-3.5.4-r4
@@ -0,0 +1,6 @@
+MD5 6f8254317dd43af7aea2a347656f552a kdelibs-3.5-patchset-05.tar.bz2 36423
+RMD160 684bb235f3b5b3cb900632e11aa912670f641b96 kdelibs-3.5-patchset-05.tar.bz2 36423
+SHA256 f237ccd3a35c629740355fbcf69b0d706690acac832a4d35db5c0d3a30235e0a kdelibs-3.5-patchset-05.tar.bz2 36423
+MD5 979d056ca0e21c12caed270126e60e3e kdelibs-3.5.4.tar.bz2 15450025
+RMD160 a80ce24ee485bcfc7f2f06c3a798401b3188670d kdelibs-3.5.4.tar.bz2 15450025
+SHA256 9458d94d842855b4f0ea30520dc9ed0988563564bc72c8a86a5c40d57ab6887e kdelibs-3.5.4.tar.bz2 15450025
diff --git a/kde-base/kdelibs/files/digest-kdelibs-3.5.5-r4 b/kde-base/kdelibs/files/digest-kdelibs-3.5.5-r4
new file mode 100644
index 000000000000..79c37c4a8348
--- /dev/null
+++ b/kde-base/kdelibs/files/digest-kdelibs-3.5.5-r4
@@ -0,0 +1,6 @@
+MD5 6f8254317dd43af7aea2a347656f552a kdelibs-3.5-patchset-05.tar.bz2 36423
+RMD160 684bb235f3b5b3cb900632e11aa912670f641b96 kdelibs-3.5-patchset-05.tar.bz2 36423
+SHA256 f237ccd3a35c629740355fbcf69b0d706690acac832a4d35db5c0d3a30235e0a kdelibs-3.5-patchset-05.tar.bz2 36423
+MD5 2cba792e3b0a766431b837c8ef924117 kdelibs-3.5.5.tar.bz2 15486690
+RMD160 8e389869f9a53445754c76a0f7535ef2fffc6d03 kdelibs-3.5.5.tar.bz2 15486690
+SHA256 e487cdd56aa14eec3e100501a5e14658c6329fac30ea0ce812c860e3564c31e3 kdelibs-3.5.5.tar.bz2 15486690
diff --git a/kde-base/kdelibs/files/digest-kdelibs-3.5.5-r5 b/kde-base/kdelibs/files/digest-kdelibs-3.5.5-r5
new file mode 100644
index 000000000000..79c37c4a8348
--- /dev/null
+++ b/kde-base/kdelibs/files/digest-kdelibs-3.5.5-r5
@@ -0,0 +1,6 @@
+MD5 6f8254317dd43af7aea2a347656f552a kdelibs-3.5-patchset-05.tar.bz2 36423
+RMD160 684bb235f3b5b3cb900632e11aa912670f641b96 kdelibs-3.5-patchset-05.tar.bz2 36423
+SHA256 f237ccd3a35c629740355fbcf69b0d706690acac832a4d35db5c0d3a30235e0a kdelibs-3.5-patchset-05.tar.bz2 36423
+MD5 2cba792e3b0a766431b837c8ef924117 kdelibs-3.5.5.tar.bz2 15486690
+RMD160 8e389869f9a53445754c76a0f7535ef2fffc6d03 kdelibs-3.5.5.tar.bz2 15486690
+SHA256 e487cdd56aa14eec3e100501a5e14658c6329fac30ea0ce812c860e3564c31e3 kdelibs-3.5.5.tar.bz2 15486690
diff --git a/kde-base/kdelibs/kdelibs-3.5.4-r3.ebuild b/kde-base/kdelibs/kdelibs-3.5.4-r3.ebuild
new file mode 100644
index 000000000000..927a8af7ea7f
--- /dev/null
+++ b/kde-base/kdelibs/kdelibs-3.5.4-r3.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/kdelibs-3.5.4-r3.ebuild,v 1.1 2006/10/25 20:29:22 flameeyes Exp $
+
+inherit kde flag-o-matic eutils multilib
+set-kdedir 3.5
+
+DESCRIPTION="KDE libraries needed by all KDE programs."
+HOMEPAGE="http://www.kde.org/"
+SRC_URI="mirror://kde/stable/${PV}/src/${P}.tar.bz2
+	mirror://gentoo/kdelibs-3.5-patchset-05.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="3.5"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="acl alsa arts cups doc jpeg2k kerberos legacyssl noutempter openexr spell ssl tiff
+zeroconf kernel_linux fam lua"
+
+# kde.eclass has kdelibs in DEPEND, and we can't have that in here.
+# so we recreate the entire DEPEND from scratch.
+
+# Added aspell-en as dependency to work around bug 131512.
+RDEPEND="$(qt_min_version 3.3.3)
+	arts? ( ~kde-base/arts-${PV} )
+	app-arch/bzip2
+	>=media-libs/freetype-2
+	media-libs/fontconfig
+	>=dev-libs/libxslt-1.1.15
+	>=dev-libs/libxml2-2.6.6
+	>=dev-libs/libpcre-4.2
+	media-libs/libart_lgpl
+	net-dns/libidn
+	acl? ( kernel_linux? ( sys-apps/acl ) )
+	ssl? ( >=dev-libs/openssl-0.9.7d )
+	alsa? ( media-libs/alsa-lib )
+	cups? ( >=net-print/cups-1.1.19 )
+	tiff? ( media-libs/tiff )
+	kerberos? ( virtual/krb5 )
+	jpeg2k? ( media-libs/jasper )
+	openexr? ( >=media-libs/openexr-1.2.2-r2 )
+	zeroconf? ( net-misc/mDNSResponder )
+	fam? ( virtual/fam )
+	virtual/ghostscript
+	!noutempter? ( sys-libs/libutempter )
+	!kde-base/kde-env
+	lua? ( dev-lang/lua )
+	spell? ( app-text/aspell app-dicts/aspell-en )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	sys-devel/gettext"
+
+RDEPEND="${RDEPEND}
+	|| ( ( x11-apps/rgb x11-apps/iceauth ) <virtual/x11-7 )"
+
+# Testing code is rather broken and merely for developer purposes, so disable it.
+RESTRICT="test"
+
+pkg_setup() {
+	if use legacyssl ; then
+		echo ""
+		ewarn "You have the legacyssl use flag enabled, which fixes issues with some broken"
+		ewarn "sites, but breaks others instead. It is strongly discouraged to use it."
+		ewarn "For more information, see bug #128922."
+		echo ""
+	fi
+	if use noutempter ; then
+		echo ""
+		ewarn "Not using utempter, KDE applications won't create login records. Don't remove"
+		ewarn "this functionality, unless you know exactly what you're doing."
+		echo ""
+	fi
+}
+
+src_unpack() {
+	kde_src_unpack
+	if use legacyssl ; then
+		# This patch won't be included upstream, see bug #128922
+		epatch "${WORKDIR}/patches/kdelibs_3.5.4-kssl-3des.patch" || die "Patch did not apply."
+	fi
+
+	if use cups && has_version '>=net-print/cups-1.2_pre'; then
+		cd "${S}"
+
+		EPATCH_EXCLUDE="kubuntu_39_cups12_compile_fixes.diff" \
+		EPATCH_SUFFIX="diff" \
+		EPATCH_MULTI_MSG="Applying KUbuntu patches for CUPS 1.2 support ..." \
+		EPATCH_FORCE="yes" \
+		epatch "${WORKDIR}/kdeprint-3.5.2-cups-1.2-patches/"
+	fi
+
+	epatch "${FILESDIR}/${PN}-3.5-lua.patch"
+}
+
+src_compile() {
+	rm -f ${S}/configure
+
+	myconf="--with-distribution=Gentoo --disable-fast-malloc
+			$(use_enable fam libfam) $(use_enable kernel_linux dnotify)
+			--with-libart --with-libidn
+			$(use_with acl) $(use_with ssl)
+			$(use_with alsa) $(use_with arts)
+			$(use_with kerberos gssapi) $(use_with tiff)
+			$(use_with jpeg2k jasper) $(use_with openexr)
+			$(use_enable cups) $(use_enable zeroconf dnssd)
+			$(use_with !noutempter utempter) $(use_with lua)
+			$(use_with spell aspell) --without-hspell"
+
+	if has_version x11-apps/rgb; then
+		myconf="${myconf} --with-rgbfile=/usr/share/X11/rgb.txt"
+	fi
+
+	# fix bug 58179, bug 85593
+	# kdelibs-3.4.0 needed -fno-gcse; 3.4.1 needs -mminimal-toc; this needs a
+	# closer look... - corsair
+	use ppc64 && append-flags "-mminimal-toc"
+
+	# work around bug #120858, gcc 3.4.x -Os miscompilation
+	use x86 && replace-flags "-Os" "-O2" # see bug #120858
+
+	export BINDNOW_FLAGS="$(bindnow-flags)"
+
+	kde_src_compile
+
+	if use doc; then
+		make apidox || die
+	fi
+}
+
+src_install() {
+	kde_src_install
+
+	if use doc; then
+		make DESTDIR="${D}" install-apidox || die
+	fi
+
+	# Needed to create lib -> lib64 symlink for amd64 2005.0 profile
+	if [ "${SYMLINK_LIB}" = "yes" ]; then
+		dosym $(get_abi_LIBDIR ${DEFAULT_ABI}) ${KDEDIR}/lib
+	fi
+
+	dodir /etc/env.d
+
+	# List all the multilib libdirs
+	local libdirs
+	for libdir in $(get_all_libdirs); do
+		libdirs="${libdirs}:${PREFIX}/${libdir}"
+	done
+
+	cat <<EOF > "${D}"/etc/env.d/45kdepaths-${SLOT} # number goes down with version upgrade
+PATH=${PREFIX}/bin
+ROOTPATH=${PREFIX}/sbin:${PREFIX}/bin
+LDPATH=${libdirs:1}
+CONFIG_PROTECT="${PREFIX}/share/config ${PREFIX}/env ${PREFIX}/shutdown /usr/share/config"
+KDEDIRS="${PREFIX}:/usr:/usr/local"
+#KDE_IS_PRELINKED=1
+EOF
+}
+
+pkg_postinst() {
+	if use zeroconf; then
+		echo
+		einfo "To make zeroconf support available in KDE"
+		einfo "make sure that the 'mdnsd' daemon is running."
+		einfo "Make sure also that multicast dns lookups are"
+		einfo "enabled by editing the 'hosts:' line in"
+		einfo "/etc/nsswitch.conf to include 'mdns', e.g.:"
+		einfo "hosts: files mdns dns"
+		echo
+	fi
+}
diff --git a/kde-base/kdelibs/kdelibs-3.5.4-r4.ebuild b/kde-base/kdelibs/kdelibs-3.5.4-r4.ebuild
new file mode 100644
index 000000000000..cf1cc9ea2d06
--- /dev/null
+++ b/kde-base/kdelibs/kdelibs-3.5.4-r4.ebuild
@@ -0,0 +1,178 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/kdelibs-3.5.4-r4.ebuild,v 1.1 2006/10/25 20:29:22 flameeyes Exp $
+
+inherit kde flag-o-matic eutils multilib
+set-kdedir 3.5
+
+DESCRIPTION="KDE libraries needed by all KDE programs."
+HOMEPAGE="http://www.kde.org/"
+SRC_URI="mirror://kde/stable/${PV}/src/${P}.tar.bz2
+	mirror://gentoo/kdelibs-3.5-patchset-05.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="3.5"
+KEYWORDS="~alpha ~ppc ~x86"
+IUSE="acl alsa arts cups doc jpeg2k kerberos legacyssl noutempter openexr spell ssl tiff
+zeroconf kernel_linux fam lua linguas_he"
+
+# kde.eclass has kdelibs in DEPEND, and we can't have that in here.
+# so we recreate the entire DEPEND from scratch.
+
+# Added aspell-en as dependency to work around bug 131512.
+RDEPEND="$(qt_min_version 3.3.3)
+	arts? ( ~kde-base/arts-${PV} )
+	app-arch/bzip2
+	>=media-libs/freetype-2
+	media-libs/fontconfig
+	>=dev-libs/libxslt-1.1.15
+	>=dev-libs/libxml2-2.6.6
+	>=dev-libs/libpcre-4.2
+	media-libs/libart_lgpl
+	net-dns/libidn
+	acl? ( kernel_linux? ( sys-apps/acl ) )
+	ssl? ( >=dev-libs/openssl-0.9.7d )
+	alsa? ( media-libs/alsa-lib )
+	cups? ( >=net-print/cups-1.1.19 )
+	tiff? ( media-libs/tiff )
+	kerberos? ( virtual/krb5 )
+	jpeg2k? ( media-libs/jasper )
+	openexr? ( >=media-libs/openexr-1.2.2-r2 )
+	zeroconf? ( net-misc/mDNSResponder )
+	fam? ( virtual/fam )
+	virtual/ghostscript
+	!noutempter? ( sys-libs/libutempter )
+	!kde-base/kde-env
+	lua? ( dev-lang/lua )
+	spell? ( app-text/aspell app-dicts/aspell-en
+		linguas_he? ( >=app-text/hspell-1.0 ) )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	sys-devel/gettext"
+
+RDEPEND="${RDEPEND}
+	|| ( ( x11-apps/rgb x11-apps/iceauth ) <virtual/x11-7 )"
+
+# Testing code is rather broken and merely for developer purposes, so disable it.
+RESTRICT="test"
+
+pkg_setup() {
+	if use legacyssl ; then
+		echo ""
+		ewarn "You have the legacyssl use flag enabled, which fixes issues with some broken"
+		ewarn "sites, but breaks others instead. It is strongly discouraged to use it."
+		ewarn "For more information, see bug #128922."
+		echo ""
+	fi
+	if use noutempter ; then
+		echo ""
+		ewarn "Not using utempter, KDE applications won't create login records. Don't remove"
+		ewarn "this functionality, unless you know exactly what you're doing."
+		echo ""
+	fi
+}
+
+src_unpack() {
+	kde_src_unpack
+	if use legacyssl ; then
+		# This patch won't be included upstream, see bug #128922
+		epatch "${WORKDIR}/patches/kdelibs_3.5.4-kssl-3des.patch" || die "Patch did not apply."
+	fi
+
+	if use cups && has_version '>=net-print/cups-1.2_pre'; then
+		cd "${S}"
+
+		EPATCH_EXCLUDE="kubuntu_39_cups12_compile_fixes.diff" \
+		EPATCH_SUFFIX="diff" \
+		EPATCH_MULTI_MSG="Applying KUbuntu patches for CUPS 1.2 support ..." \
+		EPATCH_FORCE="yes" \
+		epatch "${WORKDIR}/kdeprint-3.5.2-cups-1.2-patches/"
+	fi
+
+	epatch "${FILESDIR}/${PN}-3.5-lua.patch"
+}
+
+src_compile() {
+	rm -f ${S}/configure
+
+	myconf="--with-distribution=Gentoo --disable-fast-malloc
+			$(use_enable fam libfam) $(use_enable kernel_linux dnotify)
+			--with-libart --with-libidn
+			$(use_with acl) $(use_with ssl)
+			$(use_with alsa) $(use_with arts)
+			$(use_with kerberos gssapi) $(use_with tiff)
+			$(use_with jpeg2k jasper) $(use_with openexr)
+			$(use_enable cups) $(use_enable zeroconf dnssd)
+			$(use_with !noutempter utempter) $(use_with lua)
+			$(use_with spell aspell)"
+
+	if use spell; then
+		myconf="${myconf} $(use_with linguas_he hspell)"
+	else
+		myconf="${myconf} --without-hspell"
+	fi
+
+	if has_version x11-apps/rgb; then
+		myconf="${myconf} --with-rgbfile=/usr/share/X11/rgb.txt"
+	fi
+
+	# fix bug 58179, bug 85593
+	# kdelibs-3.4.0 needed -fno-gcse; 3.4.1 needs -mminimal-toc; this needs a
+	# closer look... - corsair
+	use ppc64 && append-flags "-mminimal-toc"
+
+	# work around bug #120858, gcc 3.4.x -Os miscompilation
+	use x86 && replace-flags "-Os" "-O2" # see bug #120858
+
+	export BINDNOW_FLAGS="$(bindnow-flags)"
+
+	kde_src_compile
+
+	if use doc; then
+		make apidox || die
+	fi
+}
+
+src_install() {
+	kde_src_install
+
+	if use doc; then
+		make DESTDIR="${D}" install-apidox || die
+	fi
+
+	# Needed to create lib -> lib64 symlink for amd64 2005.0 profile
+	if [ "${SYMLINK_LIB}" = "yes" ]; then
+		dosym $(get_abi_LIBDIR ${DEFAULT_ABI}) ${KDEDIR}/lib
+	fi
+
+	dodir /etc/env.d
+
+	# List all the multilib libdirs
+	local libdirs
+	for libdir in $(get_all_libdirs); do
+		libdirs="${libdirs}:${PREFIX}/${libdir}"
+	done
+
+	cat <<EOF > "${D}"/etc/env.d/45kdepaths-${SLOT} # number goes down with version upgrade
+PATH=${PREFIX}/bin
+ROOTPATH=${PREFIX}/sbin:${PREFIX}/bin
+LDPATH=${libdirs:1}
+CONFIG_PROTECT="${PREFIX}/share/config ${PREFIX}/env ${PREFIX}/shutdown /usr/share/config"
+KDEDIRS="${PREFIX}:/usr:/usr/local"
+#KDE_IS_PRELINKED=1
+EOF
+}
+
+pkg_postinst() {
+	if use zeroconf; then
+		echo
+		einfo "To make zeroconf support available in KDE"
+		einfo "make sure that the 'mdnsd' daemon is running."
+		einfo "Make sure also that multicast dns lookups are"
+		einfo "enabled by editing the 'hosts:' line in"
+		einfo "/etc/nsswitch.conf to include 'mdns', e.g.:"
+		einfo "hosts: files mdns dns"
+		echo
+	fi
+}
diff --git a/kde-base/kdelibs/kdelibs-3.5.5-r4.ebuild b/kde-base/kdelibs/kdelibs-3.5.5-r4.ebuild
new file mode 100644
index 000000000000..61a354d7f7c4
--- /dev/null
+++ b/kde-base/kdelibs/kdelibs-3.5.5-r4.ebuild
@@ -0,0 +1,173 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/kdelibs-3.5.5-r4.ebuild,v 1.1 2006/10/25 20:29:22 flameeyes Exp $
+
+inherit kde flag-o-matic eutils multilib
+set-kdedir 3.5
+
+DESCRIPTION="KDE libraries needed by all KDE programs."
+HOMEPAGE="http://www.kde.org/"
+SRC_URI="mirror://kde/stable/${PV}/src/${P}.tar.bz2
+	mirror://gentoo/kdelibs-3.5-patchset-05.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="3.5"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="acl alsa arts cups doc jpeg2k kerberos legacyssl utempter openexr spell ssl tiff
+zeroconf kernel_linux fam lua"
+
+# kde.eclass has kdelibs in DEPEND, and we can't have that in here.
+# so we recreate the entire DEPEND from scratch.
+
+# Added aspell-en as dependency to work around bug 131512.
+RDEPEND="$(qt_min_version 3.3.3)
+	arts? ( ~kde-base/arts-${PV} )
+	app-arch/bzip2
+	>=media-libs/freetype-2
+	media-libs/fontconfig
+	>=dev-libs/libxslt-1.1.15
+	>=dev-libs/libxml2-2.6.6
+	>=dev-libs/libpcre-4.2
+	media-libs/libart_lgpl
+	net-dns/libidn
+	acl? ( kernel_linux? ( sys-apps/acl ) )
+	ssl? ( >=dev-libs/openssl-0.9.7d )
+	alsa? ( media-libs/alsa-lib )
+	cups? ( >=net-print/cups-1.1.19 )
+	tiff? ( media-libs/tiff )
+	kerberos? ( virtual/krb5 )
+	jpeg2k? ( media-libs/jasper )
+	openexr? ( >=media-libs/openexr-1.2.2-r2 )
+	zeroconf? ( net-misc/mDNSResponder )
+	fam? ( virtual/fam )
+	virtual/ghostscript
+	utempter? ( sys-libs/libutempter )
+	!kde-base/kde-env
+	lua? ( dev-lang/lua )
+	spell? ( app-text/aspell app-dicts/aspell-en )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	sys-devel/gettext"
+
+RDEPEND="${RDEPEND}
+	|| ( ( x11-apps/rgb x11-apps/iceauth ) <virtual/x11-7 ) "
+
+# Testing code is rather broken and merely for developer purposes, so disable it.
+RESTRICT="test"
+
+pkg_setup() {
+	if use legacyssl ; then
+		echo ""
+		elog "You have the legacyssl use flag enabled, which fixes issues with some broken"
+		elog "sites, but breaks others instead. It is strongly discouraged to use it."
+		elog "For more information, see bug #128922."
+		echo ""
+	fi
+	if ! use utempter ; then
+		echo ""
+		elog "On some setups that relies on the correct update of utmp records, not using"
+		elog "utempter might not update them correctly. If you experience unexpected"
+		elog "behaviour, try to rebuild kde-base/kdelibs with utempter use-flag enabled."
+		echo ""
+	fi
+}
+
+src_unpack() {
+	kde_src_unpack
+	if use legacyssl ; then
+		# This patch won't be included upstream, see bug #128922
+		epatch "${WORKDIR}/patches/kdelibs_3.5.4-kssl-3des.patch" || die "Patch did not apply."
+	fi
+
+	# Apply the following patch on the next revision of kdelibs-3.5.5 (fixes kde
+	# bug #135409), which corrects a nasty regression in the cstyle indenter.
+	epatch "${FILESDIR}/${P}-kate-cstyle-indenter-fix.diff"
+
+	# Fix kdeprint timeout when trying to connect to cupsd. Bug #151261.
+	epatch "${FILESDIR}/${P}-kdeprint-cupsd-timeout-fix.patch"
+
+	# Fix rendering (see upstream bug #135639).
+	epatch "${FILESDIR}/${P}-khtml.patch"
+
+	# Allow notification with arts disabled
+	epatch "${FILESDIR}/${P}-noarts.patch"
+	epatch "${FILESDIR}/${P}-noarts-2.patch"
+}
+
+src_compile() {
+	rm -f "${S}/configure"
+
+	myconf="--with-distribution=Gentoo --disable-fast-malloc
+			$(use_enable fam libfam) $(use_enable kernel_linux dnotify)
+			--with-libart --with-libidn
+			$(use_with acl) $(use_with ssl)
+			$(use_with alsa) $(use_with arts)
+			$(use_with kerberos gssapi) $(use_with tiff)
+			$(use_with jpeg2k jasper) $(use_with openexr)
+			$(use_enable cups) $(use_enable zeroconf dnssd)
+			$(use_with utempter) $(use_with lua)
+			$(use_enable kernel_linux sendfile) --enable-mitshm
+			$(use_with spell aspell) --without-hspell"
+
+	if has_version x11-apps/rgb; then
+		myconf="${myconf} --with-rgbfile=/usr/share/X11/rgb.txt"
+	fi
+
+	# fix bug 58179, bug 85593
+	# kdelibs-3.4.0 needed -fno-gcse; 3.4.1 needs -mminimal-toc; this needs a
+	# closer look... - corsair
+	use ppc64 && append-flags "-mminimal-toc"
+
+	# work around bug #120858, gcc 3.4.x -Os miscompilation
+	use x86 && replace-flags "-Os" "-O2" # see bug #120858
+
+	export BINDNOW_FLAGS="$(bindnow-flags)"
+
+	kde_src_compile
+
+	if use doc; then
+		make apidox || die
+	fi
+}
+
+src_install() {
+	kde_src_install
+
+	if use doc; then
+		make DESTDIR="${D}" install-apidox || die
+	fi
+
+	# Needed to create lib -> lib64 symlink for amd64 2005.0 profile
+	if [ "${SYMLINK_LIB}" = "yes" ]; then
+		dosym $(get_abi_LIBDIR ${DEFAULT_ABI}) ${KDEDIR}/lib
+	fi
+
+	dodir /etc/env.d
+
+	# List all the multilib libdirs
+	local libdirs
+	for libdir in $(get_all_libdirs); do
+		libdirs="${libdirs}:${PREFIX}/${libdir}"
+	done
+
+	cat <<EOF > "${D}"/etc/env.d/45kdepaths-${SLOT} # number goes down with version upgrade
+PATH=${PREFIX}/bin
+ROOTPATH=${PREFIX}/sbin:${PREFIX}/bin
+LDPATH=${libdirs:1}
+CONFIG_PROTECT="${PREFIX}/share/config ${PREFIX}/env ${PREFIX}/shutdown /usr/share/config"
+KDEDIRS="${PREFIX}:/usr:/usr/local"
+#KDE_IS_PRELINKED=1
+EOF
+}
+
+pkg_postinst() {
+	if use zeroconf; then
+		echo
+		elog "To make zeroconf support available in KDE make sure that the 'mdnsd' daemon"
+		elog "is running. Make sure also that multicast dns lookups are enabled by editing"
+		elog "the 'hosts:' line in /etc/nsswitch.conf to include 'mdns', e.g.:"
+		elog "  hosts: files mdns dns"
+		echo
+	fi
+}
diff --git a/kde-base/kdelibs/kdelibs-3.5.5-r5.ebuild b/kde-base/kdelibs/kdelibs-3.5.5-r5.ebuild
new file mode 100644
index 000000000000..a4c5164817b9
--- /dev/null
+++ b/kde-base/kdelibs/kdelibs-3.5.5-r5.ebuild
@@ -0,0 +1,180 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/kdelibs-3.5.5-r5.ebuild,v 1.1 2006/10/25 20:29:22 flameeyes Exp $
+
+inherit kde flag-o-matic eutils multilib
+set-kdedir 3.5
+
+DESCRIPTION="KDE libraries needed by all KDE programs."
+HOMEPAGE="http://www.kde.org/"
+SRC_URI="mirror://kde/stable/${PV}/src/${P}.tar.bz2
+	mirror://gentoo/kdelibs-3.5-patchset-05.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="3.5"
+KEYWORDS="~alpha ~ppc ~x86"
+IUSE="acl alsa arts cups doc jpeg2k kerberos legacyssl utempter openexr spell ssl tiff
+zeroconf kernel_linux fam lua linguas_he"
+
+# kde.eclass has kdelibs in DEPEND, and we can't have that in here.
+# so we recreate the entire DEPEND from scratch.
+
+# Added aspell-en as dependency to work around bug 131512.
+RDEPEND="$(qt_min_version 3.3.3)
+	arts? ( ~kde-base/arts-${PV} )
+	app-arch/bzip2
+	>=media-libs/freetype-2
+	media-libs/fontconfig
+	>=dev-libs/libxslt-1.1.15
+	>=dev-libs/libxml2-2.6.6
+	>=dev-libs/libpcre-4.2
+	media-libs/libart_lgpl
+	net-dns/libidn
+	acl? ( kernel_linux? ( sys-apps/acl ) )
+	ssl? ( >=dev-libs/openssl-0.9.7d )
+	alsa? ( media-libs/alsa-lib )
+	cups? ( >=net-print/cups-1.1.19 )
+	tiff? ( media-libs/tiff )
+	kerberos? ( virtual/krb5 )
+	jpeg2k? ( media-libs/jasper )
+	openexr? ( >=media-libs/openexr-1.2.2-r2 )
+	zeroconf? ( net-misc/mDNSResponder )
+	fam? ( virtual/fam )
+	virtual/ghostscript
+	utempter? ( sys-libs/libutempter )
+	!kde-base/kde-env
+	lua? ( dev-lang/lua )
+	spell? ( app-text/aspell app-dicts/aspell-en
+		linguas_he? ( >=app-text/hspell-1.0 ) )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	sys-devel/gettext"
+
+RDEPEND="${RDEPEND}
+	|| ( ( x11-apps/rgb x11-apps/iceauth ) <virtual/x11-7 ) "
+
+# Testing code is rather broken and merely for developer purposes, so disable it.
+RESTRICT="test"
+
+pkg_setup() {
+	if use legacyssl ; then
+		echo ""
+		elog "You have the legacyssl use flag enabled, which fixes issues with some broken"
+		elog "sites, but breaks others instead. It is strongly discouraged to use it."
+		elog "For more information, see bug #128922."
+		echo ""
+	fi
+	if ! use utempter ; then
+		echo ""
+		elog "On some setups that relies on the correct update of utmp records, not using"
+		elog "utempter might not update them correctly. If you experience unexpected"
+		elog "behaviour, try to rebuild kde-base/kdelibs with utempter use-flag enabled."
+		echo ""
+	fi
+}
+
+src_unpack() {
+	kde_src_unpack
+	if use legacyssl ; then
+		# This patch won't be included upstream, see bug #128922
+		epatch "${WORKDIR}/patches/kdelibs_3.5.4-kssl-3des.patch" || die "Patch did not apply."
+	fi
+
+	# Apply the following patch on the next revision of kdelibs-3.5.5 (fixes kde
+	# bug #135409), which corrects a nasty regression in the cstyle indenter.
+	epatch "${FILESDIR}/${P}-kate-cstyle-indenter-fix.diff"
+
+	# Fix kdeprint timeout when trying to connect to cupsd. Bug #151261.
+	epatch "${FILESDIR}/${P}-kdeprint-cupsd-timeout-fix.patch"
+
+	# Fix rendering (see upstream bug #135639).
+	epatch "${FILESDIR}/${P}-khtml.patch"
+
+	# Allow notification with arts disabled
+	epatch "${FILESDIR}/${P}-noarts.patch"
+	epatch "${FILESDIR}/${P}-noarts-2.patch"
+}
+
+src_compile() {
+	rm -f "${S}/configure"
+
+	myconf="--with-distribution=Gentoo --disable-fast-malloc
+			$(use_enable fam libfam) $(use_enable kernel_linux dnotify)
+			--with-libart --with-libidn
+			$(use_with acl) $(use_with ssl)
+			$(use_with alsa) $(use_with arts)
+			$(use_with kerberos gssapi) $(use_with tiff)
+			$(use_with jpeg2k jasper) $(use_with openexr)
+			$(use_enable cups) $(use_enable zeroconf dnssd)
+			$(use_with utempter) $(use_with lua)
+			$(use_enable kernel_linux sendfile) --enable-mitshm
+			$(use_with spell aspell)"
+
+	if use spell; then
+		myconf="${myconf} $(use_with linguas_he hspell)"
+	else
+		myconf="${myconf} --without-hspell"
+	fi
+
+	if has_version x11-apps/rgb; then
+		myconf="${myconf} --with-rgbfile=/usr/share/X11/rgb.txt"
+	fi
+
+	# fix bug 58179, bug 85593
+	# kdelibs-3.4.0 needed -fno-gcse; 3.4.1 needs -mminimal-toc; this needs a
+	# closer look... - corsair
+	use ppc64 && append-flags "-mminimal-toc"
+
+	# work around bug #120858, gcc 3.4.x -Os miscompilation
+	use x86 && replace-flags "-Os" "-O2" # see bug #120858
+
+	export BINDNOW_FLAGS="$(bindnow-flags)"
+
+	kde_src_compile
+
+	if use doc; then
+		make apidox || die
+	fi
+}
+
+src_install() {
+	kde_src_install
+
+	if use doc; then
+		make DESTDIR="${D}" install-apidox || die
+	fi
+
+	# Needed to create lib -> lib64 symlink for amd64 2005.0 profile
+	if [ "${SYMLINK_LIB}" = "yes" ]; then
+		dosym $(get_abi_LIBDIR ${DEFAULT_ABI}) ${KDEDIR}/lib
+	fi
+
+	dodir /etc/env.d
+
+	# List all the multilib libdirs
+	local libdirs
+	for libdir in $(get_all_libdirs); do
+		libdirs="${libdirs}:${PREFIX}/${libdir}"
+	done
+
+	cat <<EOF > "${D}"/etc/env.d/45kdepaths-${SLOT} # number goes down with version upgrade
+PATH=${PREFIX}/bin
+ROOTPATH=${PREFIX}/sbin:${PREFIX}/bin
+LDPATH=${libdirs:1}
+CONFIG_PROTECT="${PREFIX}/share/config ${PREFIX}/env ${PREFIX}/shutdown /usr/share/config"
+KDEDIRS="${PREFIX}:/usr:/usr/local"
+#KDE_IS_PRELINKED=1
+EOF
+}
+
+pkg_postinst() {
+	if use zeroconf; then
+		echo
+		elog "To make zeroconf support available in KDE make sure that the 'mdnsd' daemon"
+		elog "is running. Make sure also that multicast dns lookups are enabled by editing"
+		elog "the 'hosts:' line in /etc/nsswitch.conf to include 'mdns', e.g.:"
+		elog "  hosts: files mdns dns"
+		echo
+	fi
+}