Restore requests-1.2.2 to satisfy the silly dependency set in python-cinderclient.

Package-Manager: portage-2.2.6/cvs/Linux x86_64
Manifest-Sign-Key: 0x0BBEEA1FEA4843A4

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/requests/requests-1.2.2.ebuild b/dev-python/requests/requests-1.2.2.ebuild
new file mode 100644
index 000000000000..0fb66fadb9dd
--- /dev/null
+++ b/dev-python/requests/requests-1.2.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/requests/requests-1.2.2.ebuild,v 1.4 2013/09/25 22:59:40 floppym Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP library for human beings"
+HOMEPAGE="http://python-requests.org/ http://pypi.python.org/pypi/requests"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+
+# bundles dev-python/urllib3 snapshot
+RDEPEND="app-misc/ca-certificates
+	dev-python/charade[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+# tests connect to various remote sites
+RESTRICT="test"
+
+DOCS=( README.rst HISTORY.rst )
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}"/${PN}-1.2.0-system-cacerts.patch
+		"${FILESDIR}"/${PN}-1.2.0-system-libs.patch
+		"${FILESDIR}"/${PN}-1.2.1-urllib3-py3.patch
+	)
+
+	# use system charade
+	rm -r requests/packages/charade || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests || die "Tests fail with ${EPYTHON}"
+}