Version bump.

NEWS
~~~~

- Pyro4.test.echoserver now correctly runs the NS’s broadcast server as well
- unix domain socket creation no longer fails when bind or connect address is
  unicode instead of str
- docs: added more info on dealing with new serialization configuration in
  existing code
- docs: improved name server documentation on registering objects
- docs: various small updates

Package-Manager: portage-2.2.8-r1/cvs/Linux x86_64
Manifest-Sign-Key: 0xF0134531E1DBFAB5

1 files changed, 78 insertions, 0 deletions

diff --git a/dev-python/pyro/pyro-4.23.ebuild b/dev-python/pyro/pyro-4.23.ebuild
new file mode 100644
index 000000000000..3f391832f16f
--- /dev/null
+++ b/dev-python/pyro/pyro-4.23.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyro/pyro-4.23.ebuild,v 1.1 2014/01/23 08:42:01 aidecoe Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
+
+inherit distutils-r1
+
+MY_PN="Pyro4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Advanced and powerful Distributed Object Technology system written entirely in Python"
+HOMEPAGE="http://www.xs4all.nl/~irmen/pyro/ http://pypi.python.org/pypi/Pyro4"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="!dev-python/pyro:0
+	dev-python/serpent[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		virtual/python-unittest2[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	sed \
+		-e '/sys.path.insert/a sys.path.insert(1,"PyroTests")' \
+		-i tests/run_suite.py || die
+
+	# Disable tests requiring network connection.
+	sed \
+		-e "s/testBCstart/_&/" \
+		-e "s/testDaemonPyroObj/_&/" \
+		-e "s/testLookupAndRegister/_&/" \
+		-e "s/testMulti/_&/" \
+		-e "s/testRefuseDottedNames/_&/" \
+		-e "s/testResolve/_&/" \
+		-e "s/testBCLookup/_&/" \
+		-i tests/PyroTests/test_naming.py || die
+	sed \
+		-e "s/testOwnloopBasics/_&/" \
+		-e "s/testStartNSfunc/_&/" \
+		-i tests/PyroTests/test_naming2.py || die
+
+	sed \
+		-e "s/testServerConnections/_&/" \
+	    -e "s/testServerParallelism/_&/" \
+		-i tests/PyroTests/test_server.py || die
+
+	sed \
+		-e "s/testBroadcast/_&/" \
+		-e "s/testGetIP/_&/" \
+		-e "s/testGetIpVersion[46]/_&/" \
+		-i tests/PyroTests/test_socket.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${S}"/tests || die
+	${PYTHON} run_suite.py || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}