Add live ebuilds for trunk and for EMACS_23_1_RC branch.

Package-Manager: portage-2.2_rc33/cvs/Linux i686

4 files changed, 311 insertions, 7 deletions

diff --git a/app-editors/emacs-cvs/ChangeLog b/app-editors/emacs-cvs/ChangeLog
index 4c85aedbd4d9..9b080be82aa0 100644
--- a/app-editors/emacs-cvs/ChangeLog
+++ b/app-editors/emacs-cvs/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for app-editors/emacs-cvs
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-cvs/ChangeLog,v 1.250 2009/06/19 22:42:51 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-cvs/ChangeLog,v 1.251 2009/06/21 17:00:33 ulm Exp $
+
+*emacs-cvs-23.1.9999 (21 Jun 2009)
+*emacs-cvs-23.0.9999-r2 (21 Jun 2009)
+
+  21 Jun 2009; Ulrich Mueller <ulm@gentoo.org>
+  -emacs-cvs-23.0.9999-r1.ebuild, +emacs-cvs-23.0.9999-r2.ebuild,
+  +emacs-cvs-23.1.9999.ebuild:
+  Upstream CVS has been branched for the 23.1 release. 23.0.9999-r2 is the
+  live ebuild for the EMACS_23_1_RC branch, 23.1.9999 for the trunk.
 
 *emacs-cvs-23.0.95 (19 Jun 2009)
 
diff --git a/app-editors/emacs-cvs/Manifest b/app-editors/emacs-cvs/Manifest
index cfad02caa0ff..d3a3b1255b08 100644
--- a/app-editors/emacs-cvs/Manifest
+++ b/app-editors/emacs-cvs/Manifest
@@ -9,13 +9,14 @@ DIST emacs-23.0.95.tar.gz 42792970 RMD160 07c3aed638dc5ba3d825215cdca9d280c888bb
 EBUILD emacs-cvs-23.0.93.ebuild 8918 RMD160 87fcde2928b4e8589e258d25ee32b2a5581ef128 SHA1 8693b1499538873bc159e08037f0dd8beaf71019 SHA256 e7de496f60d7bed0558e90bd1796ed2dd0f38b5df59f6cd2417c818f2183e071
 EBUILD emacs-cvs-23.0.94.ebuild 8922 RMD160 4ec46c8ad3f0bcbebc9431a11ec608608762d95f SHA1 e8c7aea5607179f3c6a47711572ac399f63273e1 SHA256 469cce1549b1de5caac9e656e9a03dbf544a5858b17c69a2fb4dbe699ab93949
 EBUILD emacs-cvs-23.0.95.ebuild 8924 RMD160 061f70bc7908daac82ea17654b85bc097112cd6f SHA1 2894ecd2d567c42d9336fbd26d4b65bf24b54127 SHA256 9512fd859830c60dbe32318550b184d6e79ee0f839d84c3d9d39ba60e4c233ac
-EBUILD emacs-cvs-23.0.9999-r1.ebuild 8870 RMD160 5504e7413c182945479e6d62eabe133242837156 SHA1 5a4997c9d7d8ee18f4fb06abf3be6e0795f653cd SHA256 da9e6daf2b3fa009b167a54d69e9d47968561432d6cb926806738bb0b16204af
-MISC ChangeLog 46838 RMD160 0959229ce181217542240d1b7d1335e4dba038eb SHA1 cb9606d411fadc72f03c9a7e83580d55646a4dc3 SHA256 dbbcb56a139bdc2b6ae374da2c69b98d2ac47b601936ec5781aa3c278449cde8
+EBUILD emacs-cvs-23.0.9999-r2.ebuild 8883 RMD160 429de5ead8f74a0f77421eec3f75f14558f013e0 SHA1 530c626ddcbdbaea2a48b9bb7c2f154574e13abf SHA256 ccca56e2a6aa217c485a74367008a01faf6d610f6d6f2998cf585d7c45bf0f9b
+EBUILD emacs-cvs-23.1.9999.ebuild 8866 RMD160 33aa402f2be8a753e4ac16706477cd9f4a7834ad SHA1 e71010d3091d46ee1fff4b9575b25facd060d376 SHA256 086de832a7b5242e4819b8167acdb45a8f4da516fd44b233ef07713dfebfe8ef
+MISC ChangeLog 47201 RMD160 29ecf38ab6618f4a53f0f1c9d090c4e553eea0eb SHA1 e7d45eac8adc5aa3b4236a0325f7e35bc28ab9af SHA256 e4a78f95417725f76102969a5a8f14d355b86501db1ce346640be79b15322f65
 MISC metadata.xml 1529 RMD160 e40abfeff829d64e9f7d699d4e8fc5c4d6097bb5 SHA1 b2c01905cf0230739a45ad86bfbec800f8562c9f SHA256 b24dbef03ac32c182f69573275d416d664537eee2667e1e8c3199d4d34f3b20e
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v1.4.9 (GNU/Linux)
 
-iEYEARECAAYFAko8FNgACgkQOeoy/oIi7uzA5ACg0ZlO33jFbQ1foRDI7ueBBUhf
-5xcAnjblaus8cjUYwd1EdlqeS9L3H6Q9
-=ma7g
+iEYEARECAAYFAko+Z6AACgkQOeoy/oIi7uzjxgCgkJhzHOtzHwuXAZwS2lxehYxR
+EQ8AoMNXvDi/WStxtYZJdu8ec0l7xnk+
+=Cd6y
 -----END PGP SIGNATURE-----
diff --git a/app-editors/emacs-cvs/emacs-cvs-23.0.9999-r2.ebuild b/app-editors/emacs-cvs/emacs-cvs-23.0.9999-r2.ebuild
new file mode 100644
index 000000000000..13bf42ce85d5
--- /dev/null
+++ b/app-editors/emacs-cvs/emacs-cvs-23.0.9999-r2.ebuild
@@ -0,0 +1,294 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-cvs/emacs-cvs-23.0.9999-r2.ebuild,v 1.1 2009/06/21 17:00:33 ulm Exp $
+
+EAPI=2
+
+inherit autotools elisp-common eutils flag-o-matic
+
+if [ "${PV##*.}" = "9999" ]; then
+	ECVS_AUTH="pserver"
+	ECVS_SERVER="cvs.savannah.gnu.org:/sources/emacs"
+	ECVS_MODULE="emacs"
+	ECVS_BRANCH="EMACS_23_1_RC"
+	ECVS_LOCALNAME="emacs-23.1"
+	inherit cvs
+	SRC_URI=""
+	S="${WORKDIR}/${ECVS_LOCALNAME}"
+else
+	SRC_URI="mirror://gentoo/emacs-${PV}.tar.gz
+		ftp://alpha.gnu.org/gnu/emacs/pretest/emacs-${PV}.tar.gz"
+	# FULL_VERSION keeps the full version number, which is needed in
+	# order to determine some path information correctly for copy/move
+	# operations later on
+	FULL_VERSION="${PV%%_*}"
+	S="${WORKDIR}/emacs-${FULL_VERSION}"
+fi
+
+DESCRIPTION="The extensible, customizable, self-documenting real-time display editor"
+HOMEPAGE="http://www.gnu.org/software/emacs/"
+
+LICENSE="GPL-3 FDL-1.3 BSD as-is X11 W3C unicode"
+SLOT="23"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="alsa dbus gif gpm gtk gzip-el hesiod jpeg kerberos m17n-lib motif png sound source svg tiff toolkit-scroll-bars X Xaw3d xft +xpm"
+RESTRICT="strip"
+
+RDEPEND="sys-libs/ncurses
+	>=app-admin/eselect-emacs-1.2
+	net-libs/liblockfile
+	hesiod? ( net-dns/hesiod )
+	kerberos? ( virtual/krb5 )
+	alsa? ( media-libs/alsa-lib )
+	gpm? ( sys-libs/gpm )
+	dbus? ( sys-apps/dbus )
+	X? (
+		x11-libs/libXmu
+		x11-libs/libXt
+		x11-misc/xbitmaps
+		gif? ( media-libs/giflib )
+		jpeg? ( media-libs/jpeg )
+		png? ( media-libs/libpng )
+		svg? ( >=gnome-base/librsvg-2.0 )
+		tiff? ( media-libs/tiff )
+		xpm? ( x11-libs/libXpm )
+		xft? (
+			media-libs/fontconfig
+			media-libs/freetype
+			x11-libs/libXft
+			m17n-lib? (
+				>=dev-libs/libotf-0.9.4
+				>=dev-libs/m17n-lib-1.5.1
+			)
+		)
+		gtk? ( x11-libs/gtk+:2 )
+		!gtk? (
+			Xaw3d? ( x11-libs/Xaw3d )
+			!Xaw3d? ( motif? ( x11-libs/openmotif ) )
+		)
+	)"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	gzip-el? ( app-arch/gzip )"
+
+RDEPEND="${RDEPEND}
+	>=app-emacs/emacs-common-gentoo-1[X?]"
+
+EMACS_SUFFIX="emacs-${SLOT}"
+SITEFILE="20${PN}-${SLOT}-gentoo.el"
+
+src_prepare() {
+	if [ "${PV##*.}" = "9999" ]; then
+		FULL_VERSION=$(grep 'defconst[	 ]*emacs-version' lisp/version.el \
+			| sed -e 's/^[^"]*"\([^"]*\)".*$/\1/')
+		[ "${FULL_VERSION}" ] || die "Cannot determine current Emacs version"
+		echo
+		einfo "Emacs CVS branch: ${ECVS_BRANCH}"
+		einfo "Emacs version number: ${FULL_VERSION}"
+		[ "${FULL_VERSION%.*}" = ${PV%.*} ] \
+			|| die "Upstream version number changed to ${FULL_VERSION}"
+		echo
+	fi
+
+	sed -i -e "s:/usr/lib/crtbegin.o:$(`tc-getCC` -print-file-name=crtbegin.o):g" \
+		-e "s:/usr/lib/crtend.o:$(`tc-getCC` -print-file-name=crtend.o):g" \
+		"${S}"/src/s/freebsd.h || die "unable to sed freebsd.h settings"
+
+	if ! use alsa; then
+		# ALSA is detected even if not requested by its USE flag.
+		# Suppress it by supplying pkg-config with a wrong library name.
+		sed -i -e "/ALSA_MODULES=/s/alsa/DiSaBlEaLsA/" configure.in \
+			|| die "unable to sed configure.in"
+	fi
+	if ! use gzip-el; then
+		# Emacs' build system automatically detects the gzip binary and
+		# compresses el files. We don't want that so confuse it with a
+		# wrong binary name
+		sed -i -e "s/ gzip/ PrEvEnTcOmPrEsSiOn/" configure.in \
+			|| die "unable to sed configure.in"
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	ALLOWED_FLAGS=""
+	strip-flags
+	#unset LDFLAGS
+	if use sh; then
+		replace-flags -O[1-9] -O0		#262359
+	else
+		replace-flags -O[3-9] -O2
+	fi
+
+	local myconf
+
+	if use alsa && ! use sound; then
+		echo
+		einfo "Although sound USE flag is disabled you chose to have alsa,"
+		einfo "so sound is switched on anyway."
+		echo
+		myconf="${myconf} --with-sound"
+	else
+		myconf="${myconf} $(use_with sound)"
+	fi
+
+	if use X; then
+		myconf="${myconf} --with-x"
+		myconf="${myconf} $(use_with toolkit-scroll-bars)"
+		myconf="${myconf} $(use_with gif) $(use_with jpeg)"
+		myconf="${myconf} $(use_with png) $(use_with svg rsvg)"
+		myconf="${myconf} $(use_with tiff) $(use_with xpm)"
+		myconf="${myconf} $(use_with xft)"
+
+		if use xft; then
+			myconf="${myconf} $(use_with m17n-lib libotf)"
+			myconf="${myconf} $(use_with m17n-lib m17n-flt)"
+		else
+			myconf="${myconf} --without-libotf --without-m17n-flt"
+			use m17n-lib && ewarn \
+				"USE flag \"m17n-lib\" has no effect because xft is not set."
+		fi
+
+		# GTK+ is the default toolkit if USE=gtk is chosen with other
+		# possibilities. Emacs upstream thinks this should be standard
+		# policy on all distributions
+		if use gtk; then
+			einfo "Configuring to build with GIMP Toolkit (GTK+)"
+			myconf="${myconf} --with-x-toolkit=gtk"
+		elif use Xaw3d; then
+			einfo "Configuring to build with Xaw3d (Athena/Lucid) toolkit"
+			myconf="${myconf} --with-x-toolkit=athena"
+		elif use motif; then
+			einfo "Configuring to build with Motif toolkit"
+			myconf="${myconf} --with-x-toolkit=motif"
+		else
+			einfo "Configuring to build with no toolkit"
+			myconf="${myconf} --with-x-toolkit=no"
+		fi
+
+		local f tk=
+		for f in gtk Xaw3d motif; do
+			use ${f} || continue
+			[ "${tk}" ] \
+				&& ewarn "USE flag \"${f}\" ignored (superseded by \"${tk}\")"
+			tk="${tk}${tk:+ }${f}"
+		done
+	else
+		myconf="${myconf} --without-x"
+	fi
+
+	myconf="${myconf} $(use_with hesiod)"
+	myconf="${myconf} $(use_with kerberos) $(use_with kerberos kerberos5)"
+	myconf="${myconf} $(use_with gpm) $(use_with dbus)"
+
+	econf \
+		--program-suffix=-${EMACS_SUFFIX} \
+		--infodir=/usr/share/info/${EMACS_SUFFIX} \
+		${myconf} || die "econf emacs failed"
+}
+
+src_compile() {
+	export SANDBOX_ON=0			# for the unbelievers, see Bug #131505
+	if [ "${PV##*.}" = "9999" ]; then
+		emake CC="$(tc-getCC)" bootstrap || die "make bootstrap failed"
+		# cleanup, otherwise emacs will be dumped again in src_install
+		(cd src; emake versionclean)
+	fi
+	emake CC="$(tc-getCC)" || die "emake failed"
+}
+
+src_install () {
+	local i m
+
+	emake install DESTDIR="${D}" || die "make install failed"
+
+	rm "${D}"/usr/bin/emacs-${FULL_VERSION}-${EMACS_SUFFIX} \
+		|| die "removing duplicate emacs executable failed"
+	mv "${D}"/usr/bin/emacs-${EMACS_SUFFIX} "${D}"/usr/bin/${EMACS_SUFFIX} \
+		|| die "moving Emacs executable failed"
+
+	# move info documentation to the correct place
+	for i in "${D}"/usr/share/info/${EMACS_SUFFIX}/*; do
+		mv "${i}" "${i}.info" || die "mv info failed"
+	done
+
+	# move man pages to the correct place
+	for m in "${D}"/usr/share/man/man1/* ; do
+		mv "${m}" "${m%.1}-${EMACS_SUFFIX}.1" || die "mv man failed"
+	done
+
+	# avoid collision between slots, see bug #169033 e.g.
+	rm "${D}"/usr/share/emacs/site-lisp/subdirs.el
+	rm -rf "${D}"/usr/share/{applications,icons}
+	rm "${D}"/var/lib/games/emacs/{snake,tetris}-scores
+	keepdir /var/lib/games/emacs
+
+	local c=";;"
+	if use source; then
+		insinto /usr/share/emacs/${FULL_VERSION}/src
+		# This is not meant to install all the source -- just the
+		# C source you might find via find-function
+		doins src/*.[ch]
+		c=""
+	fi
+
+	sed 's/^X//' >"${SITEFILE}" <<-EOF
+	X
+	;;; ${PN}-${SLOT} site-lisp configuration
+	X
+	(when (string-match "\\\\\`${FULL_VERSION//./\\\\.}\\\\>" emacs-version)
+	X  ${c}(setq find-function-C-source-directory
+	X  ${c}      "/usr/share/emacs/${FULL_VERSION}/src")
+	X  (let ((path (getenv "INFOPATH"))
+	X	(dir "/usr/share/info/${EMACS_SUFFIX}"))
+	X    (and path
+	X	 ;; move Emacs Info dir to beginning of list
+	X	 (setq Info-directory-list
+	X	       (cons dir (delete dir (split-string path ":" t)))))))
+	EOF
+	elisp-site-file-install "${SITEFILE}" || die
+
+	dodoc README BUGS || die "dodoc failed"
+}
+
+emacs-infodir-rebuild() {
+	# Depending on the Portage version, the Info dir file is compressed
+	# or removed. It is only rebuilt by Portage if our directory is in
+	# INFOPATH, which is not guaranteed. So we rebuild it ourselves.
+
+	local infodir=/usr/share/info/${EMACS_SUFFIX} f
+	[ -d "${ROOT}"${infodir} ] || return	# may occur with FEATURES=noinfo
+	einfo "Regenerating Info directory index in ${infodir} ..."
+	rm -f "${ROOT}"${infodir}/dir{,.*}
+	for f in "${ROOT}"${infodir}/*.info*; do
+		[[ ${f##*/} != *[0-9].info* && -e ${f} ]] \
+			&& install-info --info-dir="${ROOT}"${infodir} "${f}" &>/dev/null
+	done
+	rmdir "${ROOT}"${infodir} 2>/dev/null	# remove dir if it is empty
+	echo
+}
+
+pkg_postinst() {
+	local f
+	for f in "${ROOT}"/var/lib/games/emacs/{snake,tetris}-scores; do
+		[ -e "${f}" ] || touch "${f}"
+	done
+
+	elisp-site-regen
+	emacs-infodir-rebuild
+	eselect emacs update ifunset
+
+	echo
+	elog "You can set the version to be started by /usr/bin/emacs through"
+	elog "the Emacs eselect module, which also redirects man and info pages."
+	elog "You can therefore test emacs-cvs along with the stable release."
+	elog "\"man emacs.eselect\" for details."
+}
+
+pkg_postrm() {
+	elisp-site-regen
+	emacs-infodir-rebuild
+	eselect emacs update ifunset
+}
diff --git a/app-editors/emacs-cvs/emacs-cvs-23.0.9999-r1.ebuild b/app-editors/emacs-cvs/emacs-cvs-23.1.9999.ebuild
index 7f1c1f575c54..e969b506818f 100644
--- a/app-editors/emacs-cvs/emacs-cvs-23.0.9999-r1.ebuild
+++ b/app-editors/emacs-cvs/emacs-cvs-23.1.9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-cvs/emacs-cvs-23.0.9999-r1.ebuild,v 1.13 2009/06/19 22:42:51 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-cvs/emacs-cvs-23.1.9999.ebuild,v 1.1 2009/06/21 17:00:33 ulm Exp $
 
 EAPI=2