New version for GNOME 2.28.

Package-Manager: portage-2.2_rc46/cvs/Linux x86_64

6 files changed, 126 insertions, 3 deletions

diff --git a/x11-themes/gnome-backgrounds/ChangeLog b/x11-themes/gnome-backgrounds/ChangeLog
index 56d8e68e4a0e..04d28b7c07b9 100644
--- a/x11-themes/gnome-backgrounds/ChangeLog
+++ b/x11-themes/gnome-backgrounds/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-themes/gnome-backgrounds
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-themes/gnome-backgrounds/ChangeLog,v 1.113 2009/10/25 21:34:50 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-themes/gnome-backgrounds/ChangeLog,v 1.114 2009/10/29 22:45:34 eva Exp $
+
+*gnome-backgrounds-2.28.0 (29 Oct 2009)
+
+  29 Oct 2009; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-backgrounds-2.28.0.ebuild:
+  New version for GNOME 2.28.
 
   25 Oct 2009; Gilles Dartiguelongue <eva@gentoo.org>
   -gnome-backgrounds-2.20.0.ebuild, -gnome-backgrounds-2.22.0.ebuild:
diff --git a/x11-themes/gnome-backgrounds/gnome-backgrounds-2.28.0.ebuild b/x11-themes/gnome-backgrounds/gnome-backgrounds-2.28.0.ebuild
new file mode 100644
index 000000000000..22ab408c0380
--- /dev/null
+++ b/x11-themes/gnome-backgrounds/gnome-backgrounds-2.28.0.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-themes/gnome-backgrounds/gnome-backgrounds-2.28.0.ebuild,v 1.1 2009/10/29 22:45:34 eva Exp $
+
+GCONF_DEBUG="no"
+
+inherit gnome2
+
+DESCRIPTION="A set of backgrounds packaged with the GNOME desktop"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND=""
+DEPEND="sys-devel/gettext
+	>=dev-util/intltool-0.35"
+
+DOCS="AUTHORS ChangeLog NEWS README"
diff --git a/x11-themes/gnome-themes/ChangeLog b/x11-themes/gnome-themes/ChangeLog
index 24c35899b6eb..8b4e0e489365 100644
--- a/x11-themes/gnome-themes/ChangeLog
+++ b/x11-themes/gnome-themes/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-themes/gnome-themes
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-themes/gnome-themes/ChangeLog,v 1.216 2009/10/24 16:34:25 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-themes/gnome-themes/ChangeLog,v 1.217 2009/10/29 22:41:49 eva Exp $
+
+*gnome-themes-2.28.1 (29 Oct 2009)
+
+  29 Oct 2009; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-themes-2.28.1.ebuild:
+  New version for GNOME 2.28.
 
   24 Oct 2009; nixnut <nixnut@gentoo.org> gnome-themes-2.26.3.1.ebuild:
   ppc stable #281427
diff --git a/x11-themes/gnome-themes/gnome-themes-2.28.1.ebuild b/x11-themes/gnome-themes/gnome-themes-2.28.1.ebuild
new file mode 100644
index 000000000000..dfd74d9b52a4
--- /dev/null
+++ b/x11-themes/gnome-themes/gnome-themes-2.28.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-themes/gnome-themes/gnome-themes-2.28.1.ebuild,v 1.1 2009/10/29 22:41:49 eva Exp $
+
+GCONF_DEBUG="no"
+
+inherit eutils gnome2
+
+DESCRIPTION="A set of GNOME themes, with sets for users with limited or low vision"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="accessibility"
+
+RDEPEND=">=x11-libs/gtk+-2
+	 >=x11-themes/gtk-engines-2.15.3"
+DEPEND="${RDEPEND}
+	>=x11-misc/icon-naming-utils-0.8.7
+	>=dev-util/pkgconfig-0.19
+	>=dev-util/intltool-0.35"
+# dev-perl/XML-LibXML is bug 266136
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+# This ebuild does not install any binaries
+RESTRICT="binchecks strip"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		$(use_enable accessibility all-themes)
+		--disable-test-themes
+		--enable-icon-mapping"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# Fix bashisms, bug #256337
+	epatch "${FILESDIR}/${PN}-2.24.3-bashism.patch"
+
+	# Do not build/install accessibility themes, bug #274515
+	if ! use accessibility; then
+		sed 's:HighContrast.*\\:\\:g' -i \
+			desktop-themes/Makefile.am desktop-themes/Makefile.in \
+			gtk-themes/Makefile.am gtk-themes/Makefile.in \
+			icon-themes/Makefile.am icon-themes/Makefile.in \
+			|| die "sed 1 failed"
+	fi
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+		|| die "sed 2 failed"
+}
diff --git a/x11-themes/gtk-engines/ChangeLog b/x11-themes/gtk-engines/ChangeLog
index 1a3d1b2ea542..1a7c28d26a69 100644
--- a/x11-themes/gtk-engines/ChangeLog
+++ b/x11-themes/gtk-engines/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-themes/gtk-engines
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-themes/gtk-engines/ChangeLog,v 1.152 2009/10/25 21:31:45 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-themes/gtk-engines/ChangeLog,v 1.153 2009/10/29 22:41:00 eva Exp $
+
+*gtk-engines-2.18.4 (29 Oct 2009)
+
+  29 Oct 2009; Gilles Dartiguelongue <eva@gentoo.org>
+  +gtk-engines-2.18.4.ebuild:
+  New version for GNOME 2.28.
 
   25 Oct 2009; Gilles Dartiguelongue <eva@gentoo.org>
   -gtk-engines-2.18.2.ebuild, -gtk-engines-2.18.2-r1.ebuild,
diff --git a/x11-themes/gtk-engines/gtk-engines-2.18.4.ebuild b/x11-themes/gtk-engines/gtk-engines-2.18.4.ebuild
new file mode 100644
index 000000000000..e5ce98b26465
--- /dev/null
+++ b/x11-themes/gtk-engines/gtk-engines-2.18.4.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-themes/gtk-engines/gtk-engines-2.18.4.ebuild,v 1.1 2009/10/29 22:41:00 eva Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+
+inherit gnome2
+
+DESCRIPTION="GTK+2 standard engines and themes"
+HOMEPAGE="http://www.gtk.org/"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="accessibility lua"
+
+RDEPEND=">=x11-libs/gtk+-2.12
+	lua? ( dev-lang/lua )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.31
+	>=dev-util/pkgconfig-0.9"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+pkg_setup() {
+	G2CONF="${G2CONF} --enable-animation $(use_enable lua) $(use_with lua system-lua)"
+	use accessibility || G2CONF="${G2CONF} --disable-hc"
+}