blob: df91d9b7fc8a3e4dce8337517721df18a4d9399c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 pypy )
inherit distutils-r1
DESCRIPTION="A graphical and console tool for exploring the size of directories"
HOMEPAGE="http://guichaz.free.fr/pysize/"
SRC_URI="http://guichaz.free.fr/${PN}/files/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="gtk ncurses"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RESTRICT="test"
RDEPEND="
gtk? ( dev-python/pygtk:2 )
ncurses? ( sys-libs/ncurses:0= )"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]"
PATCHES=(
"${FILESDIR}"/psyco-${PV}-automagic.patch
"${FILESDIR}"/${PV}-setuptools-automagic.patch
)
python_prepare_all() {
if ! use gtk; then
sed \
-e '/^from pysize.ui.gtk/d' \
-e "s~'gtk': ui_gtk.run,~~g" \
-e 's:ui_gtk.run,::g' \
-i pysize/main.py || die "Failed to remove gtk support"
rm -rf pysize/ui/gtk || die "Failed to remove gtk support"
fi
if ! use ncurses; then
sed \
-e '/^from pysize.ui.curses/d' \
-e "s~'curses': ui_curses.run,~~g" \
-e 's:ui_curses.run,::g' \
-i pysize/main.py || die "Failed to remove ncurses support"
rm -rf pysize/ui/curses || die "Failed to remove ncurses support"
fi
sed \
-e "s:/tmp:${T}:g" \
-i tests/tests/*.py tests/*py || die
sed \
-e '/for ui_run in/s:ui_ascii.run:ui_ascii.run, ui_ascii.run:g' \
-i pysize/main.py || die
distutils-r1_python_prepare_all
}
python_test() {
pushd "${S}"/tests > /dev/null
PYTHONPATH=.:../ "${PYTHON}" pysize_tests.py || die "tests failed under ${EPYTHON}"
popd > /dev/null
}
|
GitWeb
