blob: 3ef7155a7e2cb49ab9050fc8d9b0977c36ee2bdd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6..9} )
inherit cmake python-single-r1 xdg
DESCRIPTION="Android File Transfer for Linux"
HOMEPAGE="https://github.com/whoozle/android-file-transfer-linux"
if [[ "${PV}" = *9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/whoozle/android-file-transfer-linux.git"
else
SRC_URI="https://github.com/whoozle/android-file-transfer-linux/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="LGPL-2.1"
SLOT="0"
IUSE="fuse libressl python qt5 taglib zune"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
sys-apps/file
sys-libs/readline:0=
fuse? ( sys-fs/fuse:0 )
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/pybind11[${PYTHON_USEDEP}]
')
)
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtwidgets:5
)
taglib? ( media-libs/taglib )
zune? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
)
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
qt5? ( dev-qt/linguist-tools:5 )
"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
# required to override src_prepare from xdg eclass
src_prepare() {
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DBUILD_FUSE="$(usex fuse)"
-DBUILD_MTPZ="$(usex zune)"
-DBUILD_PYTHON="$(usex python)"
-DBUILD_QT_UI="$(usex qt5)"
-DBUILD_SHARED_LIB="ON"
-DBUILD_TAGLIB="$(usex taglib)"
# Upstream recommends to keep this off as libusb is broken
-DUSB_BACKEND_LIBUSB="OFF"
$(usex qt5 '-DDESIRED_QT_VERSION=5' '')
)
cmake_src_configure
}
|
GitWeb