sys-apps/audio-entropyd/audio-entropyd-2.0.3-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit systemd toolchain-funcs

DESCRIPTION="Audio-entropyd generates entropy-data for the /dev/random device"
HOMEPAGE="http://www.vanheusden.com/aed/"
SRC_URI="http://www.vanheusden.com/aed/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ~sparc x86"
IUSE="selinux"

DEPEND="media-libs/alsa-lib:="
RDEPEND="${DEPEND}
	media-sound/alsa-utils
	selinux? ( sec-policy/selinux-entropyd )"

PATCHES=(
	"${FILESDIR}"/${PN}-2.0.1-uclibc.patch
	"${FILESDIR}"/${PN}-2.0.1-ldflags.patch
)

src_prepare() {
	default

	sed -i -e "s|^OPT_FLAGS=.*|OPT_FLAGS=${CFLAGS}|" \
		-e "/^WARNFLAGS/s: -g::" Makefile || die
}

src_configure() {
	tc-export CC
}

src_install() {
	dosbin audio-entropyd
	einstalldocs

	systemd_dounit "${FILESDIR}"/${PN}.service
	newinitd "${FILESDIR}"/${PN}.init-2 ${PN}
	newconfd "${FILESDIR}"/${PN}.conf-2 ${PN}
}