blob: 3d41b6d75d2a34ce40562247bcc88f402011b925 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
LUA_COMPAT=( luajit )
LUA_REQ_USE="lua52compat"
WX_GTK_VER=3.0-gtk3
PLOCALES="ar be bg ca cs da de el es eu fa fi fr_FR gl hu id it ja ko nl pl pt_BR pt_PT ru sr_RS sr_RS@latin uk_UA vi zh_CN zh_TW"
inherit autotools lua-single plocale wxwidgets xdg-utils git-r3
DESCRIPTION="Advanced subtitle editor"
HOMEPAGE="http://www.aegisub.org/ https://github.com/wangqr/Aegisub"
EGIT_REPO_URI="https://github.com/wangqr/${PN^}.git"
# Submodules are used to pull bundled libraries.
EGIT_SUBMODULES=()
LICENSE="BSD MIT"
SLOT="0"
KEYWORDS=""
IUSE="+alsa debug +fftw openal oss portaudio pulseaudio spell +uchardet"
RESTRICT="test"
# aegisub bundles luabins (https://github.com/agladysh/luabins).
# Unfortunately, luabins upstream is practically dead since 2010.
# Thus unbundling luabins isn't worth the effort.
RDEPEND="${LUA_DEPS}
x11-libs/wxGTK:${WX_GTK_VER}[X,opengl,debug?]
dev-libs/boost:=[icu,nls,threads(+)]
dev-libs/icu:=
media-libs/ffmpegsource:=
media-libs/fontconfig
media-libs/freetype
media-libs/libass:=[fontconfig]
sys-libs/zlib
virtual/libiconv
virtual/opengl
alsa? ( media-libs/alsa-lib )
fftw? ( >=sci-libs/fftw-3.3:= )
openal? ( media-libs/openal )
portaudio? ( =media-libs/portaudio-19* )
pulseaudio? ( media-sound/pulseaudio )
spell? ( app-text/hunspell:= )
uchardet? ( app-i18n/uchardet )
"
DEPEND="${RDEPEND}"
BDEPEND="dev-util/intltool
sys-devel/gettext
virtual/pkgconfig
"
REQUIRED_USE="${LUA_REQUIRED_USE}
|| ( alsa openal oss portaudio pulseaudio )"
PATCHES=(
"${FILESDIR}/${P}-git.patch"
)
pkg_setup() {
lua-single_pkg_setup
}
src_prepare() {
default_src_prepare
# Remove tests that require unavailable uuid Lua module.
rm automation/tests/modules/lfs.moon || die
remove_locale() {
rm "po/${1}.po" || die
}
plocale_find_changes 'po' '' '.po'
plocale_for_each_disabled_locale remove_locale
# See http://devel.aegisub.org/ticket/1914
config_rpath_update "${S}"/config.rpath
eautoreconf
}
src_configure() {
# Prevent access violations from OpenAL detection. See Gentoo bug 508184.
use openal && export agi_cv_with_openal="yes"
setup-wxwidgets
local myeconfargs=(
--disable-update-checker
--with-ffms2
--with-system-luajit
$(use_enable debug)
$(use_with alsa)
$(use_with fftw fftw3)
$(use_with openal)
$(use_with oss)
$(use_with portaudio)
$(use_with pulseaudio libpulse)
$(use_with spell hunspell)
$(use_with uchardet)
--disable-compiler-flags
)
econf "${myeconfargs[@]}"
}
src_compile() {
# Concurrent builds seem to break the build process.
emake -j1
}
src_test() {
emake test-automation
emake test-libaegisub
}
pkg_postinst() {
xdg_icon_cache_update
xdg_desktop_database_update
}
pkg_postrm() {
xdg_icon_cache_update
xdg_desktop_database_update
}
|
GitWeb