blob: 6364aaca1aa4a1a66c355cb6447b9e63c714322d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit multilib-minimal toolchain-funcs
DESCRIPTION="Network Audio System"
HOMEPAGE="https://radscan.com/nas.html"
SRC_URI="mirror://sourceforge/${PN}/${P}.src.tar.gz"
LICENSE="HPND MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86"
IUSE="doc static-libs"
RDEPEND="
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
>=x11-libs/libXau-1.0.7-r1[${MULTILIB_USEDEP}]
x11-libs/libXaw
x11-libs/libXext
x11-libs/libXmu
x11-libs/libXpm
>=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}]"
DEPEND="${RDEPEND}
app-text/rman
sys-devel/bison
sys-devel/flex
x11-base/xorg-proto
x11-misc/gccmakedep
x11-misc/imake"
DOCS=( BUILDNOTES FAQ HISTORY README RELEASE TODO )
PATCHES=(
"${FILESDIR}/${PN}-1.9.2-asneeded.patch"
"${FILESDIR}/${P}-remove-abs-fabs.patch"
"${FILESDIR}/${P}-libfl.patch"
"${FILESDIR}/${P}-fno-config.patch"
)
src_prepare() {
default
multilib_copy_sources
}
multilib_src_configure() {
# Need to run econf so that config.guess is updated
pushd config || die
econf
popd || die
xmkmf -a || die
}
multilib_src_compile() {
# EXTRA_LDOPTIONS, SHLIBGLOBALSFLAGS #336564#c2
local emakeopts=(
AR="$(tc-getAR) clq"
AS="$(tc-getAS)"
CC="$(tc-getCC)"
CDEBUGFLAGS="${CFLAGS}"
CXX="$(tc-getCXX)"
CXXDEBUFLAGS="${CXXFLAGS}"
EXTRA_LDOPTIONS="${LDFLAGS}"
LD="$(tc-getLD)"
MAKE="${MAKE:-gmake}"
RANLIB="$(tc-getRANLIB)"
SHLIBGLOBALSFLAGS="${LDFLAGS}"
WORLDOPTS=
)
if multilib_is_native_abi ; then
# dumb fix for parallel make issue wrt #446598, Imake sux
emake "${emakeopts[@]}" -C server/dia all
emake "${emakeopts[@]}" -C server/dda/voxware all
emake "${emakeopts[@]}" -C server/os all
else
sed -i \
-e 's/SUBDIRS =.*/SUBDIRS = include lib config/' \
Makefile || die
fi
emake "${emakeopts[@]}" World
}
multilib_src_install() {
# ranlib is used at install phase too wrt #446600
emake RANLIB="$(tc-getRANLIB)" \
DESTDIR="${D}" USRLIBDIR=/usr/$(get_libdir) \
install install.man
}
multilib_src_install_all() {
einstalldocs
if use doc; then
docinto doc
dodoc doc/{actions,protocol.txt,README}
docinto pdf
dodoc doc/pdf/*.pdf
fi
mv -vf "${D}"/etc/nas/nasd.conf{.eg,} || die
newconfd "${FILESDIR}"/nas.conf.d nas
newinitd "${FILESDIR}"/nas.init.d nas
if ! use static-libs; then
rm -f "${D}"/usr/lib*/libaudio.a || die
fi
}
|
GitWeb