blob: 824e056d80f1f660e5f384690c45906288965aea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_PN="intel-vaapi-driver"
if [[ ${PV} = *9999* ]] ; then # Live ebuild
inherit git-r3
EGIT_REPO_URI="https://github.com/intel/intel-vaapi-driver"
fi
inherit autotools multilib-minimal
DESCRIPTION="HW video decode support for Intel integrated graphics"
HOMEPAGE="https://github.com/intel/intel-vaapi-driver"
if [[ ${PV} != *9999* ]] ; then
SRC_URI="https://github.com/intel/${MY_PN}/releases/download/${PV}/${MY_PN}-${PV}.tar.bz2"
S="${WORKDIR}/${MY_PN}-${PV}"
KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
fi
LICENSE="MIT"
SLOT="0"
IUSE="hybrid wayland X"
RESTRICT="test" # No tests
RDEPEND="
>=x11-libs/libdrm-2.4.52[video_cards_intel,${MULTILIB_USEDEP}]
>=media-libs/libva-2.4.0:=[X?,wayland?,${MULTILIB_USEDEP}]
hybrid? (
>=media-libs/intel-hybrid-codec-driver-2.0.0[X?,wayland?]
)
wayland? (
>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
>=media-libs/mesa-9.1.6[egl(+),${MULTILIB_USEDEP}]
)
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PV}-Make-wl_drm-optional.patch
)
src_prepare() {
default
sed -e 's/intel-gen4asm/\0diSaBlEd/g' -i configure.ac || die
eautoreconf
}
multilib_src_configure() {
local myconf=(
$(use_enable hybrid hybrid-codec)
$(use_enable wayland)
$(use_enable X x11)
)
ECONF_SOURCE="${S}" econf "${myconf[@]}"
}
multilib_src_install_all() {
find "${D}" -name "*.la" -delete || die
}
|
GitWeb
