blob: 6ec8c7b5d1aaaa1efc237ef9688e49a1da3a765f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="Translate PostScript and PDF graphics into other vector formats"
HOMEPAGE="https://sourceforge.net/projects/pstoedit/"
SRC_URI="https://downloads.sourceforge.net/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
IUSE="emf imagemagick plotutils pptx"
BDEPEND="
virtual/pkgconfig
"
RDEPEND="
>=app-text/ghostscript-gpl-8.71-r1
>=media-libs/gd-2.0.35-r1:=
emf? ( >=media-libs/libemf-1.0.3 )
imagemagick? ( >=media-gfx/imagemagick-6.6.1.2:=[cxx] )
plotutils? ( media-libs/plotutils )
pptx? ( dev-libs/libzip:= )
"
DEPEND="${RDEPEND}"
DOCS=( doc/readme.txt )
HTML_DOCS=( doc/{changelog,pstoedit}.htm )
PATCHES=(
"${FILESDIR}"/${P}-libdl.patch
"${FILESDIR}"/${P}-gcc12.patch
)
src_prepare() {
default
sed -i \
-e '/CXXFLAGS="-g"/d' \
-e 's:-pedantic::' \
configure.ac || die
eautoreconf
}
src_configure() {
local myeconfargs=(
--disable-static
--without-swf
$(use_with emf)
$(use_with imagemagick magick)
$(use_with plotutils libplot)
$(use_with pptx)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
doman doc/pstoedit.1
find "${ED}" -name '*.la' -delete || die
}
|
GitWeb
