blob: 05cc150deeca1806e28f70627db7687f96fa6bd4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7,8,9} )
DISTUTILS_OPTIONAL=1
inherit linux-info bash-completion-r1 python-r1 toolchain-funcs
DESCRIPTION="User-space front-end for Ftrace"
HOMEPAGE="https://git.kernel.org/cgit/linux/kernel/git/rostedt/trace-cmd.git"
if [[ ${PV} == *9999 ]] ; then
EGIT_REPO_URI="https://git.kernel.org/pub/scm/linux/kernel/git/rostedt/${PN}.git"
inherit git-r3
else
SRC_URI="https://git.kernel.org/pub/scm/utils/trace-cmd/trace-cmd.git/snapshot/${PN}-v${PV}.tar.gz"
KEYWORDS="~amd64 ~arm64 ~x86"
S="${WORKDIR}/${PN}-v${PV}"
fi
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0/${PV}"
IUSE="+audit doc python test udis86"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
RDEPEND="
audit? ( sys-process/audit )
python? ( ${PYTHON_DEPS} )
udis86? ( dev-libs/udis86 )
"
DEPEND="${RDEPEND}
sys-kernel/linux-headers
test? ( dev-util/cunit )
"
BDEPEND="
python? (
virtual/pkgconfig
dev-lang/swig
)
doc? ( app-text/asciidoc )
"
# having trouble getting tests to compile
RESTRICT+=" test"
pkg_setup() {
local CONFIG_CHECK="
~TRACING
~FTRACE
~BLK_DEV_IO_TRACE"
linux-info_pkg_setup
}
src_prepare() {
default
sed -r -e 's:([[:space:]]+)install_bash_completion($|[[:space:]]+):\1:' \
-i Makefile || die "sed failed"
}
src_configure() {
EMAKE_FLAGS=(
BUILD_OUTPUT="${WORKDIR}/${P}_build"
"prefix=${EPREFIX}/usr"
"libdir=${EPREFIX}/usr/$(get_libdir)"
"CC=$(tc-getCC)"
"AR=$(tc-getAR)"
"BASH_COMPLETE_DIR=$(get_bashcompdir)"
"etcdir=/etc"
$(usex audit '' 'NO_AUDIT=' '' '1')
$(usex test 'CUNIT_INSTALLED=' '' '1' '')
$(usex udis86 '' 'NO_UDIS86=' '' '1')
VERBOSE=1
)
}
src_compile() {
emake "${EMAKE_FLAGS[@]}" NO_PYTHON=1 \
trace-cmd
if use python; then
python_copy_sources
python_foreach_impl python_compile
fi
use doc && emake doc
}
python_compile() {
pushd "${BUILD_DIR}" > /dev/null || die
emake "${EMAKE_FLAGS[@]}" \
PYTHON_VERS="${EPYTHON}" \
PYTHON_PKGCONFIG_VERS="${EPYTHON//python/python-}" \
python_dir=$(python_get_sitedir)/${PN} \
python ctracecmd.so
popd > /dev/null || die
}
src_test() {
emake "${EMAKE_FLAGS[@]}" test
}
src_install() {
emake "${EMAKE_FLAGS[@]}" NO_PYTHON=1 \
DESTDIR="${D}" \
install install_libs
newbashcomp tracecmd/trace-cmd.bash "${PN}"
use doc && emake DESTDIR="${D}" install_doc
use python && python_foreach_impl python_install
}
python_install() {
pushd "${BUILD_DIR}" > /dev/null || die
emake "${EMAKE_FLAGS[@]}" DESTDIR="${D}" \
PYTHON_VERS="${EPYTHON}" \
PYTHON_PKGCONFIG_VERS="${EPYTHON//python/python-}" \
python_dir=$(python_get_sitedir)/${PN} \
install_python
popd > /dev/null || die
python_optimize
}
|
GitWeb