blob: b4bfee6c10424efb46fd9f3ec5ba36ec45b868a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=(python3_{8,9,10})
# This is the commit that the CI for the release commit used
BINS_COMMIT="aa6a88dcdfaad54335e3935c16ce21a124ff861d"
inherit meson python-any-r1
DESCRIPTION="reverse engineering framework for binary analysis"
HOMEPAGE="https://rizin.re/"
SRC_URI="mirror+https://github.com/rizinorg/rizin/releases/download/v${PV}/rizin-src-v${PV}.tar.xz
test? ( https://github.com/rizinorg/rizin-testbins/archive/${BINS_COMMIT}.tar.gz -> rizin-testbins-${BINS_COMMIT}.tar.gz )"
KEYWORDS="~amd64 ~arm64 ~x86"
LICENSE="Apache-2.0 BSD LGPL-3 MIT"
SLOT="0/${PV}"
IUSE="test"
# Need to audit licenses of the binaries used for testing
RESTRICT="fetch !test? ( test )"
RDEPEND="
sys-apps/file
app-arch/lz4:0=
dev-libs/capstone:0=
dev-libs/libuv:0=
dev-libs/libzip:0=
dev-libs/openssl:0=
>=dev-libs/tree-sitter-0.19.0
dev-libs/xxhash
sys-libs/zlib:0=
"
DEPEND="${RDEPEND}"
BDEPEND="${PYTHON_DEPS}"
PATCHES=(
"${FILESDIR}/${PN}-0.3.0-typedb-prefix.patch"
"${FILESDIR}/${PN}-0.3.2-never-rebuild-parser.patch"
)
S="${WORKDIR}/${PN}-v${PV}"
src_prepare() {
default
local py_to_mangle=(
librz/core/cmd_descs/cmd_descs_generate.py
subprojects/lz4-1.9.3/contrib/meson/meson/GetLz4LibraryVersion.py
subprojects/lz4-1.9.3/contrib/meson/meson/InstallSymlink.py
subprojects/lz4-1.9.3/tests/test-lz4-list.py
subprojects/lz4-1.9.3/tests/test-lz4-speed.py
subprojects/lz4-1.9.3/tests/test-lz4-versions.py
sys/clang-format.py
test/fuzz/scripts/fuzz_rz_asm.py
test/scripts/gdbserver.py
)
python_fix_shebang "${py_to_mangle[@]}"
if use test; then
cp -r "${WORKDIR}/rizin-testbins-${BINS_COMMIT}" "${S}/test/bins" || die
cp -r "${WORKDIR}/rizin-testbins-${BINS_COMMIT}" "${S}" || die
fi
}
src_configure() {
local emesonargs=(
-Dcli=enabled
-Duse_sys_capstone=enabled
-Duse_sys_magic=enabled
-Duse_sys_libzip=enabled
-Duse_sys_zlib=enabled
-Duse_sys_lz4=enabled
-Duse_sys_xxhash=enabled
-Duse_sys_openssl=enabled
-Duse_sys_tree_sitter=enabled
$(meson_use test enable_tests)
$(meson_use test enable_rz_test)
)
meson_src_configure
}
src_test() {
# Rizin uses data files that it expects to be installed on the
# system. To hack around this, we create a tree of what it expects
# in ${T}, and patch the tests to support a prefix from the
# environment. https://github.com/rizinorg/rizin/issues/1789
mkdir -p "${T}/usr/share/${PN}/${PV}" || die
ln -sf "${BUILD_DIR}/librz/analysis/d" "${T}/usr/share/${PN}/${PV}/types" || die
ln -sf "${BUILD_DIR}/librz/syscall/d" "${T}/usr/share/${PN}/${PV}/syscall" || die
ln -sf "${BUILD_DIR}/librz/asm/d" "${T}/usr/share/${PN}/${PV}/opcodes" || die
# https://github.com/rizinorg/rizin/issues/1797
ln -sf "${BUILD_DIR}/librz/flag/d" "${T}/usr/share/${PN}/${PV}/flag" || die
export RZ_PREFIX="${T}/usr"
meson_src_test
}
|
GitWeb