blob: 6462474c71dd30c3dc2096f1c7095d9781e4483f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
PYTHON_COMPAT=( python2_7 python3_{4,5} )
PYTHON_REQ_USE="sqlite,xml"
inherit python-single-r1
DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
HOMEPAGE="http://eric-ide.python-projects.org/"
LICENSE="GPL-3"
SLOT="6"
MY_P=${PN}${SLOT}-${PV}
BASE_URI="mirror://sourceforge/eric-ide/${PN}${SLOT}/stable/${PV}"
SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""
PLOCALES="cs de en es fr it pt ru tr zh-CN"
for L in ${PLOCALES}; do
SRC_URI+=" l10n_${L}? ( ${BASE_URI}/${PN}${SLOT}-i18n-${L/-/_}-${PV}.tar.gz )"
IUSE+=" l10n_${L}"
done
unset L
DEPEND="
${PYTHON_DEPS}
>=dev-python/sip-4.14.3[${PYTHON_USEDEP}]
>=dev-python/PyQt4-4.10[${PYTHON_USEDEP},X,help,sql,svg,webkit]
>=dev-python/qscintilla-python-2.8[${PYTHON_USEDEP}]
"
RDEPEND="${DEPEND}
>=dev-python/chardet-2.2.1[${PYTHON_USEDEP}]
>=dev-python/coverage-4.0.0[${PYTHON_USEDEP}]
>=dev-python/pygments-2.0.2[${PYTHON_USEDEP}]
!dev-util/eric:4
!dev-util/eric:5
"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
S=${WORKDIR}/${MY_P}
DOCS=(changelog README{,-i18n}.rst THANKS)
src_prepare() {
default
# Delete internal copies of dev-python/chardet and dev-python/pygments
rm -fr eric/ThirdParty/{CharDet,Pygments} || die
# Delete internal copy of dev-python/coverage
rm -fr eric/DebugClients/Python{,3}/coverage || die
sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
# Fix desktop files (bug 458092)
sed -i -e '/^Categories=/s:Python:X-&:' eric/eric6{,_webbrowser}.desktop || die
}
src_install() {
"${PYTHON}" install.py \
-b "${EPREFIX}/usr/bin" \
-d "$(python_get_sitedir)" \
-i "${D}" \
-c \
-z \
--pyqt=4 \
|| die
python_optimize
einstalldocs
}
|
GitWeb