blob: 7de6d24bacc4d626d507f6b01fa801238b7fb230 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit gnome.org gnome2-utils meson python-single-r1 xdg
DESCRIPTION="An API documentation browser for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Devhelp"
LICENSE="GPL-3+ CC-BY-SA-4.0"
SLOT="0/3-6" # subslot = 3-(libdevhelp-3 soname version)
KEYWORDS="amd64 ~arm ~arm64 ~ppc64 ~sparc x86"
IUSE="+gedit gtk-doc +introspection"
REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} ) gtk-doc? ( introspection )"
DEPEND="
>=dev-libs/glib-2.64:2
>=x11-libs/gtk+-3.22:3[introspection?]
net-libs/webkit-gtk:4.1[introspection?]
gnome-base/gsettings-desktop-schemas
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
"
RDEPEND="${DEPEND}
gedit? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
app-editors/gedit[introspection(+),python,${PYTHON_SINGLE_USEDEP}]
dev-python/pygobject:3[${PYTHON_USEDEP}]
')
)
"
# libxml2 required for glib-compile-resources
BDEPEND="
${PYTHON_DEPS}
dev-libs/libxml2:2
dev-util/glib-utils
dev-util/itstool
gtk-doc? ( >=dev-util/gi-docgen-2021.6 )
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/41.2-optional-introspection.patch
)
pkg_setup() {
use gedit && python-single-r1_pkg_setup
}
src_configure() {
local emesonargs=(
-Dflatpak_build=false
$(meson_use gtk-doc gtk_doc)
$(meson_use introspection)
-Dplugin_emacs=true
$(meson_use gedit plugin_gedit)
-Dplugin_vim=true
)
meson_src_configure
}
src_install() {
meson_src_install
if use gtk-doc; then
mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
mv "${ED}"/usr/share/doc/devhelp-3 "${ED}"/usr/share/gtk-doc/html/ || die
fi
use gedit && python_optimize "${ED}"/usr/$(get_libdir)/gedit/plugins
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb