blob: 7e04839295dcee012fb0eedbecdc725ba841b4f1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
USE_RUBY="ruby30 ruby31 ruby32"
# Skip integration tests since they require additional unpackaged
# dependencies and running daemons.
RUBY_FAKEGEM_TASK_TEST="test:units"
RUBY_FAKEGEM_EXTRADOC="README.md"
RUBY_FAKEGEM_BINWRAP=""
inherit ruby-fakegem
DESCRIPTION="A DSL for blocking & throttling abusive clients"
HOMEPAGE="https://github.com/rack/rack-attack"
LICENSE="MIT"
SLOT="$(ver_cut 1)"
KEYWORDS="~amd64"
IUSE="test"
ruby_add_rdepend "dev-ruby/rack:*"
ruby_add_bdepend "test? (
dev-ruby/actionpack
dev-ruby/activesupport
dev-ruby/railties
dev-ruby/rack-test
dev-ruby/minitest )"
all_ruby_prepare() {
sed -i -e '/\(bundler\|byebug\)/ s:^:#:' Rakefile spec/spec_helper.rb || die
sed -i -e '3igem "actionpack"' spec/spec_helper.rb || die
sed -i -e '/rubocop/I s:^:#:' Rakefile || die
# Avoid specs requiring a live redis service
sed -i -e '/should delete rack attack key/askip "requires redis service"' spec/rack_attack_spec.rb || die
}
|
GitWeb
