blob: 000e71d2c36c957377a7b7c965914f6c452de601 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 2022-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
# custom wrapper over setuptools
DISTUTILS_USE_PEP517=standalone
PYTHON_COMPAT=( pypy3 python3_{10..13} )
inherit distutils-r1 pypi
DESCRIPTION="Rapid fuzzy string matching in Python using various string metrics"
HOMEPAGE="
https://github.com/rapidfuzz/RapidFuzz/
https://pypi.org/project/rapidfuzz/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
# all these are header-only libraries
DEPEND="
>=dev-cpp/taskflow-3.0.0
>=dev-cpp/rapidfuzz-cpp-3.0.5
dev-python/numpy[${PYTHON_USEDEP}]
"
BDEPEND="
>=dev-python/cython-3[${PYTHON_USEDEP}]
>=dev-python/scikit-build-0.16.2[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
dev-python/hypothesis[${PYTHON_USEDEP}]
)
"
EPYTEST_XDIST=1
distutils_enable_tests pytest
src_prepare() {
# sterilize build flags
sed -i -e '/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
# remove bundled libraries
rm -r extern || die
# force recythonization
find src -name '*.cxx' -delete || die
# do not require exact taskflow version
sed -i -e '/Taskflow/s:3\.7\.0::' CMakeLists.txt || die
distutils-r1_src_prepare
export RAPIDFUZZ_BUILD_EXTENSION=1
}
python_compile() {
distutils-r1_python_compile
# scikit-build is broken and reuses the same build
# https://github.com/scikit-build/scikit-build/issues/633
rm -r _skbuild || die
}
python_test() {
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest
}
|
GitWeb
