blob: 5a2d172c90bd465ec6e9fe281566b80c697a8ed3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy pypy3 )
inherit distutils-r1
DESCRIPTION="C parser and AST generator written in Python"
HOMEPAGE="https://github.com/eliben/pycparser"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
IUSE="test"
RDEPEND="dev-python/ply[${PYTHON_USEDEP}]:="
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
test? ( dev-python/nose[${PYTHON_USEDEP}] )"
PATCHES=(
"${FILESDIR}"/pycparser-2.18-OO.patch
)
python_prepare_all() {
# remove the original files to guarantee their regen
rm pycparser/{c_ast,lextab,yacctab}.py || die
# kill sys.path manipulations to force the tests to use built files
sed -i -e '/sys\.path/d' tests/*.py || die
distutils-r1_python_prepare_all
}
python_compile() {
distutils-r1_python_compile
# note: tables built by py3.5+ are incompatible with older versions
# because of 100 group limit of 're' module -- just generate them
# separately optimized for each target instead
pushd "${BUILD_DIR}"/lib/pycparser > /dev/null || die
"${PYTHON}" _build_tables.py || die
popd > /dev/null || die
}
python_test() {
# change workdir to avoid '.' import
nosetests -v -w tests || die
}
|
GitWeb
