blob: d39f59a5d400da8949762cb029df209a9f1f7beb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 2018-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 python3_{4..7})
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
MY_PN="M2Crypto"
DESCRIPTION="A Python crypto and SSL toolkit"
HOMEPAGE="https://gitlab.com/m2crypto/m2crypto https://pypi.org/project/M2Crypto/"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
IUSE="libressl"
RDEPEND="
!libressl? ( dev-libs/openssl:0=[-bindist(-)] )
libressl? ( dev-libs/libressl:0= )
virtual/python-typing[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}
>=dev-lang/swig-2.0.9
dev-python/setuptools[${PYTHON_USEDEP}]
"
S="${WORKDIR}/${MY_PN}-${PV}"
# Tests access network, and fail randomly. Bug #431458.
RESTRICT=test
PATCHES=(
"${FILESDIR}/${PN}-libressl-${PV}.patch"
)
python_compile() {
# setup.py looks at platform.machine() to determine swig options.
# For exotic ABIs, we need to give swig a hint.
# https://bugs.gentoo.org/617946
# TODO: Fix cross-compiles
local -x SWIG_FEATURES=
case ${ABI} in
x32) SWIG_FEATURES="-D__ILP32__" ;;
esac
distutils-r1_python_compile --openssl="${EPREFIX}"/usr
}
python_test() {
esetup.py test
}
|
GitWeb
