blob: c957edaec2de7c05842fe831888c5d33f40e9028 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
VCS_INHERIT=""
if [[ "${PV}" == 9999 ]] ; then
VCS_INHERIT="git-r3"
EGIT_REPO_URI="https://github.com/MariaDB/mariadb-connector-c.git"
else
MY_PN=${PN#mariadb-}
MY_PV=${PV/_b/-b}
SRC_URI="https://downloads.mariadb.org/f/${MY_PN}-${PV%_beta}/${PN}-${MY_PV}-src.tar.gz?serve -> ${P}-src.tar.gz"
S="${WORKDIR%/}/${PN}-${MY_PV}-src"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
fi
inherit cmake-utils multilib-minimal toolchain-funcs ${VCS_INHERIT}
MULTILIB_CHOST_TOOLS=( /usr/bin/mariadb_config )
MULTILIB_WRAPPED_HEADERS+=(
/usr/include/mariadb/mariadb_version.h
)
DESCRIPTION="C client library for MariaDB/MySQL"
HOMEPAGE="https://mariadb.org/"
LICENSE="LGPL-2.1"
SLOT="0/3"
IUSE="+curl gnutls kerberos libressl mysqlcompat +ssl static-libs test"
DEPEND="sys-libs/zlib:=[${MULTILIB_USEDEP}]
virtual/libiconv:=[${MULTILIB_USEDEP}]
curl? ( net-misc/curl:0=[${MULTILIB_USEDEP}] )
kerberos? ( || ( app-crypt/mit-krb5[${MULTILIB_USEDEP}]
app-crypt/heimdal[${MULTILIB_USEDEP}] ) )
ssl? (
gnutls? ( >=net-libs/gnutls-3.3.24:0=[${MULTILIB_USEDEP}] )
!gnutls? (
libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
!libressl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
)
)
"
RDEPEND="${DEPEND}
mysqlcompat? (
!dev-db/mysql[client-libs(+)]
!dev-db/mysql-cluster[client-libs(+)]
!dev-db/mariadb[client-libs(+)]
!dev-db/mariadb-galera[client-libs(+)]
!dev-db/percona-server[client-libs(+)]
!dev-db/mysql-connector-c )
!>=dev-db/mariadb-10.2.0[client-libs(+)]
"
PATCHES=(
"${FILESDIR}"/gentoo-layout-3.0.patch
"${FILESDIR}"/${PN}-3.0.8-fix-pkconfig-file.patch
)
src_configure() {
# bug 508724 mariadb cannot use ld.gold
tc-ld-disable-gold
multilib-minimal_src_configure
}
multilib_src_configure() {
local mycmakeargs=(
-DWITH_EXTERNAL_ZLIB=ON
-DWITH_SSL:STRING=$(usex ssl $(usex gnutls GNUTLS OPENSSL) OFF)
-DWITH_CURL=$(usex curl ON OFF)
-DCLIENT_PLUGIN_AUTH_GSSAPI_CLIENT:STRING=$(usex kerberos DYNAMIC OFF)
-DMARIADB_UNIX_ADDR="${EPREFIX%/}/var/run/mysqld/mysqld.sock"
-DINSTALL_LIBDIR="$(get_libdir)"
-DINSTALL_PCDIR="$(get_libdir)/pkgconfig"
-DINSTALL_PLUGINDIR="$(get_libdir)/mariadb/plugin"
-DINSTALL_BINDIR=bin
-DWITH_UNIT_TESTS=$(usex test ON OFF)
)
cmake-utils_src_configure
}
multilib_src_compile() {
cmake-utils_src_compile
}
multilib_src_install() {
cmake-utils_src_install
if use mysqlcompat ; then
dosym libmariadb.so.3 /usr/$(get_libdir)/libmysqlclient.so.19
dosym libmariadb.so.3 /usr/$(get_libdir)/libmysqlclient.so
fi
}
multilib_src_install_all() {
if ! use static-libs ; then
find "${D}" -name "*.a" -delete || die
fi
if use mysqlcompat ; then
dosym mariadb_config /usr/bin/mysql_config
dosym mariadb /usr/include/mysql
fi
}
|
GitWeb