blob: 21f9544f85ee6e85a752dfc6ff9045acc0cef52f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PLOCALES="ast az be bg bs ca cs da de el en_AU en_GB eo es eu fa fi fr gl he hr hu id it ja kk ko ku ky lt lv ms my nb nds oc pl pt pt_BR ro ru sk sr sv th tr ug uk uz vi zh_CN zh_TW"
inherit l10n qmake-utils xdg-utils gnome2-utils
DESCRIPTION="A tabbed document viewer"
HOMEPAGE="https://launchpad.net/qpdfview"
SRC_URI="https://dev.gentoo.org/~grozin/${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
IUSE="cups +dbus djvu fitz +pdf postscript +sqlite +svg synctex"
REQUIRED_USE="?? ( fitz pdf )"
RDEPEND="
cups? ( net-print/cups )
djvu? ( app-text/djvu )
fitz? ( >=app-text/mupdf-1.7:= )
postscript? ( app-text/libspectre )
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtprintsupport:5
dev-qt/qtwidgets:5
dbus? ( dev-qt/qtdbus:5 )
pdf? ( >=app-text/poppler-0.35[qt5]
dev-qt/qtxml:5 )
sqlite? ( dev-qt/qtsql:5[sqlite] )
svg? ( dev-qt/qtsvg:5 )
!svg? ( virtual/freedesktop-icon-theme )
synctex? ( app-text/texlive-core )"
DEPEND="${RDEPEND}
dev-qt/linguist-tools:5
virtual/pkgconfig"
DOCS=( CHANGES CONTRIBUTORS README TODO )
src_prepare() {
local mylrelease="$(qt5_get_bindir)"/lrelease
prepare_locale() {
"${mylrelease}" "translations/${PN}_${1}.ts" || die "preparing ${1} locale failed"
}
rm_help() {
rm -f "help/help_${1}.html" || die "removing ${1} help file failed"
}
l10n_find_plocales_changes translations ${PN}_ .ts
l10n_for_each_locale_do prepare_locale
l10n_for_each_disabled_locale_do rm_help
# adapt for prefix
sed -i -e "s:/usr:${EPREFIX}/usr:g" qpdfview.pri || die
default
}
src_configure() {
local myconfig=() i=
for i in cups dbus djvu pdf svg synctex; do
use ${i} || myconfig+=(without_${i})
done
use fitz && myconfig+=(with_fitz)
use postscript || myconfig+=(without_ps)
use sqlite || myconfig+=(without_sql)
local myqmakeargs=(
qpdfview.pro
CONFIG+="${myconfig[@]}"
PLUGIN_INSTALL_PATH="${EPREFIX}/usr/$(get_libdir)/${PN}"
)
eqmake5 "${myqmakeargs[@]}"
}
src_install() {
emake INSTALL_ROOT="${D}" install
einstalldocs
}
pkg_postinst() {
xdg_desktop_database_update
xdg_mimeinfo_database_update
gnome2_icon_cache_update
}
pkg_postrm() {
xdg_desktop_database_update
xdg_mimeinfo_database_update
gnome2_icon_cache_update
}
|
GitWeb