blob: 9d5b5b806b5fd4cfe813c5f07dbe84a7800ed838 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PLOCALES="ca cs de en es fr hu it nb nl pl pt ru sv"
inherit cmake-utils l10n
DESCRIPTION="Application to create and manage beer recipes"
HOMEPAGE="http://www.brewtarget.org/"
SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${PN}_${PV}.orig.tar.gz"
LICENSE="GPL-3 WTFPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="kde phonon"
DEPEND="
>=dev-qt/qtcore-4.8:4
>=dev-qt/qtgui-4.8:4
>=dev-qt/qtsql-4.8:4[sqlite]
>=dev-qt/qtsvg-4.8:4
>=dev-qt/qtwebkit-4.8:4
phonon? (
kde? ( media-libs/phonon[qt4] )
!kde? ( || ( >=dev-qt/qtphonon-4.8:4 media-libs/phonon[qt4] ) )
)
"
RDEPEND="${DEPEND}"
remove_locale() {
sed -i -e "/bt_$1.ts/d" CMakeLists.txt || die
}
src_prepare() {
# Check for new locales, respect LINGUAS
l10n_find_plocales_changes "${S}/translations" bt_ .ts
l10n_for_each_disabled_locale_do remove_locale
# Fix desktop file
sed -i -e '/^Encoding=/d' ${PN}.desktop.in || die
cmake-utils_src_prepare
}
src_configure() {
local mycmakeargs=(
-DDO_RELEASE_BUILD=ON
-DNO_MESSING_WITH_FLAGS=ON
$(cmake-utils_use_no phonon)
)
cmake-utils_src_configure
}
|
GitWeb
